Liren Large Software Subsidy 9/09.iso/l/l076/1.ddi/TURTLE.TRU

Text File | 1988-08-27 | 1.7 KB | 84 lines

!  Turtle.
!  Sample program that implements Turtle Graphics.
!
set color 0
call Right(45)
call Forward(70)
call Left(45)
set color 1
for i = 1 to 500
    call Forward(8)
    call Left(5+mod(i,50))
next i
end

!  Turtle graphics -- a sample module.
!  Version 1.0
!
MODULE Turtle

    SHARE x, y, a                 !current turtle position, direction

    OPTION ANGLE degrees          !use degrees throughout module

    CALL ClearScreen              !initialize -- clear screen


    !
    !  ClearScreen
    !
    !  Clear the output window, set the x/y position to
    !  (0,0) and turn the turtle to face "up".
    !
    SUB ClearScreen
        CLEAR
        SET WINDOW -140, 140, -120, 120
        LET x,y = 0
        LET a = 90
    END SUB

    !
    !  Left
    !
    !  Turn left by 'da' degrees.  Don't move; just turn.
    !
    SUB Left(da)
        LET a = a + da
    END SUB

    !
    !  Right
    !
    !  Turn right by 'da' degrees.  Don't move; just turn.
    !
    SUB Right(da)
        LET a = a - da
    END SUB

    !
    !  Forward
    !
    !  Go forward 'd' units.  We move in the current direction.
    !
    SUB Forward(d)
        LET dx = d*cos(a)         !compute x/y distances to move
        LET dy = d*sin(a)
        LET newx = x + dx         !get new x/y position
        LET newy = y + dy
        PLOT x,y; newx, newy      !draw line from old position to new
        LET x = newx
        LET y = newy              !remember new position
    END SUB

    !
    !  Back
    !
    !  Go backward 'd' units.  We move in the opposite
    !  of the current direction.
    !
    SUB Back(d)
        CALL Forward(-d)
    END SUB

END MODULE