Liren Large Software Subsidy 9/09.iso/e/e065/1.ddi/BOLTZIO.INS

Text File | 1991-08-28 | 3.9 KB | 149 lines

inst4.0        ! 17-4-89  boltzio.ins
!****************************************************************
!*                                *
!*    Boltzman Network Generator - Input/Output version    *
!*                                *
!****************************************************************

!    *** check that input PE count is non-zero

?&In    1
>bge    CheckHid
@Err    "Boltzmann I/O model MUST have at least one input PE"
:CheckHid
?&Hd1    1
>bge    CheckOut
@Err    "Boltzmann I/O model MUST have at least one hidden PE"
:CheckOut
?&Out    1
>bge    OutOK
@Err    "Boltzmann I/O model MUST have at least one output PE"
:OutOK

!    *** Load the Control Strategy and LRS if needed

@LdCS    "boltzio"        !control strategy
@LdLR    "boltzman"        !L/R schedule

=netn    "InstaNet (tm) Boltzmann Network (I/O model) version 1.00 17-04-89"
=DLnF    0            !learn  re-display off
=DRcF    0            !recall re-display off

!    *** Build the Input Layer ***

@LLdf                !load default layer to mi_layer structure
=LDln    "In"            !layer name
=Lpes    &In            !copy # of input PEs from menu
=Ltrn    "StepFunction"        !transfer function
=x    100            !place to put layer on screen
=y     50
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd                !add the input layer
=n0    LayN            !track input layer

!    *** Build the Boltzmann Layer ***

@LLdf                !start with default layer again
=LDln    "Boltzmann"        !layer name
=Lpes    &In            !desired number of PEs
+Lpes    &Hd1
+Lpes    &Out
=Ltrn    "Boltzmann"        !transfer function
=Llrn    "Boltzmann"        !learning rule
=Llrs    "boltzman"        !L/R schedule
=LInL    0.0            !low initialization limit
=LInH    0.0            !high initialization limit
+y    170            !up higher on display
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd
=n1    LayN            !track Boltzmann layer

!    *** Connect input layer to Boltzmann layer ***

=SPEl    LayN            !current layer
@SlPE
=NPEl    n0            !input layer
@NrPE
=cnwt    1.0            !unit weight
=cnsc    WRel
=cnty    WSet
@LCCr                !connect corresponding items

!    *** Connect Boltzmann layer to itself ***

=NPEl    LayN
@NrPE
=cnwt    0.0            !zero weights
=cnty    WVar            !trainable
=cnsc    WAbs
@LCFl                !fully connect (except diagonal)

!    *** Connect the bias to the Boltzmann layer ***

=NPEl    -1
@NrPE
=cnwt    0.0            !zero weights
=cnty    WVar            !trainable
=cnsc    WAbs
@LCFl                !fully connect (except diagonal)

!    *** Build the Output Layer ***

@LLdf                !start with default layer again
=LDln    "Output"        !layer name
=Lpes    &Out            !desired number of PEs
=Ltrn    "StepFunction"        !transfer function
=LInL    0.0            !low initialization limit
=LInH    0.0            !high initialization limit
+y    60            !up higher on display
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd
=n7    LayN            !save for stdprobe
=n2    LayN            !track output layer

!    *** Connect the Boltzmann layer to the Output layer ***

=SPEl    LayN            !output layer
=SPEn    0
=NPEl    n1            !Boltzmann layer
=NPEn    &In
=cnwt    1.0            !set weight to 1.0
=cnty    WFix            !fixed weight
=cnsc    WRel            !relative connections
:B2OCn                !Boltzmann to output connections
@SlPE                !select next PE in output layer
@NrPE                !select next PE in Boltzmann layer
@PCon                !connect two PEs together
+SPEn    1            !next PE in output layer
?SPEn    &Out            !past the end?
>bge    EndB20            !Connection complete
+NPEn    1            !next PE in the Boltzmann layer
>br    B2OCn            !next connection
:EndB20

@LLsl                !load super layer
=Lctl    "boltzio"        !control strategy
=Llnn    "boltzman"        !name of learn input
=Lrcn    "boltzman"        !name of recall output
#Incl    "stdioset.iif"        !standard I/O settings
=Lax1    10            !nominal number of accumulations
=Lax2    10            !nominal number of firings per iteration
=Lax3    20            !nominal # of iterations for collecting stats
=Lscl    -1            !input  low-value
=Loff     1            !input  high-value
=Llow     0            !output low-value
=Lhgh     1            !output high-value
@SVsl                !save it back
!
=n5    0.0
=n6    1.0
=n4    &Out
#Incl    "stdprobe.iif"        !Standard probe include file
!
=jogl    -.1            !lower limit for jog
=jogh    +.1            !upper limit for jog
=seed    257            !starting seed number
@seed                !set the seed
@Nini                !initialize the network
@EOF