home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l043 / 2.ddi / GRLINK.PAS < prev    next >
Encoding:
Pascal/Delphi Source File  |  1987-11-02  |  4.4 KB  |  126 lines
  1.  
  2. {           Copyright (c) 1985, 87 by Borland International, Inc.            }
  3.  
  4. program GrLink;
  5. { This program demonstrates how to link graphics driver and font files
  6.   into an EXE file. BGI graphic's drivers and fonts are kept in
  7.   separate disk files so they may be dynamically loaded at runtime.
  8.   However, sometimes it is preferable to place all auxiliary files
  9.   directly into an .EXE. This program, along with its make file
  10.   (GRLINK.MAK) and two units (DRIVERS.PAS and FONTS.PAS) links all
  11.   the drivers and fonts directly into GRLINK.EXE.
  12.  
  13.   Have these 3 programs in the current drive or directory, or
  14.   have them available via a path (both are on Disk II):
  15.  
  16.     MAKE.EXE     - Make utility that will build GRLINK.EXE
  17.     BINOBJ.EXE   - utility program to convert any file into an .OBJ file
  18.  
  19.   Place in the current drive or directory the following files (all
  20.   are on Disk III):
  21.  
  22.     GRLINK.PAS   - this sample program
  23.     DRIVERS.PAS  - Pascal unit that will link in all BGI drivers
  24.     FONTS.PAS    - Pascal unit that will link in all BGI fonts
  25.     *.CHR        - BGI font files
  26.     *.BGI        - BGI driver files
  27.     GRLINK.MAK   - "make" file that builds DRIVERS.TPU, FONT.TPU, and
  28.                    finally GRLINK.EXE
  29.  
  30.   DIRECTIONS:
  31.   1. Run MAKE on the GRLINK.MAK file by typing the following command
  32.      at a DOS prompt:
  33.  
  34.        make -fgrlink.mak
  35.  
  36.      Using BINOBJ.EXE, this will first build .OBJ files out of the driver
  37.      files (*.BGI) and then call Turbo Pascal to compile DRIVERS.PAS.
  38.      Next, the font files (*.CHR) will be converted to .OBJs and
  39.      FONTS.PAS will be compiled. Finally, GRLINK.PAS will be compiled
  40.      (it uses DRIVERS.TPU and FONTS.TPU).
  41.  
  42.   2. Run GRLINK.EXE. It contains all the drivers and all the fonts, so it
  43.      will run on any system with a graphics card supported by the Graph
  44.      unit (CGA, EGA, EGA 64 K, EGA monochrome, Hercules monochrome,
  45.      VGA, MCGA, IBM 3270 PC and AT&T 6400).
  46.  
  47.   EXPLANATION
  48.  
  49.     GRLINK.PAS uses DRIVERS.TPU and FONTS.TPU in its uses statement:
  50.  
  51.       uses Drivers, Fonts;
  52.  
  53.     Then, it "registers" the drivers it intends to use (in this case,
  54.     all of them, so it will run on any graphics card). Then it registers
  55.     all of the fonts it will use (again all of them, just for demonstration
  56.     purposes) and finally it does some very modest graphics.
  57.  
  58.     You can easily modify GRLINK.PAS for your own use by commenting out
  59.     the calls to RegisterBGIdriver and RegisterBGIfont for drivers and
  60.     fonts that your program doesn't use.
  61.  
  62.     For a detailed explanation of registering and linking drivers and fonts,
  63.     refer to the RegisterBGIdriver and RegisterBGIfont descriptions in
  64.     GRAPH.DOC (on Disk III).
  65. }
  66.  
  67. uses Graph,   { library of graphics routines }
  68.      Drivers, { all the BGI drivers }
  69.      Fonts;   { all the BGI fonts }
  70. var
  71.   GraphDriver, GraphMode, Error : integer;
  72.  
  73. procedure Abort(Msg : string);
  74. begin
  75.   Writeln(Msg, ': ', GraphErrorMsg(GraphResult));
  76.   Halt(1);
  77. end;
  78.  
  79. begin
  80.   { Register all the drivers }
  81.   if RegisterBGIdriver(@CGADriverProc) < 0 then
  82.     Abort('CGA');
  83.   if RegisterBGIdriver(@EGAVGADriverProc) < 0 then
  84.     Abort('EGA/VGA');
  85.   if RegisterBGIdriver(@HercDriverProc) < 0 then
  86.     Abort('Herc');
  87.   if RegisterBGIdriver(@ATTDriverProc) < 0 then
  88.     Abort('AT&T');
  89.   if RegisterBGIdriver(@PC3270DriverProc) < 0 then
  90.     Abort('PC 3270');
  91.  
  92.  
  93.   { Register all the fonts }
  94.   if RegisterBGIfont(@GothicFontProc) < 0 then
  95.     Abort('Gothic');
  96.   if RegisterBGIfont(@SansSerifFontProc) < 0 then
  97.     Abort('SansSerif');
  98.   if RegisterBGIfont(@SmallFontProc) < 0 then
  99.     Abort('Small');
  100.   if RegisterBGIfont(@TriplexFontProc) < 0 then
  101.     Abort('Triplex');
  102.  
  103.   GraphDriver := Detect;                  { autodetect the hardware }
  104.   InitGraph(GraphDriver, GraphMode, '');  { activate graphics }
  105.   if GraphResult <> grOk then             { any errors? }
  106.   begin
  107.     Writeln('Graphics init error: ', GraphErrorMsg(GraphDriver));
  108.     Halt(1);
  109.   end;
  110.  
  111.   MoveTo(5, 5);
  112.   OutText('Drivers and fonts were ');
  113.   MoveTo(5, 20);
  114.   SetTextStyle(GothicFont, HorizDir, 4);
  115.   OutText('Built ');
  116.   SetTextStyle(SmallFont, HorizDir, 4);
  117.   OutText('into ');
  118.   SetTextStyle(TriplexFont, HorizDir, 4);
  119.   OutText('EXE ');
  120.   SetTextStyle(SansSerifFont, HorizDir, 4);
  121.   OutText('file!');
  122.   Rectangle(0, 0, GetX, GetY + TextHeight('file!') + 1);
  123.   Readln;
  124.   CloseGraph;
  125. end.
  126.