home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_144 / 1.ddi / MATHSRC.ZIP / FBSTP.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  6.9 KB  |  302 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      FBSTP.ASM                                                    |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         include rules.asi
  13.  
  14.         emul            ; generated emulated instructions
  15.  
  16. ld_temp        STRUC
  17.         ld_fraction     dw      ?
  18.                         dw      ?
  19.                         dw      ?
  20.                         dw      ?
  21.         ld_exponent     dw      ?
  22. ld_temp ENDS
  23.  
  24.  
  25. Code_Seg@
  26.  
  27. ; void _fbstp  ( long double z, short *packedDecimal)
  28.  
  29. ; This is a helper function for __xcvt() used only on Windows,
  30. ; which currently doesn't emulate the FBSTP instruction.
  31. ;
  32. ; It pops and converts the floating point number on the top of the x87
  33. ; stack to a packed decimal integer, storing the result at ES:DI.
  34.  
  35. ; int exp;              /* exponent part of z */
  36. ; short frac[4];        /* fractional part of z */
  37. ; short res[5]          /* packed BCD number */
  38.  
  39. ; void PutFourDigits ( int rem, int posn )
  40.  
  41. ;     res.digits [posn] = rem % 10;
  42. ;     rem = rem / 10;
  43. ;     res.digits [posn+1] = rem % 10;
  44. ;     rem = rem / 10;
  45. ;     res.digits [posn+2] = rem % 10;
  46. ;     res.digits [posn+3] = rem / 10;
  47.  
  48. PutFourDigits   PROC    ;  rem in DX, posn in DI
  49.  
  50.         push    ax
  51.         push    cx
  52.  
  53.         mov     al, 100
  54.         mov     cl, 4
  55.         xchg    ax, dx
  56.  
  57.         div     dl
  58.         mov     dl, ah
  59.         aam                     ; AH, AL = AL DIV 10, AL MOD 10
  60.         shl     ah, cl
  61.         or      ah, al
  62.         xchg    ax, dx
  63.         aam
  64.         shl     ah, cl
  65.         or      al, ah
  66.         mov     ah, dh
  67.         stosw
  68.  
  69.         pop     cx
  70.         pop     ax
  71.         ret
  72.  
  73. PutFourDigits   ENDP
  74.  
  75.  
  76. ; exp  = z.exp;
  77. ; frac = z.frac;
  78.  
  79. ; if (exp < 1) res = 0;
  80.  
  81. ; else if (exp > 60) res = +infinity;
  82.  
  83. ; else
  84. ;     while (exp < 64)
  85. ;         frac = frac DIV 2;
  86. ;         exp  = exp + 1;
  87.  
  88. ;     frac = frac + carry; /* rounding */
  89.  
  90. ;     res = 0;
  91.  
  92. ;     PutFourDigits (frac % 10000, 0);
  93. ;     frac = frac / 10000;
  94. ;     PutFourDigits (frac % 10000, 4);
  95. ;     frac = frac / 10000;
  96. ;     PutFourDigits (frac % 10000, 8);
  97. ;     frac = frac / 10000;
  98. ;     PutFourDigits (frac % 10000, 12);
  99. ;     frac = frac / 10000;
  100.  
  101. ;     res.digits [16] = frac % 10;
  102. ;     res.digits [17] = frac / 10;
  103.  
  104. ;     res.sign = z.sign;
  105.  
  106. ;     return res;
  107.  
  108.         public  __fbstp
  109. __fbstp PROC    NEAR
  110.  
  111. ; Convert floating point value on TOS to packed BCD at ES:DI
  112.  
  113.         push    bp
  114.         mov     bp, sp
  115.         push    si                      ; save SI
  116.         push    di                      ; ES:DI points to result
  117. po?zPtr equ     ([bp - 4].w0)
  118.  
  119.         cld                             ; forward string direction
  120.  
  121. ; exp  = z.exp;
  122. ; frac = z.frac;
  123.  
  124.         FSTP    tbyte ptr es:[di]       ; value is converted in place
  125.         FWAIT
  126.         mov     ax, es:[di].ld_exponent
  127.         and     ax, 07fffh              ; remove sign bit
  128.         sub     ax, 03ffeh              ; subtract (bias+1)
  129.         mov     bx, es:[di].ld_fraction.w0
  130.         mov     cx, es:[di].ld_fraction.w1
  131.         mov     dx, es:[di].ld_fraction.w3
  132.         mov     si, es:[di].ld_fraction.w2
  133.  
  134.  
  135. ; if (exp < 1)
  136. ;    res = 0
  137. ;
  138. ; /* will the result exceed 999,999,999,999,999,999 ? */
  139. ; else (z > [3C, DE0B 6B3A 763F FFF0])
  140. ;    res = +infinity
  141.  
  142.         cmp     ax, 0
  143.         jl      po@underflowJmp
  144.  
  145.         sub     ax, 3Ch
  146.         jl      po@inRange
  147.         jg      po@overflowJmp
  148.         cmp     dx, 0DE0Bh
  149.         jb      po@inRange
  150.         ja      po@overflowJmp
  151.         cmp     si, 06B3Ah
  152.         jb      po@inRange
  153.         ja      po@overflowJmp
  154.         cmp     cx, 0763Fh
  155.         jb      po@inRange
  156.         ja      po@overflowJmp
  157.         cmp     bx, 0FFF0h
  158.         ja      po@overflowJmp
  159.  
  160.  
  161. ; else
  162. ;     while (exp < 64)
  163. ;         frac = frac / 2;
  164. ;         exp  = exp + 1;
  165.  
  166. po@inRange:
  167.         mov     ah, 0                           ; excess precision for rounding
  168.         sub     al, 4
  169.  
  170. po@wordAlign:
  171.         add     al, 16
  172.         jg      po@bitAlign
  173.  
  174.         mov     ah, bh
  175.         mov     bx, cx
  176.         mov     cx, si
  177.         mov     si, dx
  178.         sub     dx, dx
  179.         jmp     po@wordAlign
  180.  
  181. ;----
  182. po@underflowJmp:        jmp     short   po@underflow
  183. po@overflowJmp:         jmp     short   po@overflow
  184. ;----
  185.  
  186. po@bitAlign:
  187.         sub     al, 16
  188.         jnl     po@aligned
  189. po@anotherBit:
  190.         shr     dx, 1
  191.         rcr     si, 1
  192.         rcr     cx, 1
  193.         rcr     bx, 1
  194.         rcr     ah, 1
  195.         inc     al
  196.         jl      po@anotherBit
  197.  
  198. po@aligned:
  199.  
  200. ;     frac = frac + carry; /* rounding */
  201.  
  202.         add     ah, ah
  203.         adc     bx, 0
  204.         adc     cx, 0
  205.         adc     si, 0
  206.         adc     dx, 0           ; DX:SI:CX:BX is now an integer < 2^60
  207.  
  208. ;     PutFourDigits (frac % 10000, 0);
  209. ;     frac = frac / 10000;
  210.  
  211.                                 ; DX < 4096 since 2^60 = 4096 * 2^48
  212.         xchg    ax, si
  213.         mov     si, 10000
  214.         div     si
  215.         xchg    ax, cx
  216.         div     si
  217.         xchg    ax, bx
  218.         div     si              ; frac = CX:BX:AX < 2^47, DX = mod 10000
  219.  
  220.         call    PutFourDigits   ; DX is parameter
  221.  
  222. ;     PutFourDigits (frac % 10000, 4);
  223. ;     frac = frac / 10000;
  224.  
  225.         sub     dx, dx
  226.         xchg    ax, cx
  227.         div     si
  228.         xchg    ax, bx
  229.         div     si
  230.         xchg    ax, cx
  231.         div     si              ; frac = BX:CX:AX < 2^34, DX = mod 10000
  232.  
  233.         call    PutFourDigits   ; DX is parameter
  234.  
  235. ;     PutFourDigits (frac % 10000, 8);
  236. ;     frac = frac / 10000;
  237.  
  238.         mov     dx, bx
  239.         xchg    ax, cx
  240.         div     si
  241.         xchg    ax, cx
  242.         div     si              ; frac = CX:AX < 2^20, DX = mod 10000
  243.  
  244.         call    PutFourDigits   ; DX is parameter
  245.  
  246.  
  247. ;     PutFourDigits (frac % 10000, 12);
  248. ;     frac = frac / 10000;
  249.  
  250.         mov     dx, cx
  251.         div     si              ; frac = AX < 2^7, DX = mod 10000
  252.  
  253.         call    PutFourDigits   ; DX is parameter
  254.  
  255. ;     res.digits [16] = frac % 10;
  256. ;     res.digits [17] = frac / 10;
  257.  
  258.         aam                     ; AH, AL = AL / 10, AL % 10
  259.         mov     cl, 4
  260.         shl     ah, cl
  261.         or      al, ah
  262.         stosb
  263.  
  264. po@end:
  265.  
  266. ;     res.sign = z.sign;
  267.  
  268.         mov     si, po?zPtr
  269.         mov     al, es:[si].ld_exponent.by1
  270.         and     al, 080h        ; isolate sign bit
  271.         stosb
  272.  
  273.         pop     di
  274.         pop     si
  275.         pop     bp
  276.         ret
  277.  
  278. ; ----
  279.  
  280. po@underflow:
  281.         mov     al, 0
  282.  
  283. po@extreme:
  284.         mov     cx, 9
  285. rep     stosb
  286.         jmp     short   po@end
  287.  
  288.  
  289. po@overflow:
  290.         mov     al, 99h
  291.         jmp     short   po@extreme
  292.  
  293.  
  294. ; ----
  295.  
  296.  
  297. __fbstp endp
  298.  
  299. Code_EndS@
  300.  
  301.         end
  302.