Liren Large Software Subsidy 9/09.iso/e/e065/1.ddi/DNNANCUM.INS

Text File | 1991-08-28 | 4.5 KB | 159 lines

inst4.0        ! 07-Aug-90  (dnnancum.ins)  DNNA InstaNet
!****************************************************************
!*                                *
!*    Digital Neural Network Architecture Builder        *
!*    with Norm-Cum-Delta Learning Rule            *
!****************************************************************

!    *** check that input / output PE count is non-zero

?&In    1
>bge    CheckOut
@Err    "DNNA MUST have at least one input PE"
:CheckOut
?&Out    1
>bge    OutOK
@Err    "DNNA MUST have at least one output PE"
:OutOK
?&Hd1    1
>bge    HidOK
@Err    "DNNA MUST have at least one Hidden Layer 1 PE"
:HidOK

!    *** Load the Control Strategy and LRS if needed

@LdCS    "backprop"        !control strategy
@LdLR    "ncum_hid"        !L/R schedule
@LdLR    "ncum_out"        !L/R schedule

=netn    "InstaNet (tm) Digital Neural Network Arch. version 2.0 07-Aug-90"
=DLnF    0            !learn  re-display off
=DRcF    0            !recall re-display off

!    *** Build the Input Layer ***

@LLdf                !load default layer to mi_layer structure
=LDln    "In"            !layer name
=Lpes    &In            !copy # of input PEs from menu
=Ltrn    "Linear"        !buffer
=x    100            !place to put layer on screen
=y     80
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd                !add the input layer

!    *** Build the first hidden Layer ***

@LLdf                !start with default layer again
=LDln    "Hidden 1"        !layer name
=Lpes    &Hd1            !Proper number of PEs
=Lsum    "DNNA"            !DNNA sum function
=Ltrn    "DNNA"            !DNNA transfer function
=Llrn    "Norm-Cum-Delta"    !Norm-Cum Delta learning rule
=Llrs    "ncum_hid"        !L/R Schedule
+y    60            !up higher on display
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd

!    *** Connect Hidden Layer to Bias & Input Layers ***

=SPEl    LayN            !current layer
@SlPE                !select it as destination (sb already)
=NPEl    -1            !near to bias term (source)
@NrPE
=cnwt    1.0            !connection weight
=cnty    WVar            !variable
=cnsc    WAbs            !absolute
@LCFl                !fully connect to bias element
=NPEl    0            !input layer
@NrPE
@LCFl                !fully connect to input layer
=n0    LayN            !save current layer for later

!    *** Build the Second hidden Layer ***

?&Hd2    0
>ble    NoHid2            !skip adding second hidden layer

@LLdf                !start with default layer again
=LDln    "Hidden 2"        !layer name
=Lpes    &Hd2            !Proper number of PEs
=Lsum    "DNNA"            !DNNA sum function
=Ltrn    "DNNA"            !DNNA transfer function
=Llrn    "Delta-Rule"        !Standard Delta learning rule
=Llrn    "Norm-Cum-Delta"    !Norm-Cum Delta learning rule
=Llrs    "ncum_hid"        !L/R Schedule
+y    60            !up higher on display
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd

!    *** Connect Hidden Layer 2 to Bias & Input Layers ***

=SPEl    LayN            !current layer
@SlPE                !select it as destination (sb already)
=NPEl    -1            !near to bias term (source)
@NrPE
@LCFl                !fully connect to bias element
=NPEl    n0            !previous layer
@NrPE
@LCFl                !fully connect to input layer
=n0    LayN            !save current layer for later
:NoHid2

!    *** Build the output layer & connect it to prior layer & bias term ***

@LLdf                !load default layer to mi_layer structure
=LDln    "Out"            !layer name
=Lpes    &Out            !copy # of input PEs from menu
=Lsum    "DNNA"            !DNNA sum function
=Ltrn    "DNNA"            !DNNA transfer function
=Llrn    "Delta-Rule"        !Standard  Delta learning rule
=Llrn    "Norm-Cum-Delta"    !Norm-Cum Delta learning rule
=Llrs    "ncum_out"        !L/R Schedule
+y    60
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd                !add the output layer
=n7    LayN            !save for stdprobe

=SPEl    LayN            !current layer
@SlPE                !select it as destination (sb already)
=NPEl    -1            !near to bias term (source)
@NrPE
@LCFl                !fully connect to bias element
=NPEl    n0            !previous layer
@NrPE
@LCFl                !fully connect to input layer

!    *** Select Control Strategy & L/R Schedule ***

@LLsl                !load super layer
=Lctl    "backprop"        !backprop control strategy
=Llrs    "ncum_out"        !backprop L/R Schedule
=Llnn    "train"            !name of learn input
=Lrcn    "test"            !name of recall output
#Incl    "stdioset.iif"        !standard I/O settings
=Lscl     -1.0            !input  low-value
=Loff     1.0            !input  high-value
=Llow     0.2            !output low-value
=Lhgh     0.8            !output high-value
=DLnN     1            !learn count for Check Points
=MWLF     1            !turn on weight limiting
=WtVl     0.99            !max value for weight limiting
@SVsl                !save it back
!
=n5    0.0
=n6    1.0
=n4    &Out
#Incl    "stdprobe.iif"        !Standard probe include file
!
=jogl    -.1            !lower limit for jog
=jogh    +.1            !upper limit for jog
=seed    257            !starting seed number
@seed                !set the seed
@Nini                !initialize the network

@LLsl                !load super layer
=Lepc     0            !set learn counter to zero
@SVsl                !save it back
@EOF