home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_144 / 2.ddi / CLIBSRC3.ZIP / NEARHEAP.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  26.6 KB  |  604 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      NEARHEAP.ASM                                                 |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14.         LOCALS
  15.         INCLUDE _HEAP.INC
  16.  
  17. IF LDATA EQ false
  18.  
  19. ;-----------------------------------------------------------------------
  20. ; Memory Block Header (near heap)
  21. ;-----------------------------------------------------------------------
  22. ; Each block in the heap, whether allocated or free, has a header.
  23. ; For an allocated block, only the first two fields of the header are
  24. ; used. For a free block all eight bytes are used, thus the smallest
  25. ; possible block is the size of a free header.
  26. ;
  27. ; Field       Description
  28. ; ---------   ----------------------------------------------------------
  29. ; size        total size, in bytes, of this block (+1 if the block is in use)
  30. ; prev_real   pointer to the physically previous block in the heap
  31. ; prev_free   pointer to the logically previous free block
  32. ; next_free   pointer to the logically next free block
  33. ;
  34. ; Note that the size field is also used to indicate whether the block
  35. ; is allocated or free.  A doubly-linked queue is maintained of the
  36. ; free blocks and it is important to know that ordering of the blocks
  37. ; in this queue is logical rather than physical.  If there is only one
  38. ; free block on the heap prev_free and next_free point to itself.
  39. ;-----------------------------------------------------------------------
  40. Header          STRUC
  41. bsize           dw      ?
  42. prev_real       dw      ?
  43. prev_free       dw      ?
  44. next_free       dw      ?
  45.                 ENDS
  46.  
  47. ;-----------------------------------------------------------------------
  48. ; heapinfo structure (near heap)
  49. ;-----------------------------------------------------------------------
  50. ; Used by the heapwalk function.
  51. ; heapwalk accepts a pointer to a struct of this type.
  52. ; On entry, the pointer field contains the address of the previous
  53. ; memory block in the heap (NULL for the first call).  The next block
  54. ; in the heap is then found and its address is stored in the structure
  55. ; along with its size, in bytes, and a 'used' flag.
  56. ;-----------------------------------------------------------------------
  57. HeapInfo        STRUC
  58. hi_ptr          dw      ?
  59. hi_size         dw      ?
  60. hi_inuse        dw      ?
  61.                 ENDS
  62.  
  63. UsedHeaderSize  EQU     4
  64. FreeHeaderSize  EQU     8
  65.  
  66. ;-----------------------------------------------------------------------
  67. ; Only three variables are needed to efficiently manage the heap.
  68. ;-----------------------------------------------------------------------
  69. _DATA           SEGMENT WORD PUBLIC 'DATA'
  70.                 PUBLIC  __first,__last,__rover
  71.                 ALIGN   2
  72. __first         dw      0               ;pointer to the first block
  73. __last          dw      0               ;pointer to the last block
  74. __rover         dw      0               ;pointer to an arbitrary free block
  75. _DATA           ENDS
  76.  
  77. IF LPROG
  78.  EXTRADISP      equ     2         ; Allow for FAR returns when getting parms
  79. ELSE
  80.  EXTRADISP      equ     0
  81. ENDIF
  82.  
  83. DGROUP  GROUP   _DATA
  84.  
  85.                 EXTRN   ___brk:NEAR, ___sbrk:NEAR
  86. _TEXT           SEGMENT PUBLIC 'CODE'
  87.                 ASSUME CS:_TEXT,DS:DGROUP
  88.  
  89. ;-----------------------------------------------------------------------------
  90. ; C callable function to free a memory block
  91. ;-----------------------------------------------------------------------------
  92. ; Args:                 Pointer to the block to free (stack)
  93. ; Returns:              void
  94. ;-----------------------------------------------------------------------------
  95.                 PUBLIC  _free
  96. _free           PROC DIST
  97.                 push    si
  98.                 push    di
  99.                 mov     si,sp
  100.                 mov     bx,[si+(6+EXTRADISP)]   ;bx = first parameter passed
  101.                 sub     bx,UsedHeaderSize       ;bx = the address of the block to free
  102.                 jc      @@AllDone               ;skip if NULL
  103.                 cmp     bx,[__last]             ;is this the last block in the heap?
  104.                 je      @@lastBlock
  105. @@InnerBlock:
  106.                 call    FreeInnerBlock          ;free the inner block
  107.                 jmp     short @@AllDone
  108. @@LastBlock:
  109.                 call    FreeLastBlock           ;free the last block
  110. @@AllDone:
  111.                 pop     di                      ;all done
  112.                 pop     si
  113.                 ret
  114. _free           ENDP
  115.  
  116. ;-----------------------------------------------------------------------------
  117. ; Frees the last block on the heap
  118. ; free helper function
  119. ;-----------------------------------------------------------------------------
  120. ; Args:                 Pointer to the block (bx)
  121. ; Returns:              void
  122. ;-----------------------------------------------------------------------------
  123. FreeLastBlock   PROC NEAR
  124.                 cmp     [__first],bx            ;freeing the ONLY block?
  125.                 je      @@KillHeap
  126.                 mov     si,[bx.prev_real]       ;si = next-to-last block
  127.                 test    BYTE PTR [si.bsize],01h
  128.                 jz      @@PreviousBlockIsFree
  129. @@PreviousBlockIsUsed:
  130.                 mov     __last,si
  131.                 jmp     short @@ResetBreak      ;done!
  132. @@PreviousBlockIsFree:
  133.                 cmp     si,[__first]            ;is the previous block the
  134.                 je      @@ResetHeap             ;first block in the heap?
  135.  
  136.                 mov     bx,si                   ;remove the next-to-last block
  137.                 call    PullFreeBlock           ;from the free-block queue
  138.                 mov     ax,[bx.prev_real]
  139.                 mov     __last,ax
  140.                 jmp     short @@ResetBreak      ;done!
  141. @@ResetHeap:
  142.                 mov     bx,si
  143. ;we are freeing the only block so reset the break level and kill the heap
  144. @@KillHeap:
  145.                 xor     ax,ax
  146.                 mov     __first,ax              ;clear variables
  147.                 mov     __last,ax
  148.                 mov     __rover,ax
  149. @@ResetBreak:
  150.                 push    bx
  151.                 call    ___brk                  ;reset the break level
  152.                 pop     bx                      ;cleanup stack
  153.                 ret
  154. FreeLastBlock   ENDP
  155.  
  156. ;-----------------------------------------------------------------------------
  157. ; Frees an interior block from within the heap
  158. ; free helper function
  159. ;-----------------------------------------------------------------------------
  160. ; Args:                 Pointer to the block (bx)
  161. ; Returns:              void
  162. ;-----------------------------------------------------------------------------
  163. FreeInnerBlock  PROC NEAR
  164.                 dec     WORD PTR [bx.bsize]     ;mark the block as free
  165.                 cmp     bx,[__first]            ;first block?
  166.                 je      @@PreviousBlockIsUsed
  167.                 mov     si,[bx.prev_real]       ;get the previous block (si)
  168.                 mov     ax,[si.bsize]           ;is the previous block free?
  169.                 test    al,01h
  170.                 jnz     @@PreviousBlockIsUsed
  171. ; join this block to the previous block
  172. @@PreviousBlockIsFree:
  173.                 add     ax,[bx.bsize]           ;add the size of this block to
  174.                 mov     [si.bsize],ax           ;the size of the previous block
  175.                 mov     di,[bx.bsize]           ;get the next block (di)
  176.                 add     di,bx
  177.                 mov     [di.prev_real],si       ;adjust the prev_real pointer
  178.                 mov     bx,si                   ;set up the current block
  179.                 jmp     SHORT @@CheckNextBlock
  180. @@PreviousBlockIsUsed:
  181.                 call    InsertFreeBlock         ;add it to the free queue
  182. @@CheckNextBlock:
  183.                 mov     di,[bx.bsize]           ;get the next block (di)
  184.                 add     di,bx
  185.                 mov     ax,[di.bsize]           ;is the next block free?
  186.                 test    al,01h
  187.                 jz      JoinFreeBlocks          ;join this block to the next
  188. @@AllDone:
  189.                 ret                             ;all done
  190. FreeInnerBlock  ENDP
  191.  
  192. ;-----------------------------------------------------------------------------
  193. ; Joins two physically adjacent free blocks together
  194. ; free helper function
  195. ;-----------------------------------------------------------------------------
  196. ; Args:                 Pointer to the lower block (bx)
  197. ;                       Pointer to the upper block (di)
  198. ;                       Size of the upper block, in bytes (ax)
  199. ; Returns:              void
  200. ; Registers destroyed:  ax si di
  201. ; This routine falls through to PullFreeBlock
  202. ;-----------------------------------------------------------------------------
  203. JoinFreeBlocks  PROC NEAR
  204.                 add     [bx.bsize],ax           ;adjust the size of the lower block
  205.                 mov     si,di                   ;si = the next block after di
  206.                 add     si,ax
  207.                 mov     [si.prev_real],bx       ;adjust the link
  208.                 mov     bx,di
  209. ;;;;            jmp     SHORT PullFreeBlock     ;eliminate the upper block
  210. JoinFreeBlocks  ENDP
  211.  
  212. ;-----------------------------------------------------------------------------
  213. ; Removes a block from the free block queue
  214. ; free helper function
  215. ; malloc helper function
  216. ;-----------------------------------------------------------------------------
  217. ; Args:                 Pointer to the block (bx)
  218. ; Returns:              void
  219. ;-----------------------------------------------------------------------------
  220. PullFreeBlock   PROC NEAR
  221.                 mov     di,[bx.next_free]       ;di = the next free block
  222.                 cmp     bx,di                   ;removing the last free block?
  223.                 je      @@NoFreeBlocks
  224.                 mov     __rover,di
  225.                 mov     si,[bx.prev_free]       ;si = previous free block
  226.                 mov     [di.prev_free],si       ;adjust the links
  227.                 mov     [si.next_free],di
  228.                 ret                             ;all done
  229. @@NoFreeBlocks:
  230.                 mov     __rover,0
  231.                 ret                             ;all done
  232. PullFreeBlock   ENDP
  233.  
  234. ;-----------------------------------------------------------------------------
  235. ; Inserts a block into the free block queue
  236. ; free helper function
  237. ;-----------------------------------------------------------------------------
  238. ; Args:                 Pointer to the block (bx)
  239. ; Returns:              void
  240. ;-----------------------------------------------------------------------------
  241. InsertFreeBlock PROC NEAR
  242.                 mov     si,[__rover]            ;si = rover pointer
  243.                 or      si,si                   ;no free blocks?
  244.                 jz      @@FirstFreeBlock
  245. @@AnotherFreeBlock:
  246.                 mov     di,[si.next_free]       ;di = free block after rover
  247.                 mov     [si.next_free],bx       ;adjust links
  248.                 mov     [di.prev_free],bx
  249.                 mov     [bx.next_free],di
  250.                 mov     [bx.prev_free],si
  251.                 ret
  252. @@FirstFreeBlock:
  253.                 mov     __rover,bx
  254.                 mov     [bx.prev_free],bx
  255.                 mov     [bx.next_free],bx
  256.                 ret
  257. InsertFreeBlock ENDP
  258.  
  259.  
  260. ;-----------------------------------------------------------------------------
  261. ; C callable function to allocates a given number of bytes from the heap
  262. ;-----------------------------------------------------------------------------
  263. ; Args:                 Number of bytes requested (stack)
  264. ; Returns:              Address of the first byte of user space available
  265. ;                       from the heap if successful (ax)
  266. ;                       NULL if failure (ax)
  267. ;-----------------------------------------------------------------------------
  268.                 PUBLIC  _malloc
  269. _malloc         PROC DIST
  270.                 push    si                      ;should be on an odd address
  271.                 push    di
  272.  
  273.                 mov     si,sp
  274.                 mov     ax,[si+(6+EXTRADISP)]   ;ax = number of bytes requested
  275.                 or      ax,ax                   ;does he want zero bytes?
  276.                 jz      @@AllDone
  277.  
  278.                 add     ax,UsedHeaderSize+1     ;add the header size
  279.                 jc      @@NoCanDo               ;was size too great?
  280.                 and     ax,0fffeh               ;force a word boundary
  281.                 cmp     ax,FreeHeaderSize
  282.                 jae     @@BigEnough
  283.                 mov     ax,FreeHeaderSize
  284. @@BigEnough:
  285.                 cmp     [__first],0             ;do we have a heap yet?
  286.                 jz      @@BuildHeap
  287.  
  288.                 mov     bx,[__rover]            ;bx = rover pointer
  289.                 or      bx,bx                   ;are there any free blocks at all?
  290.                 jz      @@AddToHeap
  291.                 mov     dx,bx                   ;dx = rover pointer
  292. @@SearchHeap:
  293.                 cmp     [bx.bsize],ax           ;big enough to use at all?
  294.                 jae     @@AllocateBlock
  295. @@TooSmall:
  296.                 mov     bx,[bx.next_free]       ;move to the next free block
  297.                 cmp     bx,dx                   ;at the end of the list?
  298.                 jne     @@SearchHeap
  299. @@AddToHeap:
  300.                 call    ExtendHeap
  301.                 jmp     SHORT @@AllDone
  302. @@DivideFreeBlock:
  303.                 call    AllocatePartialBlock
  304.                 jmp     SHORT @@AllDone
  305. @@BuildHeap:
  306.                 call    CreateHeap
  307.                 jmp     SHORT @@AllDone
  308. @@NoCanDo:
  309.                 xor     ax,ax
  310.                 jmp     SHORT @@AllDone
  311. @@AllocateBlock:
  312.                 mov     si,ax                   ;si = smallest divisible block size
  313.                 add     si,FreeHeaderSize
  314.                 cmp     [bx.bsize],si           ;big enough to break up?
  315.                 jae     @@DivideFreeBlock
  316.                 call    PullFreeBlock           ;remove it from the free-block queue
  317.                 inc     [bx.bsize]              ;mark it as allocated
  318.                 mov     ax,bx
  319.                 add     ax,UsedHeaderSize
  320. @@AllDone:
  321.                 pop     di                      ;all done
  322.                 pop     si
  323.                 ret
  324. _malloc         ENDP
  325.  
  326. ;-----------------------------------------------------------------------------
  327. ; Creates a heap from scratch
  328. ; malloc helper function
  329. ;-----------------------------------------------------------------------------
  330. ; Args:                 Number of bytes for the first block requested (ax)
  331. ; Returns:              Address of the first byte of user space available
  332. ;                       from the heap if successful (ax)
  333. ;                       NULL if failure (ax)
  334. ;-----------------------------------------------------------------------------
  335. CreateHeap      PROC NEAR
  336.                 push    ax                      ;save the size
  337.  
  338.                 xor     ax,ax                   ;align the heap on word
  339.                 push    ax
  340.                 push    ax
  341.                 call    ___sbrk                 ;retrieve the break level
  342.                 pop     bx                      ;cleanup stack
  343.                 pop     bx
  344.                 and     ax,0001h
  345.                 jz      @@Aligned
  346.                 xor     dx,dx
  347.                 push    dx
  348.                 push    ax
  349.                 call    ___sbrk                 ;align the heap
  350.                 pop     bx                      ;cleanup stack
  351.                 pop     bx
  352. @@Aligned:
  353.                 pop     ax                      ;retrieve and save the size
  354.                 push    ax
  355.  
  356.                 xor     bx,bx                   ;convert size request from
  357.                 push    bx                      ;unsigned int to signed long
  358.                 push    ax
  359.                 call    ___sbrk                 ;adjust the break level
  360.                 pop     bx                      ;cleanup stack
  361.                 pop     bx
  362.                 cmp     ax,-1                   ;failure?
  363.                 je      @@NoRoom
  364.                 mov     bx,ax                   ;bx = new block
  365.                 mov     __first,bx              ;save pointers
  366.                 mov     __last,bx
  367.                 pop     ax                      ;retrieve the size
  368.                 inc     ax                      ;mark it as allocated
  369.                 mov     [bx.bsize],ax
  370.                 add     bx,UsedHeaderSize
  371.                 mov     ax,bx
  372.                 ret
  373. @@NoRoom:
  374.                 pop     bx                      ;clear the size from the stack
  375.                 xor     ax,ax
  376.                 ret
  377. CreateHeap      ENDP
  378.  
  379. ;-----------------------------------------------------------------------------
  380. ; Attempts to extend the heap.
  381. ; malloc helper function
  382. ;-----------------------------------------------------------------------------
  383. ; Args:                 Number of bytes for the block requested (ax)
  384. ; Returns:              Address of the first byte of user space available
  385. ;                       from the heap if successful (ax)
  386. ;                       NULL if failure (ax)
  387. ;-----------------------------------------------------------------------------
  388. ExtendHeap      PROC NEAR
  389.                 push    ax                      ;save the size
  390.                 xor     bx,bx                   ;convert size request from
  391.                 push    bx                      ;unsigned int to signed long
  392.                 push    ax
  393.                 call    ___sbrk                 ;adjust the break level
  394.                 pop     bx                      ;cleanup stack
  395.                 pop     bx
  396.                 cmp     ax,-1                   ;failure?
  397.                 je      @@NoRoom
  398.                 mov     bx,ax                   ;bx = new block
  399.                 mov     ax,[__last]             ;ax = next-to-the-last block
  400.                 mov     [bx.prev_real],ax
  401.                 mov     __last,bx               ;update last-block pointer
  402.                 pop     ax                      ;retrieve the size
  403.                 inc     ax                      ;mark it as allocated
  404.                 mov     [bx.bsize],ax
  405.                 add     bx,UsedHeaderSize
  406.                 mov     ax,bx
  407.                 ret
  408. @@NoRoom:       pop     ax                      ;retrieve the size
  409.                 xor     ax,ax
  410.                 ret
  411. ExtendHeap      ENDP
  412.  
  413. ;-----------------------------------------------------------------------------
  414. ; Divides a free block into two pieces.
  415. ; malloc helper function
  416. ;-----------------------------------------------------------------------------
  417. ; Args:                 Number of bytes for the block requested (ax)
  418. ;                       Pointer of the block to divide (bx)
  419. ; Returns:              Address of the first byte of user space available
  420. ;                       from the heap (ax)
  421. ;-----------------------------------------------------------------------------
  422. AllocatePartialBlock    PROC NEAR
  423.                 sub     [bx.bsize],ax           ;make room!
  424.                 mov     si,bx                   ;si = new block address
  425.                 add     si,[bx.bsize]
  426.                 mov     di,si                   ;di = the block after the new block
  427.                 add     di,ax
  428.                 inc     ax
  429.                 mov     [si.bsize],ax
  430.                 mov     [si.prev_real],bx
  431.                 mov     [di.prev_real],si
  432.                 add     si,UsedHeaderSize
  433.                 mov     ax,si
  434.                 ret
  435. AllocatePartialBlock    ENDP
  436.  
  437. ;-----------------------------------------------------------------------------
  438. ; Attempts to expand a block, relocating it if necessary
  439. ; realloc helper function
  440. ;-----------------------------------------------------------------------------
  441. ; Args:                 Pointer to the old block (bx)
  442. ;                       Size of the block (cx)
  443. ;                       Number of bytes requested (ax)
  444. ; Returns:              Address of the first byte of user space available
  445. ;                       from the heap if successful (bx)
  446. ;                       NULL if failure (bx)
  447. ;-----------------------------------------------------------------------------
  448.  
  449. ExpandBlock     PROC NEAR
  450.                 mov     bp,sp
  451.                 push    bx                      ;[bp-2] = old block
  452.                 push    ax                      ;[bp-4] = new size
  453.                 push    cx                      ;[bp-6] = old block size
  454.                 push    ax
  455.                 call    _malloc                 ;ax = data area of new block
  456.                 pop     bx                      ;cleanup stack
  457.                 mov     bx,ax
  458.                 or      ax,ax
  459.                 jz      @@AllDone               ;malloc failed
  460. @@MallocOK:
  461.                 push    ds                      ;move the data to the new block
  462.                 pop     es
  463.                 cld
  464.                 mov     di,ax                   ;di = data area of new block
  465.                 mov     si,[bp-2]               ;si = old block
  466.                 mov     cx,[si.bsize]           ;cx = old block size
  467.                 add     si,UsedHeaderSize       ;si = data area of old block
  468.                 push    si                      ;save for call to _free
  469.                 sub     cx,UsedHeaderSize+1     ;cx = number of bytes in old data area
  470. @@MoveIt:
  471.                 shr     cx,1                    ;cx = number of words in data area
  472.                 rep
  473.                 movsw
  474.                 mov     [bp-2],ax               ;save data area of new block in scratch area
  475.                 call    _free
  476.                 pop     bx                      ;cleanup stack
  477.                 mov     bx,[bp-2]
  478. @@AllDone:
  479.                 add     sp,6
  480.                 ret
  481. ExpandBlock     ENDP
  482.  
  483. ;-----------------------------------------------------------------------------
  484. ; Shrinks a block
  485. ; realloc helper function
  486. ;-----------------------------------------------------------------------------
  487. ; Args:                 Pointer to the block (bx)
  488. ;                       Size of the block (cx)
  489. ;                       Normalized number of bytes requested (dx)
  490. ; Returns:              Address of the first byte of user space available
  491. ;                       from the heap if successful (bx)
  492. ;-----------------------------------------------------------------------------
  493.  
  494. ShrinkBlock     PROC NEAR
  495.                 mov     ax,dx                   ;ax = requested block size
  496.                 add     dx,FreeHeaderSize
  497.                 cmp     dx,cx
  498.                 ja      @@AllDone
  499.                 mov     dx,cx                   ;dx = old block size
  500. @@DivideTheBlock:
  501.                 cmp     bx,[__last]             ;last block in the heap?
  502.                 jne     @@InnerBlock
  503. @@LastBlock:
  504.                 mov     [bx.bsize],ax
  505.                 inc     [bx.bsize]
  506.                 add     ax,bx
  507.                 push    bx                      ;save the old block
  508.                 push    ax
  509.                 call    ___brk                  ;reset the break level
  510.                 pop     bx                      ;cleanup stack
  511.                 pop     bx                      ;restore old block
  512.                 jmp     SHORT @@AllDone
  513. @@InnerBlock:
  514.                 mov     di,bx
  515.                 add     di,ax                   ;di = new (free) block
  516.                 mov     [di.prev_real],bx
  517.                 sub     dx,ax                   ;dx = size of new (free) block
  518.                 sub     [bx.bsize],dx
  519.                 mov     si,di                   ;si = next block after the new one
  520.                 add     si,dx
  521.                 mov     [si.prev_real],di       ;adjust the link
  522.                 inc     dx                      ;mark it as used
  523.                 mov     [di.bsize],dx
  524.                 mov     cx,bx                   ;save the old block
  525.                 mov     bx,di
  526.                 call    FreeInnerBlock
  527.                 mov     bx,cx                   ;restore old block
  528. @@AllDone:
  529.                 add     bx,UsedHeaderSize
  530.                 ret
  531. ShrinkBlock     ENDP
  532.  
  533. ;-----------------------------------------------------------------------------
  534. ; Attempts to reallocate a block
  535. ;-----------------------------------------------------------------------------
  536. ; Args:                 Pointer to the old block (stack)
  537. ;                       Number of bytes requested (stack)
  538. ; Returns:              Address of the first byte of user space available
  539. ;                       from the heap if successful (ax)
  540. ;                       NULL if failure (ax)
  541. ;-----------------------------------------------------------------------------
  542.                 PUBLIC  _realloc
  543. _realloc        PROC DIST
  544.                 push    si
  545.                 push    di
  546.                 push    bp
  547.                 mov     bp,sp
  548.  
  549.                 mov     bx,[bp+(8+EXTRADISP)]   ;bx = pointer to the block to realloc
  550.                 mov     ax,[bp+(10+EXTRADISP)]  ;ax = number of bytes requested
  551.  
  552.                 or      ax,ax                   ;does he really want 0 bytes???
  553.                 jz      @@FreeIt                ;let's give him what he wants!
  554.  
  555.                 or      bx,bx                   ;did we get a NULL pointer?
  556.                 jz      @@MallocIt              ;OK, try to malloc it
  557.  
  558.                 sub     bx,UsedHeaderSize       ;make bx = start of block
  559.  
  560.                 mov     cx,[bx.bsize]           ;cx = size of block
  561.                 dec     cx
  562.                 mov     dx,ax
  563.  
  564.                 add     dx,UsedHeaderSize+1     ;add the header size and
  565.                 and     dx,0fffeh               ;force a word boundary
  566.                 cmp     dx,FreeHeaderSize
  567.                 jae     @@BigEnough
  568.                 mov     dx,FreeHeaderSize
  569. @@BigEnough:
  570.                 cmp     cx,dx
  571.                 jb      @@ExpandIt
  572.                 ja      @@ShrinkIt
  573. @@NoChange:
  574.                 add     bx,UsedHeaderSize
  575.                 jmp     SHORT @@Resized
  576. @@ShrinkIt:
  577.                 call    ShrinkBlock
  578.                 jmp     SHORT @@Resized
  579. @@ExpandIt:
  580.                 call    ExpandBlock
  581. @@Resized:
  582.                 mov     ax,bx
  583.                 jmp     SHORT @@AllDone
  584. @@MallocIt:
  585.                 push    ax
  586.                 call    _malloc
  587.                 jmp     SHORT @@Cleanup
  588. @@FreeIt:
  589.                 push    bx
  590.                 call    _free
  591.                 xor     ax, ax
  592. @@Cleanup:
  593.                 pop     bx                      ;cleanup stack
  594. @@AllDone:
  595.                 pop     bp                      ;all done
  596.                 pop     di
  597.                 pop     si
  598.                 ret
  599. _realloc        ENDP
  600.                 ENDS
  601. ENDIF
  602.  
  603.                 END
  604.