home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 9.ddi / EMUSRC.ZIP / FPINIT.ASM < prev   
Encoding:
Assembly Source File  |  1992-06-10  |  26.7 KB  |  830 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      FPINIT.ASM -- Emulator initialization                   |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1986, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         NAME    fpInit
  13.  
  14. ; Floating point (FPU) initialization.
  15. ; Includes detection of coprocessor, checking for environment override
  16. ; (SET 87=N), installation of interrupt vectors, and FINIT.
  17.  
  18. ; This module replaces EMUINIT and 87INIT, both used in TC 2.0.
  19. ; It also replaces some code in C0 related to floating point.
  20. ; Assemble with /DFP87 for hard 80x87 opcodes.
  21.  
  22. ; Caution: This code is in the _TEXT segment, and assumes that certain
  23. ; external routines can be called with NEAR calls.
  24.  
  25. .286
  26. .287
  27. locals  @@
  28.  
  29. include equates.asi
  30.  
  31. ifdef   FP87
  32. _Emu_   equ     0               ; no emulation, '87 required
  33. else
  34. _Emu_   equ     1               ; emulator
  35. endif
  36.  
  37. include emurules.asi
  38. include emuvars.asi
  39.  
  40. ; Segment and Group declarations
  41.  
  42. Header@
  43.  
  44. DSeg@
  45.  
  46. ; Public data
  47. ; initialize to -1
  48. ; if executed, emu1st will change it to 0, 1, 2, or 3
  49. PubSym@         _8087,  <dw     -1>,    __CDECL__
  50.  
  51. ; External References
  52. ExtSym@         _version, WORD, __CDECL__
  53. ExtSym@         _psp, WORD, __CDECL__
  54. ExtSym@         _protected, BYTE, __CDECL__
  55. ExtSym@         _LDT, WORD, __CDECL__
  56. ExtSym@         _default87, WORD, __CDECL__
  57.  
  58. DSegEnd@
  59.  
  60. ; External data, possibly not in DGROUP.
  61. ExtSym@         _fpstklen, word, __CDECL__
  62. ExtSym@         _stklen, word, __CDECL__
  63. extrn   __turboCvt : ABS        ; To force the link of REALCVT for printf
  64. extrn   __emu : byte
  65.  
  66. EmuAssume@      SS
  67.  
  68. ; Public procs.
  69.  
  70. public  ___fpreset
  71.  
  72. ; External procs.
  73.  
  74. ;extrn  __fperror : far
  75. extrn   __fperror : near
  76. ExtProc@        abort,  __CDECL__       ; called if init fails
  77. ;extrn  _abort : near                   ; called if init fails
  78.  
  79. ;-----------------------------------------------------------------------------
  80.  
  81. FpuPriority     equ     16d
  82. StartupStack    equ     24      ; must be even
  83.  
  84. ; debug symbols
  85. ifdef   DEBUG
  86. public  int2handler
  87. public  int75handler
  88. public  emu1st
  89. public  emuLast
  90. public  init87
  91. ;public failure
  92. ;public __fpustate
  93. endif
  94.  
  95.         PAGE
  96. ;[]------------------------------------------------------------[]
  97. ;|                                                              |
  98. ;|      General notes                                           |
  99. ;|      =============                                           |
  100. ;|                                                              |
  101. ;|      Emu086 is  designed to run  in either of  two modes:    |
  102. ;|      with   or   without   the   presence   of  the  8087    |
  103. ;|      co-processor. The  first action it takes  is to test    |
  104. ;|      for the  presence of the co-processor.  Depending on    |
  105. ;|      which it  finds, it connects  one of two  modules to    |
  106. ;|      the   interrupt   vectors   reserved   for   numeric    |
  107. ;|      coprocessor emulation.                                  |
  108. ;|                                                              |
  109. ;|      E087ENTR.ASM ("Real-87")                                |
  110. ;|                                                              |
  111. ;|      This module  is to be  used when there  is hardware     |
  112. ;|      support.  It  is  much  the  smaller  module.  This     |
  113. ;|      module will service 10  interrupt vectors (34h thru     |
  114. ;|      3Dh) which are used for floating point invocation by    |
  115. ;|      application  programs.  For  the first eight of  the    |
  116. ;|      vectors  plus some  functions of  the ninth, Real-87    |
  117. ;|      will patch  the calling program with  the equivalent    |
  118. ;|      8087  instruction  sequence  and  then  restart  the    |
  119. ;|      program to run the  patch. The application will thus    |
  120. ;|      be  converted  at  run  time   to  the  use  of  the    |
  121. ;|      co-processor.                                           |
  122. ;|                                                              |
  123. ;|      The non-converted  functions of the  ninth interrupt    |
  124. ;|      are transcendental  functions not directly  provided    |
  125. ;|      by the 8087. These  functions must be interpreted by    |
  126. ;|      a library  provided in Real-87, which  uses the 8087    |
  127. ;|      for computations.                                       |
  128. ;|                                                              |
  129. ;|      The  tenth   interrupt  is  used  for   a  NOP-FWAIT    |
  130. ;|      sequence. It is  patched the first time it  is used,    |
  131. ;|      like the other direct iNDP instructions.                |
  132. ;|                                                              |
  133. ;|      The  shortcut  vector  is  used  for instructions or    |
  134. ;|      sequences frequently  used by the compiler.  Some of    |
  135. ;|      them  are  equivalent  to  '87  instructions,  while    |
  136. ;|      others cannot be reduced  to a simple sequence. When    |
  137. ;|      the '87  is present the  direct equivalents will  be    |
  138. ;|      patched  with  in-line  code,  while  the  composite    |
  139. ;|      sequences are excuted in the interrupt routine.         |
  140. ;|                                                              |
  141. ;|      E086ENTR.ASM ("Virtual-87")                             |
  142. ;|                                                              |
  143. ;|      The Virtual-87 module is to be used when the 8087 is    |
  144. ;|      not  present.  It  supplies  all  code  necessary to    |
  145. ;|      emulate the  8087 (excepting some rare  details. See    |
  146. ;|      the   description   in   the   general   notes   for    |
  147. ;|      e086Entr.asm).  No  patching  occurs  in  this case,    |
  148. ;|      except for the tenth  interrupt which can be patched    |
  149. ;|      to a No-op sequence.                                    |
  150. ;|                                                              |
  151. ;[]------------------------------------------------------------[]
  152.  
  153.         PAGE
  154. ;[]------------------------------------------------------------[]
  155. ;|                                                              |
  156. ;|      FIXUP constants for FPU                                 |
  157. ;|                                                              |
  158. ;|      If none of the F??RQQ publics are used, then no         |
  159. ;|      floating point code will be linked.                     |
  160. ;|                                                              |
  161. ;[]------------------------------------------------------------[]
  162.  
  163. emInt           equ     34h     ; allocated to 8087 by Microsoft Corp.
  164. shortcutInt     equ     3Eh     ; used by Borland for shortcuts
  165. fpuInt          equ     02h     ; FPU interrupt number (normally = NMI)
  166.  
  167.         public  FIDRQQ          ; wait, esc
  168.         public  FIARQQ          ; wait, DS:
  169.         public  FICRQQ          ; wait, CS:
  170.         public  FIERQQ          ; wait, ES:
  171.         public  FISRQQ          ; wait, SS:
  172.         public  FIWRQQ          ; nop, wait
  173.         public  FJARQQ          ; Esc nn -> DS:nn
  174.         public  FJCRQQ          ; Esc nn -> CS:nn
  175.         public  FJSRQQ          ; Esc nn -> ES:nn
  176.  
  177.  
  178. ; Use full emulator if _Emu_ is true.
  179.  
  180. if      _Emu_
  181.  
  182. FIDRQQ  equ     05C32h
  183. FIARQQ  equ     0FE32h
  184. FICRQQ  equ     00E32h
  185. FIERQQ  equ     01632h
  186. FISRQQ  equ     00632h
  187. FIWRQQ  equ     0A23Dh
  188. FJARQQ  equ     04000h
  189. FJCRQQ  equ     0C000h
  190. FJSRQQ  equ     08000h
  191.  
  192. else
  193.  
  194. FIDRQQ  equ     00000h
  195. FIARQQ  equ     00000h
  196. FICRQQ  equ     00000h
  197. FIERQQ  equ     00000h
  198. FISRQQ  equ     00000h
  199. FIWRQQ  equ     00000h
  200. FJARQQ  equ     00000h
  201. FJCRQQ  equ     00000h
  202. FJSRQQ  equ     00000h
  203.  
  204. endif
  205.  
  206.         PAGE
  207. ;[]------------------------------------------------------------[]
  208. ;|                                                              |
  209. ;|      Emulator entry points                                   |
  210. ;|                                                              |
  211. ;[]------------------------------------------------------------[]
  212.  
  213. if      _Emu_
  214. ; This is the segment containing the full emulation code.
  215. EmuSeg@
  216. EXTRN   e086_Entry      : FAR
  217. EXTRN   e086_Shortcut   : FAR
  218. EmuSegEnd@
  219. endif
  220.  
  221. ; This is the segment containing the code to work with the 8087 chip.
  222. E87Seg@
  223. EXTRN   e087_Entry      : FAR
  224. EXTRN   e087_Shortcut   : FAR
  225. EXTRN   e087_Trap       : FAR
  226. E87SegEnd@
  227.  
  228.         PAGE
  229.  
  230. CSeg@
  231.  
  232.         PAGE
  233. ;[]------------------------------------------------------------[]
  234. ;|                                                              |
  235. ;|      emu1st -- Emulator installation routine                 |
  236. ;|                                                              |
  237. ;|      This  function  is  called  by  RTLstart  before any    |
  238. ;|      numeric work  begins. It needs  to save the  initial    |
  239. ;|      interrupt vectors  before it can install  itself.       |
  240. ;|                                                              |
  241. ;|      It will sense whether an iNDP87 co-processor exists,    |
  242. ;|      only if the _8087 variable is set to -1, which means    |
  243. ;|      that no "87" environment  variable has been defined.    |
  244. ;|      In that case it will choose which of the two numeric    |
  245. ;|      support modules is to be kept. The interrupt vectors    |
  246. ;|      34..3D  are  claimed  for  iNDP  software  interrupt    |
  247. ;|      support.                                                |
  248. ;|                                                              |
  249. ;|      An  additional  interrupt,  3Eh,  is  used  for  the    |
  250. ;|      Shortcut entries.                                       |
  251. ;|                                                              |
  252. ;|      The __fpreset function installs the interrupt vectors   |
  253. ;|      and  re-initializes the  emulator. This  function is    |
  254. ;|      called by the _fpreset() function of the RTL.           |
  255. ;|                                                              |
  256. ;[]------------------------------------------------------------[]
  257.  
  258. ; vectors 34h .. 3Eh, and 75h, and 2
  259. originalVectors dd      12 DUP (?)
  260. FPEpriorVector  dd      ?               ; interrupt handler for NMI
  261.  
  262. plus_inf        dd      7F800000R       ; + infinity
  263.  
  264. ; borrowed from T. Pascal, DOS 3.1 BIOS
  265. ; avoid DOS 3.2 stack swap
  266. int75handler    proc    far
  267.         push    ax
  268.         xor     al, al                  ; Clear BUSY latch
  269.         out     0F0h, al
  270.         mov     al, 20H                 ; End-of-interrupt
  271.         out     0A0h, al
  272.         out     20h, al
  273.         pop     ax
  274.         int     2
  275.         iret
  276. int75handler    endp
  277.  
  278.  
  279. ; Floating point exceptions on  PC-compatible machines are routed
  280. ;       to the NMI  vector. This vector must be  captured but the
  281. ;       previous contents need to  be remembered. The priorVector
  282. ;       is  used if NMI occurs  but the coprocessor did not cause
  283. ;       it, and also the priorVector  must be restored at the end
  284. ;       of the program.
  285.  
  286. OpJmpf          equ     0EAh            ; opcode for far jump
  287.  
  288. int2handler     proc    far
  289.         push    ax
  290.         mov     ax, seg __emu
  291.         call    e087_Trap       ; preserves all but ax, flags
  292. ret_trap:
  293. ; returns only if error could not be handled
  294.         jc      @@err
  295.         pop     ax
  296. ;       jmp     FPEpriorVector
  297.         db      OpJmpf
  298. nmi     dw      2 dup (?)
  299.  
  300. @@err:
  301. ; trap record in ss:ax
  302. ;       mov     bx, ax
  303.         xchg    bx, ax
  304. ; Set DS := DGROUP
  305.         mov     ax, seg _8087@
  306.         mov     DS, ax
  307.         call    __fperror
  308.         pop     ax
  309.         iret
  310. int2handler     endp
  311.  
  312. ifdef   VarStack
  313.  
  314. abortMSG        db      "Insufficient FPU or CPU stack.", 13, 10
  315. lgth_abortMSG   equ     $ - abortMSG
  316.  
  317. failure proc    near
  318.         mov     ah, 040h
  319.         mov     bx, 2
  320.         mov     cx, lgth_abortMSG
  321.         mov     dx, offset abortMSG
  322.         push    CS
  323.         pop     DS
  324.         MSDOS@                  ; write message at DS:DX
  325.         call    abort@
  326. ; never returns
  327. failure endp
  328.  
  329. endif
  330.  
  331. emu1st  proc    near            ; called only by startup code
  332.         push    DS
  333.         push    si
  334.         push    di
  335.  
  336. ifdef   VarStack
  337.  
  338. ; Make some space on the stack.
  339.  
  340.         mov     ax, seg _fpstklen@
  341.         mov     ES, ax
  342.         mov     ax, ES:_fpstklen@
  343.         and     al, 0FEh                ; round to even
  344.         mov     dx, seg _stklen@
  345.         mov     ES, dx
  346.         cmp     ax, ES:_stklen@
  347.         jae     failure
  348.         cmp     ax, MinFpStack
  349.         jb      failure
  350.  
  351.         mov     cx, StartupStack
  352.         mov     si, sp
  353.         add     ax, cx
  354.         sub     sp, ax
  355.         mov     di, sp
  356.  
  357. ; set start of FPU stack
  358. ; leave a spare to trap emulated underflows
  359.         lea     ax, [si-size_emu_temp]
  360.         mov     SS:__emu.ws_initSP, ax
  361.  
  362. ; move the stack down
  363.         mov     dx, SS
  364.         mov     DS, dx
  365.         mov     ES, dx
  366.         cld
  367.         shr     cx, 1
  368.         rep     movsw
  369.  
  370. ; set end of FPU stack
  371.         mov     SS:__emu.ws_lastSP, di
  372.  
  373. else
  374.  
  375. ; set end of FPU stack
  376.         lea     ax, __emu + (size fpu)
  377.         mov     SS:__emu.ws_lastSP, ax
  378.  
  379. ; set start of FPU stack
  380. ; leave a spare to trap emulated underflows
  381.         add     ax, MinFpStack - size_emu_temp
  382.         mov     SS:__emu.ws_initSP, ax
  383.  
  384. endif
  385.  
  386. ; Save prior vectors in the code segment.
  387. ; If in protected mode, make the segment writeable.
  388. ; Save _protected in SS where FPU can find it.
  389.  
  390.         mov     ax, _LDT@
  391.         mov     SS:__emu.ws_LDT, ax
  392.         mov     al, _protected@
  393.         mov     SS:__emu.ws_protected, al
  394.         mov     cx, CS
  395.         xor     cl, al                  ; al = 0 or 8
  396.         mov     DS, cx
  397.  
  398.         ASSUME  DS:_TEXT
  399.  
  400.         mov     ax, 3500h + emInt
  401.         mov     cx, 11          ; there are 10 emulation vectors
  402.         mov     di, offset originalVectors
  403. rememberLoop:
  404.         MSDOS@                  ; ES:BX = read interrupt vector
  405.         mov     DS:[di].W0, bx
  406.         mov     DS:[di].W1, ES
  407.         add     di, 4
  408.         inc     ax
  409.         loop    rememberLoop
  410.  
  411. ; grab INT 75h
  412.         mov     ax,3500h + 75h
  413.         MSDOS@                  ; ES:BX = read interrupt vector
  414.         mov     DS:[di].W0, bx
  415.         mov     DS:[di].W1, ES
  416.         add     di, 4
  417.  
  418. ; grab INT 2
  419.         mov     ax,3500h + fpuInt
  420.         MSDOS@                  ; ES:BX = read interrupt vector
  421.         mov     DS:[di].W0, bx
  422.         mov     DS:[di].W1, ES
  423.         mov     DS:nmi[0], bx
  424.         mov     DS:nmi[2], ES
  425.  
  426. ; Set DS := DGROUP
  427.         mov     ax, seg _8087@
  428.         mov     DS, ax
  429.  
  430.         ASSUME  CS:_TEXT, DS:seg _8087@
  431.  
  432. ; Do we need to test 80?87 presence ?
  433.  
  434.         mov     bx, -1
  435. if      _Emu_
  436.         mov     ES, _psp@
  437.  
  438. ; Look for a "87" environment variable.
  439. ; Each variable is ended by a 0 and a zero-length variable stops
  440. ; the environment. The environment can NOT be greater than 32k.
  441.  
  442.         mov     ES, ES: word ptr [2Ch]  ; environment segment
  443.         sub     di, di                  ; ES:[di] points to environ
  444.         mov     cx, 07FFFh              ; Environment cannot be > 32 Kbytes
  445.         mov     al, 0
  446.         cld
  447. env87next:
  448.         repne   scasb           ; direction flag is clear
  449.         jcxz    env87done       ; count exhausted imply end
  450.         cmp     al, ES:[di]     ; double zero bytes imply end
  451.         je      env87done
  452.         cmp     word ptr ES:[di], 3738h         ; low = '8', hi = '7'
  453.         jne     env87next
  454.         mov     dx, ES:[di+2]
  455.         cmp     dl, '='
  456.         jne     env87next
  457.         inc     bx
  458.         and     dh, not ('y' - 'Y')
  459.         cmp     dh, 'Y'
  460.         jne     env87done
  461.         inc     bx
  462. env87done:
  463. endif
  464.         pop     di
  465.         pop     si
  466.  
  467. ;[]------------------------------------------------------------[]
  468. ;|                                                              |
  469. ;|      Co-processor autosense routine                          |
  470. ;|                                                              |
  471. ;|      Note:   The code used to test the presence of a         |
  472. ;|              numeric coprocessor is similar to that          |
  473. ;|              recommended by IBM.                             |
  474. ;|                                                              |
  475. ;[]------------------------------------------------------------[]
  476.  
  477. ; If  CPU is  an 80286,  the FNINIT  instruction can  generate an
  478. ;       interrupt  if  the  NDP?87  is  not  present.  On IBM, an
  479. ;       interrupt handler is provided by  the BIOS but it may NOT
  480. ;       on clones. So won't test if there is or not an NDP?87, we
  481. ;       will just trust the BIOS equipment flag.
  482.  
  483. ; IBM uses these ports to reset the coprocessor.
  484. ; Some clone have the ports wired incorrectly, in which case it may
  485. ; be necessary to delete the OUT instructions.
  486.  
  487. ; Check whether 87=N
  488.         or      bx, bx
  489.         jz      @@set_flag
  490.  
  491. ;       xor     ax, ax
  492. ;       out     0F0h, al        ; Clear the busy latch (INT REQ)
  493. ;       out     0F1h, al        ; Reset chip in real mode
  494.  
  495. ; Distinguish between 8088/8086 and 80286/80386.
  496.         push    sp
  497.         pop     cx
  498.         cmp     cx, sp
  499.         jne     TestPresence
  500.  
  501. ; Possibly override BIOS test.
  502.         or      bx, bx
  503.         jg      @@test_inf
  504.  
  505. ; The CPU is an 80286 or 80386, so trust the BIOS equipment flag.
  506.         int     11h
  507.         and     al, 2
  508.         jz      @@test_done             ; jump with al = 0
  509.  
  510. ; Distinguish between a 80287 and 80387 using the infinity control.
  511. ; 8087 and 80287 support both infinity modes, defaults to projective
  512. ; 80387 supports affine infinity only
  513.  
  514. @@test_inf:
  515. ;       xor     ax, ax
  516. ;       out     0F0h, al        ; Clear the busy latch (INT REQ)
  517. ;       out     0F1h, al        ; Reset chip in real mode
  518.  
  519.         fninit
  520. ifdef   Intel_Test
  521.         fld1
  522.         fldz
  523.         fdiv                    ; generate infinity
  524.         fld     st              ; duplicate TOS
  525.         fchs                    ; form -INF
  526.         fcompp                  ; compare +INF to -INF
  527. else
  528.         fld     plus_inf
  529.         fchs
  530.         fcomp   plus_inf        ; compare +INF to -INF
  531. endif
  532.         fstsw   ax              ; we have a 287 or better
  533.         sahf
  534.  
  535.         mov     al, 2
  536.         je      @@test_done     ; equal on 80287 only
  537.         inc     al
  538.         jmp     short @@test_done
  539.  
  540. ; First check to see if a real 8087 is available. That allows
  541. ;       us to select which version of NDP support is to remain
  542. ;       resident.
  543.  
  544. TestPresence:
  545. ;       xor     ax, ax
  546. ;       out     0F0h, al        ; Clear the busy latch (INT REQ)
  547.         FNINIT
  548.         mov     _8087@, 0
  549.         FNSTCW  _8087@          ; Store the control word
  550.  
  551.         mov     cx, 20
  552.         loop    this near               ; Delay awhile
  553.         mov     cx, _8087@              ; Get NPX control word
  554.         and     cx, 0F3Fh               ; Mask off undefined bits
  555.         cmp     cx, 033Fh               ; Do we have a math coprocessor
  556.         jne     @@test_done             ; No ...
  557.  
  558.         mov     _8087@, -1
  559.         FNSTSW  _8087@                  ; Store the status word
  560.         mov     cx, 20
  561.         loop    this near               ; Delay awhile
  562.         test    _8087@, 0B8BFh          ; All bits off that should be?
  563.         jnz     @@test_done
  564.         inc     al
  565.  
  566. @@test_done:
  567.         cbw
  568.         xchg    ax, bx
  569.  
  570. @@set_flag:
  571.         mov     _8087@, bx
  572.         mov     SS:__emu.ws_8087, bl
  573.         pop     DS
  574. ; fall thru to reset everything
  575. emu1st  ENDP
  576.  
  577. temp1   equ     [bp-8]
  578. temp2   equ     [bp-4]
  579.  
  580. ___fpreset      proc    near
  581.         push    DS
  582.         push    bp
  583.         mov     bp, sp
  584.         sub     sp, 8
  585.  
  586.         mov     bx, seg _8087@
  587.         mov     DS, bx                  ; save DGROUP for later
  588.  
  589.         ASSUME  CS:_TEXT, DS:seg _8087@
  590.  
  591.         cmp     _8087@, 0
  592.         mov     temp1.W0, offset e087_Entry
  593.         mov     temp1.W1, seg e087_Entry
  594.         mov     temp2.W0, offset e087_Shortcut
  595.         mov     temp2.W1, seg e087_Shortcut
  596.  
  597. if      _Emu_
  598.         jne     doCapture
  599.         mov     temp1.W0, offset e086_Entry
  600.         mov     temp1.W1, seg e086_Entry
  601.         mov     temp2.W0, offset e086_Shortcut
  602.         mov     temp2.W1, seg e086_Shortcut
  603. endif
  604.  
  605. ; Now take over the vectors.
  606.  
  607. doCapture:
  608.         mov     ax, 2500h + emInt
  609.         mov     cx, 10          ; there are 10 emulation vectors
  610.         lds     dx, temp1.DD0
  611. captureLoop:
  612.         MSDOS@                  ; Set interrupt vector with DS:DX
  613.         inc     ax
  614.         loop    captureLoop
  615. ; The Shortcut vector must be captured too.
  616.  
  617.         mov     ax, 2500h + shortcutInt
  618.         lds     dx, temp2.DD0
  619.         MSDOS@                  ; Set interrupt vector with DS:DX
  620.  
  621. ; install INT 2 handler
  622.         mov     ax, 2500h + fpuInt
  623.         push    CS
  624.         pop     DS
  625.         mov     dx, offset int2handler
  626.         MSDOS@                  ; Set interrupt vector with DS:DX
  627.  
  628. ; No need for the INT 75 hack if
  629. ;       the 8087 is being emulated, or
  630. ;       the version of DOS different from 3.20
  631.         mov     DS, bx                  ; set DS = DGROUP
  632.         cmp     _8087@, 0
  633.         je      init87
  634.         mov     ax, _version@
  635.         xchg    ah, al
  636.         cmp     ax, 20 * 100h + 3       ; ok if version != 3.20
  637.         jne     init87
  638.  
  639. ; install INT 75 handler
  640.         mov     ax, 2500h + 75h
  641.         push    CS
  642.         pop     DS
  643.         mov     dx, offset int75handler
  644.         MSDOS@                  ; Set interrupt vector with DS:DX
  645.  
  646. ; Now emulation is installed. Ensure it is initialized.
  647. ; We must use an emulated FINIT in all cases.
  648. init87:
  649.         Int     emInt + 3
  650.         db      0E3h            ; (Wait, FINIT) equivalent
  651.         mov     SS:__emu.ecount1, 0
  652.         mov     SS:__emu.ecount2, 0
  653.  
  654. ; FINIT will disable all exception interrupts.  We want some enabled.
  655.         mov     DS, bx                  ; set DS = DGROUP
  656. ;       mov     temp1.W0, CW_DEFAULT
  657.         mov     ax, _default87@
  658.         mov     temp1.W0, ax
  659.  
  660. ; 80387 is fully IEEE, need not trap denormal exception
  661.         cmp     _8087@, 3
  662.         jl      @@control
  663.         or      temp1.W0, EM_DENORMAL
  664. @@control:
  665.         emul
  666.         FLDCW   temp1.W0
  667. ; set shadow control
  668.         mov     ax, temp1.W0
  669.         and     SS:__emu.ws_control, ax
  670.  
  671. ; dual mode startup requires AX=DX=0
  672.         xor     ax, ax
  673.         cwd
  674.  
  675.         mov     sp, bp
  676.         pop     bp
  677.         pop     DS
  678.         ret
  679. ___fpreset      endp
  680.  
  681.         PAGE
  682. ;[]------------------------------------------------------------[]
  683. ;|                                                              |
  684. ;|      emuLast -- Emulator termination routine                 |
  685. ;|                                                              |
  686. ;|      emuLast  is called  by RTLstart  after the  "main"      |
  687. ;|      routine returns or the program exits. Its purpose is    |
  688. ;|      to  restore the  original contents  of the interrupt    |
  689. ;|      vectors 34h..3Dh, plus the Shortcut vector.             |
  690. ;|                                                              |
  691. ;[]------------------------------------------------------------[]
  692.  
  693. emuLast proc    near    ; called only by startup code
  694.         push    DS
  695.  
  696. ; Set DS := DGROUP
  697.         mov     ax, seg _8087@
  698.         mov     DS, ax
  699.  
  700.         ASSUME  CS:_TEXT, DS:seg _8087@
  701.  
  702. ; Did we ever get initialized?
  703.         cmp     _8087@, 0
  704.         jl      @@done
  705.  
  706. ; leave the chip in a clean state
  707.         emul
  708.         finit
  709.  
  710.         mov     ax, 2500h + emInt
  711.         mov     bx, offset originalVectors
  712.         mov     cx, 11          ; there are 10 emulation vectors
  713. restoreLoop:
  714.         lds     dx, CS:[bx]
  715.         MSDOS@                  ; Set interrupt vector with DS:DX
  716.         add     bx, 4
  717.         inc     ax
  718.         loop    restoreLoop
  719.  
  720. ; restore INT 75h
  721.         mov     ax, 2500h + 75h
  722.         lds     dx, CS:[bx]
  723.         MSDOS@                  ; Set interrupt vector with DS:DX
  724.  
  725. ; restore INT 2
  726.         mov     ax, 2500h + fpuInt
  727.         lds     dx, CS:[bx+4]
  728.         MSDOS@                  ; Set interrupt vector with DS:DX
  729.  
  730. @@done:
  731.         pop     DS
  732.         ret
  733. emuLast endp
  734.  
  735. ifdef   VarStack
  736.  
  737. ; clean off all '87 registers, put chip in a predictable state
  738. ; preserves all but bx, cx, flags
  739. ; no segment assumptions other than SS
  740. ; leave current FPU stack pointer in a word at SS:bx
  741. ; void far cdecl fpustate(void);
  742.  
  743. public  __fpustate
  744.  
  745. __fpustate      proc    far
  746.         cmp     SS:__emu.ws_8087, 0
  747.         je      @@ret
  748.         noemul
  749. ; fill the '87
  750.         mov     cx, 8
  751. @@1:    fldz
  752.         loop    @@1
  753.         fcom    st(7)
  754. ; empty the '87
  755.         mov     cl, 8
  756. @@2:    fstp    st(0)
  757.         loop    @@2
  758. ; put the '87 in a predictable state
  759.         mov     cx, SS:__emu.ws_adjust
  760.         and     cx, 111b
  761.         jz      @@4
  762. @@3:    fincstp
  763.         loop    @@3
  764. @@4:
  765.         mov     SS:__emu.ws_adjust, cx          ; cx = 0
  766. @@ret:
  767.         lea     bx, SS:__emu.ws_TOS
  768.         ret
  769. __fpustate      endp
  770.  
  771. endif
  772.  
  773. ;[]------------------------------------------------------------[]
  774. ;|                                                              |
  775. ;|      __fpuint - return FPU interrupt number                  |
  776. ;|                                                              |
  777. ;|      This function returns the FPU exception number in AX.   |
  778. ;|      Used by emudecod.asm.                                   |
  779. ;|                                                              |
  780. ;[]------------------------------------------------------------[]
  781.  
  782.         public  __fpuint
  783.  
  784. __fpuint        proc    far
  785.         mov     ax, fpuInt
  786.         ret
  787. __fpuint        endp
  788.  
  789. CSegEnd@
  790.  
  791. ifdef   VarStack
  792.  
  793. _EMUSEG SEGMENT PARA COMMON 'DATA'
  794.         dw      __fpustate
  795. _EMUSEG ENDS
  796.  
  797. endif
  798.  
  799.         PAGE
  800. ;[]------------------------------------------------------------[]
  801. ;|                                                              |
  802. ;|      FPU automatic initialization logic                      |
  803. ;|                                                              |
  804. ;[]------------------------------------------------------------[]
  805.  
  806. PNEAR           EQU     0
  807. PFAR            EQU     1
  808. NOTUSED         EQU     0ffh
  809.  
  810. SE              STRUC
  811. calltype        db      ?                       ; 0=near,1=far,ff=not used
  812. priority        db      ?                       ; 0=highest,ff=lowest
  813. addrlow         dw      ?
  814. IFNDEF  __TINY__
  815. addrhigh        dw      ?
  816. ENDIF
  817. SE              ENDS
  818.  
  819. _INIT_          SEGMENT WORD PUBLIC 'INITDATA'
  820. ;SE     < PFAR, FpuPriority, offset emu1st, seg emu1st >
  821. SE      < PNEAR, FpuPriority, offset emu1st, 0 >
  822. _INIT_          ENDS
  823.  
  824. _EXIT_          SEGMENT WORD PUBLIC 'EXITDATA'
  825. ;SE     < PFAR, FpuPriority, offset emuLast, seg emuLast >
  826. SE      < PNEAR, FpuPriority, offset emuLast, 0 >
  827. _EXIT_          ENDS
  828.  
  829. END
  830.