home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 7.ddi / STARTUP.ZIP / C0D.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  13.7 KB  |  387 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0D.ASM -- Start Up Code For Windows DLLs               |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1991, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.                 locals
  13.  
  14.                 __C0__ = 1
  15. include         RULES.ASI
  16.  
  17.                 ASSUME CS:_TEXT, DS:DGROUP
  18.  
  19.                 public  __acrtused              ;satisfy MS for now
  20. __acrtused      equ     0
  21.  
  22.  
  23.                 extrn LIBMAIN:far       ;the C routine to be called
  24.                 extrn LOCALINIT:far     ;Windows heap init routine
  25.                 extrn LOCKSEGMENT:far
  26.                 extrn UNLOCKSEGMENT:far
  27.                 extrn GETWINFLAGS:far
  28.                 extrn __WEP:far
  29.                 extrn __cexit:DIST
  30.                 extrn __setupio:near    ;required!
  31.  
  32.                 public LibEntry         ;Entry point for the DLL
  33.                 publicdll WEP
  34.  
  35. NULL            segment
  36.                 db      16 dup (?)
  37.                 ends
  38.  
  39. _CVTSEG         segment
  40.                 public __RealCvtVector
  41. __RealCvtVector label word
  42.                 ends
  43.  
  44. _SCNSEG         segment
  45.                 public __ScanTodVector
  46. __ScanTodVector label word
  47.                 ends
  48.  
  49. _FPSEG          segment
  50.                 public __FPVector
  51. __FPVector      dd      0
  52.                 ends
  53.  
  54. _DATA           segment
  55.                 public _errno
  56. _errno          dw      0
  57.                 public __protected
  58. __protected     dw      0
  59.                 public __8087
  60. __8087          dw      0
  61.                 public __StartTime
  62. __StartTime     dd      0
  63.                 public __version
  64. __version       label word
  65.                 public __osversion
  66. __osversion     label word
  67.                 public __osmajor
  68. __osmajor       db      0
  69.                 public __osminor
  70. __osminor       db      0
  71.                 public __osmode         ;Used for OS/2 protected mode by MS,
  72. __osmode        db      0               ;currently set to 0 under Windows
  73.                 public __hInstance
  74. __hInstance     dw      0
  75.                 public __WinAllocFlag   ;Used by malloc for additional flags
  76. __WinAllocFlag  dw      0               ;to pass to GlobalAlloc (used in DLLs)
  77.                 public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  78. __LockWIN87EM   dw      1               ;DLL unload ordering problem
  79.  
  80. _abend          dw      1               ;If LibEntry is called gets set to
  81.                                         ;normal state (0).  If it is 1 then
  82.                                         ;exit routines are not performed
  83.                                         ;Gets set to 1 if DLL is terminated
  84.                                         ;by a call to abort() or _exit().
  85.  
  86. CopyRight       db      'Borland C++ - Copyright 1991 Borland Intl.',0
  87.                 ends
  88.  
  89. _TEXT           segment
  90.  
  91. LibEntry        proc far
  92.                 mov     __hInstance, di ;save SI and DI
  93.                 push    si
  94.  
  95.                 push    di              ;handle of the module instance
  96.                 push    ds              ;library data segment
  97.                 push    cx              ;heap size
  98.                 push    es              ;command line segment
  99.                 push    si              ;command line offset
  100.  
  101.                 ;if we have some heap then initialize it
  102.                 jcxz    @@Init          ;jump if no heap specified
  103.  
  104.                 ;call the Windows function LocalInit() to set up the heap
  105.                 ;LocalInit((LPSTR)start, WORD cbHeap);
  106.  
  107.                 push    ds              ;Heap segment
  108.                 xor     ax,ax
  109.                 push    ax              ;Heap start offset in segment
  110.                 push    cx              ;Heap end offset in segment
  111.                 call    LOCALINIT
  112.                 xchg    ax,cx
  113.                 jcxz    @@JmpExit       ;quit if it failed
  114.                 jmp     short @@Init
  115. @@JmpExit:      jmp     @@Exit
  116.  
  117. @@Init:
  118.  
  119. IF LDATA EQ false
  120.                 mov     ax,-1
  121.                 push    ax
  122.                 call    LOCKSEGMENT
  123. ENDIF
  124.  
  125.                 ;Clear _BSS, uninitialized data area
  126.  
  127.                 xor     ax, ax
  128.                 push    ds
  129.                 pop     es
  130.                 mov     di,offset DGROUP:BeginBSS
  131.                 mov     cx,offset DGROUP:EndBSS
  132.                 sub     cx,di
  133.                 cld
  134.                 rep
  135.                 stosb
  136.  
  137. ;Save start time of DLL
  138.  
  139.                 mov     ah, 0
  140.                 int     1ah             ; get current BIOS time in ticks
  141.                 mov     word ptr __StartTime,dx ; save it for clock() fn
  142.                 mov     word ptr __StartTime+2,cx
  143.                 or      al,al                   ; was midnight flag set?
  144.                 jz      @@NotMidnight
  145.                 mov     ax,40h                  ; set BIOS midnight flag
  146.                 mov     es,ax                   ;  at 40:70
  147.                 mov     bx,70h
  148.                 mov     byte ptr es:[bx],1
  149. @@NotMidnight:
  150.  
  151. ;Determine DOS version
  152.  
  153.                 mov     ah, 30h
  154.                 int     21h
  155.                 mov     __version, ax   ; save minor and major revision
  156.  
  157. ;Determine whether we are in protected mode
  158.  
  159.                 call    GETWINFLAGS
  160.                 test    ax,1            ; WF_PMODE = 1
  161.                 jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  162.                                         ; so if WF_PMODE changed it could be
  163.                                         ; in the high word.
  164.                 mov     __protected, 8  ; Eight is for convenience.
  165. @@realmode:
  166.  
  167. ;Test for 8087 presence
  168.  
  169.                 test    ax,0400h        ; WF_8087 = 0x0400
  170.                 jz      @@no8087
  171.                 mov     __8087, 1
  172. @@no8087:
  173.  
  174. ;Call our initialization functions, including C++ static constructors.
  175.  
  176.                 mov     ax,ds
  177.                 mov     es,ax
  178.                 mov     si,offset DGROUP:InitStart      ;si = start of table
  179.                 mov     di,offset DGROUP:InitEnd        ;di = end of table
  180.  
  181.                 mov     __WinAllocFlag, 2000h           ; GMEM_SHARE
  182.                 call    Initialize
  183.                 mov     __WinAllocFlag, 0
  184.                 mov     _abend, 0                       ; Set LibEntry called
  185.  
  186.                 ;invoke the C routine to do any special initialization
  187. @@Main:         call    LIBMAIN         ;invoke the 'C' routine (result in AX)
  188.                 mov     di, __hInstance ;restore SI and DI
  189.                 pop     si
  190.                 ret
  191.  
  192. @@Exit:         mov ax, 0               ;set return code
  193.                 pop si                  ;remove arguments to LIBMAIN
  194.                 pop es                  ;  since we didn't call it.
  195.                 pop cx
  196.                 pop ds
  197.                 pop di
  198.                 pop si                  ;restore saved SI.  DI is restored
  199.                 ret                     ;  by removing arguments to LIBMAIN
  200.                 endp
  201.  
  202. ;---------------------------------------------------------------------------
  203. ;       _cleanup()      call all #pragma exit cleanup routines.
  204. ;       _checknull()    check for null pointer zapping copyright message
  205. ;       _terminate(exitcode, quick)     exit program with error code
  206. ;       _restorezero()  restore interrupt vectors
  207. ;
  208. ;       These functions are called by exit(), _exit(), _cexit(),
  209. ;       and _c_exit().
  210. ;---------------------------------------------------------------------------
  211.  
  212. ;       Call cleanup routines
  213.  
  214. __cleanup       PROC    DIST
  215.                 PUBLIC  __cleanup
  216.  
  217.                 mov     ax,ds
  218.                 mov     es,ax
  219.                 push    si
  220.                 push    di
  221.                 mov     si,offset DGROUP:ExitStart
  222.                 mov     di,offset DGROUP:ExitEnd
  223.                 call    Cleanup
  224.                 pop     di
  225.                 pop     si
  226.                 ret
  227. __cleanup       ENDP
  228.  
  229. ;       Check for null pointers before exit.  NO-OP on Windows.
  230.  
  231. __checknull     PROC    DIST
  232.                 PUBLIC  __checknull
  233.                 ret
  234. __checknull     ENDP
  235.  
  236. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  237.  
  238. __restorezero     PROC    DIST
  239.                 PUBLIC  __restorezero
  240.                 ret
  241. __restorezero     ENDP
  242.  
  243. ;       Exit to DOS
  244. ;
  245. ; Usage:        void _terminate(int exitcode, int quick);
  246.  
  247. __terminate     PROC    DIST
  248.                 PUBLIC  __terminate
  249.  
  250.                 mov     bp,sp
  251.                 mov     al,[bp+cPtrSize]        ; get exitcode
  252.                 mov     ah,4ch
  253.                 int     21h
  254.                 ret
  255.                 endp
  256.  
  257. WEP             proc    windows pascal far nParam:WORD
  258.                 push    si
  259.                 push    di
  260.  
  261.                 cmp     _abend, 0
  262.                 jne     @@error
  263.                 push    nParam
  264.                 call    __WEP
  265.                 push    ax
  266.                 call    __cexit         ; perform cleanup without exiting
  267.  
  268. @@unlock:
  269.  
  270. IF LDATA EQ false
  271.                 mov     ax,-1
  272.                 push    ax
  273.                 call    UNLOCKSEGMENT
  274. ENDIF
  275.  
  276.                 pop     ax
  277.                 pop     di
  278.                 pop     si
  279.                 ret
  280.  
  281. @@error:
  282.                 push    1
  283.                 jmp     @@unlock
  284.  
  285.                 endp
  286.  
  287. ;       Return default data segment in AX
  288.  
  289. __GetDGROUP     PROC    FAR
  290.                 PUBLIC  __GetDGROUP
  291.                 mov     ax, DGROUP
  292.                 ret
  293.                 endp
  294.  
  295. ;------------------------------------------------------------------
  296. ;  Loop through a startup/exit (SE) table,
  297. ;  calling functions in order of priority.
  298. ;  ES:SI is assumed to point to the beginning of the SE table
  299. ;  ES:DI is assumed to point to the end of the SE table
  300. ;  First 64 priorities are reserved by Borland
  301. ;------------------------------------------------------------------
  302. PNEAR           EQU     0
  303. PFAR            EQU     1
  304. NOTUSED         EQU     0ffh
  305.  
  306. SE              STRUC
  307. calltype        db      ?                       ; 0=near,1=far,ff=not used
  308. priority        db      ?                       ; 0=highest,ff=lowest
  309. addrlow         dw      ?
  310. addrhigh        dw      ?
  311. SE              ENDS
  312.  
  313. Initialize      proc near
  314. @@Start:        mov     ax,100h                 ;start with lowest priority
  315.                 mov     dx,di                   ;set sentinel to end of table
  316.                 mov     bx,si                   ;bx = start of table
  317.  
  318. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  319.                 je      @@EndOfTable            ;yes, exit the loop
  320.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  321.                 je      @@Next
  322.                 mov     cl, es:[bx.priority]    ;move priority to CX
  323.                 xor     ch, ch
  324.                 cmp     cx,ax                   ;check the priority
  325.                 jae     @@Next                  ;too high?  skip
  326.                 mov     ax,cx                   ;keep priority
  327.                 mov     dx,bx                   ;keep index in dx
  328. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  329.                 jmp     @@TopOfTable
  330.  
  331. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  332.                 je      @@Done                  ;yes, quit
  333.                 mov     bx,dx                   ;bx = highest priority item
  334.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  335.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  336.                 push    es                      ;save es
  337.                 je      @@NearCall
  338.  
  339. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  340.                 pop     es                      ;restore es
  341.                 jmp     short @@Start
  342.  
  343. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  344.                 pop     es                      ;restore es
  345.                 jmp     short @@Start
  346.  
  347. @@Done:         ret
  348.                 endp
  349.  
  350. Cleanup         proc near
  351. @@Start:        mov     ah,0                    ;start with highest priority
  352.                 mov     dx,di                   ;set sentinel to end of table
  353.                 mov     bx,si                   ;bx = start of table
  354.  
  355. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  356.                 je      @@EndOfTable            ;yes, exit the loop
  357.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  358.                 je      @@Next
  359.                 cmp     es:[bx.priority],ah     ;check the priority
  360.                 jb      @@Next                  ;too low?  skip
  361.                 mov     ah,es:[bx.priority]     ;keep priority
  362.                 mov     dx,bx                   ;keep index in dx
  363. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  364.                 jmp     @@TopOfTable
  365.  
  366. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  367.                 je      @@Done                  ;yes, quit
  368.                 mov     bx,dx                   ;bx = highest priority item
  369.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  370.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  371.                 push    es                      ;save es
  372.                 je      @@NearCall
  373.  
  374. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  375.                 pop     es                      ;restore es
  376.                 jmp     short @@Start
  377.  
  378. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  379.                 pop     es                      ;restore es
  380.                 jmp     short @@Start
  381.  
  382. @@Done:         ret
  383.                 endp
  384.  
  385.                 ends
  386.                 end LibEntry
  387.