home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c480 / 19.ddi / SAMPLES / TOOLHELP / THASM.AS_ / THASM.AS
Encoding:
Text File  |  1993-02-08  |  6.6 KB  |  210 lines
  1. ;***************************************************************************
  2. ;*  THASM.ASM
  3. ;*
  4. ;*      Assembly support routines for the TOOLHELPER sample program
  5. ;*
  6. ;***************************************************************************
  7.  
  8. ;** Set up values for cMacros
  9. ?PLM    =       1                       ;PASCAL-style parameter handling
  10. ?WIN    =       0                       ;No Windows prolog/epilog
  11.  
  12. ;** Symbols
  13. FAULT_1         EQU     2001
  14. FAULT_2         EQU     2002
  15. FAULT_3         EQU     2003
  16. FAULT_4         EQU     2004
  17. FAULT_5         EQU     2005
  18. FAULT_6         EQU     2006
  19. FAULT_7         EQU     2007
  20. FAULT_8         EQU     2008
  21.  
  22. .286c
  23.  
  24.         INCLUDE cMacros.INC
  25.         INCLUDE TOOLHELP.INC
  26.  
  27. sBegin  DATA
  28.  
  29. ODSTest DB      'THSample: Test Output Debug String', 0dh, 0ah, 0
  30.  
  31. sEnd
  32.  
  33. ;** Functions
  34. ?PLM = 0
  35. externNP MyCFaultHandler
  36. ?PLM = 1
  37. externFP TerminateApp
  38. externFP OutputDebugString
  39. externFP GetWindowWord
  40.  
  41. sBegin  CODE
  42.         ASSUMES cs,CODE
  43.  
  44. ;  Fault
  45. ;
  46. ;       Causes one of three faults:
  47. ;               FAULT_1 --> GP Fault
  48. ;               FAULT_2 --> Illegal opcode
  49. ;               FAULT_3 --> Divide by zero
  50. ;               FAULT_4 --> Int 1
  51. ;               FAULT_5 --> Int 3
  52. ;               FAULT_6 --> RIP
  53. ;               FAULT_7 --> OutputDebugString
  54. ;               FAULT_8 --> Stack Fault
  55.  
  56. cProc   Fault, <PUBLIC,NEAR>, <si,di,ds>
  57.         parmW   wType
  58. cBegin
  59.         mov     ax,wType                ;Get the type
  60.         cmp     ax,FAULT_1              ;GP Fault?
  61.         je      GPFault                 ;Yes
  62.         cmp     ax,FAULT_2              ;Illegal opcode?
  63.         je      IllOpcode               ;Yes
  64.         cmp     ax,FAULT_3              ;Divide by zero?
  65.         je      DivZero                 ;Yes
  66.         cmp     ax,FAULT_4              ;Int 1?
  67.         je      Int1
  68.         cmp     ax,FAULT_5              ;Int 3?
  69.         je      Int3
  70.         cmp     ax,FAULT_6              ;RIP?
  71.         je      Rip
  72.         cmp     ax,FAULT_7              ;ODS?
  73.         je      ODS
  74.         cmp     ax,FAULT_8              ;Stack Fault?
  75.         je      StackFault
  76.         jmp     F_End                   ;Not recognized, get out
  77.  
  78.         ;** Produce GP Fault
  79. GPFault:
  80.         mov     cs:[0],BYTE PTR 55h     ;Can't write to CS
  81.         jmp     F_End                   ;If restarted
  82.  
  83.         ;** Illegal opcode
  84. IllOpcode:
  85.         DB      0c4h                    ;LES Opcode
  86.         DB      0c0h                    ;  LES AX,AX (should make #UD Excep)
  87.         jmp     F_End                   ;In case it's not
  88.  
  89.         ;** Divide by zero
  90. DivZero:
  91.         xor     bx,bx                   ;Get a zero
  92.         div     bx                      ;Divide by it
  93.         jmp     F_End                   ;Done
  94.  
  95. Int1:   int     1                       ;Cause trace interrupt
  96.         jmp     F_End                   ;Get out
  97.  
  98. Int3:   int     3                       ;Cause software int
  99.         jmp     F_End
  100.  
  101. Rip:    mov     ax,-1                   ;Bad handle
  102.         cCall   GetWindowWord, <ax,ax>  ;Guaranteed RIP
  103.         jmp     F_End
  104.  
  105. ODS:    mov     ax,OFFSET ODSTest       ;Test string
  106.         cCall   OutputDebugString, <ds,ax>
  107.         jmp     F_End
  108.  
  109. StackFault:
  110.         mov     ax,ss:[bp+7fffh]        ;Causes stack fault
  111.         jmp     F_End
  112.  
  113. F_End:
  114.  
  115. cEnd
  116.  
  117.  
  118. ;  MyFaultHandler
  119. ;       Handles all faults passed to it.  Makes the processing ready
  120. ;       for a C function, then calls it.  The handler is reentrant
  121. ;       The entry frame looks like this:
  122. ;               ------------
  123. ;       SP--->  |  Ret IP  |  [SP + 00h]
  124. ;               |  Ret CS  |  [SP + 02h]
  125. ;               |    AX    |  [SP + 04h]
  126. ;               |Exception#|  [SP + 06h]
  127. ;               |  Handle  |  [SP + 08h]
  128. ;               |    IP    |  [SP + 0Ah]
  129. ;               |    CS    |  [SP + 0Ch]
  130. ;               |   Flags  |  [SP + 0Eh]
  131. ;               ------------
  132. ;
  133.  
  134. cProc   MyFaultHandler, <FAR,PUBLIC>
  135. cBegin  NOGEN
  136.  
  137.         push    bp                      ;Make a stack frame
  138.         mov     bp,sp
  139.         pusha                           ;Save all registers
  140.         push    ds
  141.         push    es
  142.  
  143.         ;** Get instance data segment and prepare for C call
  144.         mov     ds,ax                   ;Since this function uses
  145.                                         ;  MakeProcInstance(), AX has the
  146.                                         ;  DS value in it.
  147.  
  148.         ;** Call the C function:  It returns 0 to nuke the app,
  149.         ;*      1 to restart the instruction, 2 to chain on
  150.         ;*      The entry frame to the function looks like this:
  151.         ;*              ------------
  152.         ;*       BP---->|  Old BP  |  [BP + 00h] <-- Added by C routine
  153.         ;*              |    ES    |  [BP + 02h]
  154.         ;*              |    DS    |  [BP + 04h]
  155.         ;*              |    DI    |  [BP + 06h]
  156.         ;*              |    SI    |  [BP + 08h]
  157.         ;*              |    BP    |  [BP + 0Ah]
  158.         ;*              | Dummy SP |  [BP + 0Ch]
  159.         ;*              |    BX    |  [BP + 0Eh]
  160.         ;*              |    DX    |  [BP + 10h]
  161.         ;*              |    CX    |  [BP + 12h]
  162.         ;*              |    AX    |  [BP + 14h]
  163.         ;*   Old BP---->|Old,Old BP|  [BP + 16h]
  164.         ;*              |  Ret IP  |  [BP + 18h]
  165.         ;*              |  Ret CS  |  [BP + 1Ah]
  166.         ;*              |    AX    |  [BP + 1Ch]
  167.         ;*              |Exception#|  [BP + 1Eh]
  168.         ;*              |  Handle  |  [BP + 20h]
  169.         ;*              |    IP    |  [BP + 22h]
  170.         ;*              |    CS    |  [BP + 24h]
  171.         ;*              |   Flags  |  [BP + 26h]
  172.         ;*              ------------
  173.         ;**
  174.         cCall   MyCFaultHandler
  175.  
  176.         ;** Decode the return value
  177.         or      ax,ax                   ;Check for zero
  178.         jz      MFH_NukeApp             ;Nuke it
  179.         dec     ax                      ;Check for 1
  180.         jz      MFH_Restart             ;Restart instruction
  181.  
  182. MFH_ChainOn:
  183.         pop     es                      ;Chain on to next fault handler
  184.         pop     ds
  185.         popa
  186.         pop     bp
  187.         retf
  188.  
  189. MFH_Restart:
  190.         pop     es                      ;Clear stack
  191.         pop     ds
  192.         popa
  193.         pop     bp
  194.         add     sp,10                   ;Clear the return stuff
  195.         iret                            ;Restart instruction
  196.  
  197. MFH_NukeApp:
  198.         pop     es                      ;Clear stack
  199.         pop     ds
  200.         popa
  201.         pop     bp
  202.         add     sp,10                   ;Point to IRET frame
  203.         cCall   TerminateApp, <0,NO_UAE_BOX>
  204.  
  205. cEnd    NOGEN
  206.  
  207. sEnd
  208.  
  209.         END
  210.