Liren Large Software Subsidy 9/09.iso/e/e065/1.ddi/ADALINE.INS

Text File | 1991-08-28 | 2.8 KB | 107 lines

inst4.0        !17:43 29-May-88  (adaline.ins)  Adaline Network Builder
!****************************************************************
!*                                *
!*    Adaline Network Generator                *
!*                                *
!****************************************************************

!    *** check that input / output PE count is non-zero

?&In    1
>bge    CheckOut
@Err    "Adaline MUST have at least one input PE"
:CheckOut
?&Out    1
>bge    OutOK
@Err    "Adaline MUST have at least one output PE"
:OutOK

!    *** Load the Control Strategy and LRS if needed

@LdCS    "adaline"        !control strategy
@LdLR    "adaline"        !L/R schedule

=netn    "InstaNet (tm) Adaline Network version 1.00 20-Jun-88"
=DLnF    0            !learn  re-display off
=DRcF    0            !recall re-display off

!    *** Build the Input Layer ***

@LLdf                !load default layer to mi_layer structure
=LDln    "In"            !layer name
=Lpes    &In            !copy # of input PEs from menu
!=Ltrn    "Signum"        !signum transfer function
=x    100            !place to put layer on screen
=y     80
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd                !add the input layer

!    *** Build the Adaline Layer ***

@LLdf                !start with default layer again
=LDln    "Adaline"        !adaline layer name
=Lpes    &Out            !same as the number of output PEs
=Ltrn    "Signum"        !transfer function
=Llrn    "Adaline"        !adaline learning rule
+y    80            !up higher on display
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd

!    *** Connect Adaline Layer to Bias & Input Layers ***

=SPEl    1            !current layer
@SlPE                !select it as destination (sb already)
=NPEl    -1            !near to bias term (source)
@NrPE
=cnwt    1.0            !connection weight
=cnty    WVar            !variable
=cnsc    WAbs            !absolute
@LCFl
=NPEl    0            !input layer
@NrPE
@LCFl

!    *** Build the output layer & connect it to prior layer ***

@LLdf                !load default layer to mi_layer structure
=LDln    "Out"            !layer name
=Lpes    &Out            !copy # of input PEs from menu
+y    80
#Incl    "stdnwgtf.iif"        !standard # weight fields
@LAdd                !add the output layer
=n7    LayN            !save for stdprobe
=SPEl    2            !output layer
@SlPE
=NPEl    1            !adaline layer
@NrPE
=cnty    WFix            !fixed weight
=cnsc    WRel
@LCCr                !connect corresponding

!    *** Select Control Strategy & L/R Schedule ***

@LLsl                !load super layer
=Lctl    "adaline"        !adaline control strategy
=Llrs    "adaline"        !adaline L/R Schedule
=Llnn    "adaline"        !name of learn input
=Lrcn    "adaline"        !name of recall output
#Incl    "stdioset.iif"        !standard I/O settings
=Lscl    -1            !input  low-value
=Loff     1            !input  high-value
=Llow    -1            !output low-value
=Lhgh     1            !output high-value
@SVsl                !save it back
!
=n5    -1.0
=n6    1.0
=n4    &Out
#Incl    "stdprobe.iif"        !Standard probe include file
!
=jogl    -.1            !lower limit for jog
=jogh    +.1            !upper limit for jog
=seed    257            !starting seed number
@seed                !set the seed
@Nini                !randomize the network

@EOF