home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_144 / 1.ddi / WINLBSRC.ZIP / WINMEM.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  3.3 KB  |  139 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      WINMEM.ASM -- Windows memory suballocator helper functions   |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1991, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14.         locals
  15.  
  16.         public __RLS_TEMP_BLOCK
  17.         public __GET_TEMP_BLOCK
  18.         public __SIZ_TEMP_BLOCK
  19.  
  20.         extrn   GLOBALALLOC:far
  21.         extrn   GLOBALFREE:far
  22.  
  23.         extrn   GLOBALLOCK:far
  24.         extrn   GLOBALUNLOCK:far
  25.  
  26.         extrn   GLOBALHANDLE:far
  27.         extrn   GLOBALSIZE:far
  28.  
  29.         extrn   __WinAllocFlag:word
  30.  
  31.         GMEM_MOVEABLE       equ 2
  32.  
  33.  
  34. Code_Seg@
  35.  
  36. __GET_TEMP_BLOCK  proc    far
  37.  
  38. ;
  39. ; Function __GET_TEMP_BLOCK: allocate a memory block
  40. ;
  41. ; Inputs:
  42. ;       DX:AX   =       size of block to allocate
  43. ; Outputs:
  44. ;       DX:AX   =       address of block
  45.  
  46.         local   Temp:word=STACKFRAMESIZE
  47.  
  48.         push    bp
  49.         mov     bp, sp
  50.         sub     sp, STACKFRAMESIZE
  51.  
  52.         mov     [Temp], ax
  53.  
  54.         mov     ax, __WinAllocFlag
  55.         or      ax, GMEM_MOVEABLE
  56.         push    ax              ;GLOBALALLOC flags
  57.  
  58.         mov     ax, [Temp]      ;lower 16-bits of size
  59.         push    dx              ;push 32-bit size
  60.         push    ax
  61.  
  62.         call    GLOBALALLOC     ;allocate block.  ax = handle
  63.         or      ax, ax          ;error allocating?
  64.         jz      @@Error
  65.         push    ax
  66.         call    GLOBALLOCK      ;dx:ax is pointer to block
  67.         ;; check our assumption that offsets are always zero
  68.         or      ax, ax          ;zero offset
  69.         jnz     @@Error         ; nope, return NULL
  70.  
  71. @@Exit:
  72.         mov     sp, bp
  73.         pop     bp
  74.         ret
  75.  
  76. @@Error:
  77.         xor     dx, dx
  78.         jmp     @@Exit
  79.  
  80. __GET_TEMP_BLOCK  endp
  81.  
  82. __RLS_TEMP_BLOCK  proc    far
  83.  
  84. ;
  85. ; Function __RLS_TEMP_BLOCK: free a memory block
  86. ;
  87. ; Inputs:
  88. ;       ES:DI   =       block address
  89. ; Outputs:
  90. ;       none
  91. ; Assumptions:
  92. ;       DI = 0
  93.  
  94.         push    es              ;selector of block
  95.         call    GLOBALHANDLE    ;ax = handle of block
  96.         or      ax, ax          ;no such block?
  97.         jz      @@Error         ; yes
  98.  
  99.         push    ax              ;push handle for GLOBALFREE
  100.         push    ax              ;push handle for GLOBALUNLOCK
  101.         call    GLOBALUNLOCK    ;unlock block
  102.         call    GLOBALFREE      ;free block
  103. @@Error:
  104.         ;; No block was found with the given address.  Just return.
  105.         ret
  106.  
  107. __RLS_TEMP_BLOCK  endp
  108.  
  109. __SIZ_TEMP_BLOCK  proc    far
  110.  
  111. ;
  112. ; Function __SIZ_TEMP_BLOCK: Return the size of an allocated block.
  113. ;
  114. ; Inputs:
  115. ;       ES:DI   =       block address
  116. ; Outputs:
  117. ;       DX:AX   =       block size
  118. ; Assumptions:
  119. ;       DI = 0
  120.  
  121.         push    es              ;selector of block
  122.         call    GLOBALHANDLE    ;ax = handle of block
  123.         or      ax, ax          ;no such block?
  124.         jz      @@Error         ; yes
  125.         push    ax              ;handle of block
  126.         call    GLOBALSIZE      ;dx:ax is size of block
  127.         ret
  128.  
  129. @@Error:
  130.         ;; Not much to do besides return 0.
  131.         xor     dx, dx
  132.         ;; ax already zero
  133.         ret
  134.  
  135. __SIZ_TEMP_BLOCK  endp
  136.  
  137. Code_EndS@
  138.         end
  139.