home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 2.ddi / CLIBSRC3.ZIP / SPAWN.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  6.2 KB  |  194 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      SPAWN.ASM -- Execute a program w/o Overlay                   |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14. ;       Segments Definitions
  15.  
  16. Header@
  17.  
  18. ;       External References
  19.  
  20. extrn           __IOERROR:near
  21.  
  22. ExtSym@         _psp, WORD, __CDECL__
  23.  
  24.         SUBTTL  _Spawn Function
  25.         PAGE
  26. ;/*                                                     */
  27. ;/*-----------------------------------------------------*/
  28. ;/*                                                     */
  29. ;/* int _spawn(pathP,cmdP,envP);                        */
  30. ;/*     char    *pathP;                                 */
  31. ;/*     char    *cmdP;                                  */
  32. ;/*     char    *envP;                                  */
  33. ;/*                                                     */
  34. ;/*-----------------------------------------------------*/
  35. ;/*                                                     */
  36.  
  37. pathP           equ     4
  38.  
  39. IF      LDATA
  40. cmdP            equ     pathP + 4
  41. envP            equ     cmdP + 4
  42. ELSE
  43. cmdP            equ     pathP + 2
  44. envP            equ     cmdP + 2
  45. ENDIF
  46.  
  47. Fcb2Ptr         equ     4
  48. Fcb1Ptr         equ     Fcb2Ptr + 4
  49. CmdPtr          equ     Fcb1Ptr + 4
  50. EnvSeg          equ     CmdPtr + 2
  51. Fcb2            equ     EnvSeg + 16
  52. Fcb1            equ     Fcb2 + 16
  53.  
  54. CSeg@
  55.  
  56.  
  57. SaveSP          dw      ?
  58. SaveSS          dw      ?
  59.  
  60.                 public  __spawn
  61. __spawn         proc    near
  62.                 push    bp
  63.                 mov     bp, sp
  64.                 sub     sp, Fcb1
  65.                 push    si
  66.                 push    ds
  67.                 push    di
  68.                 push    es
  69.  
  70.         ;/* All we need to access with ES is in the stack */
  71.  
  72.                 push    ss
  73.                 pop     es
  74.  
  75.         ;/* Use envP and make with it a segment address */
  76.  
  77. IF      LDATA
  78.                 mov     ax, [bp+envP]
  79.                 mov     dx, [bp+envP+2]
  80. ELSE
  81.                 mov     ax, [bp+envP]
  82.                 mov     dx, ds
  83.                 or      ax, ax
  84.                 jz      SetEnvSeg
  85. ENDIF
  86.                 mov     cl, 4
  87.                 shr     ax, cl
  88.                 add     ax, dx
  89. SetEnvSeg       label   near
  90.                 mov     [bp-EnvSeg], ax
  91.  
  92.         ;/* Parse the command line for FCBs */
  93.  
  94.                 pushDS_
  95.                 LDS_    si, [bp+cmdP]
  96.                 mov     [bp-CmdPtr], si
  97.                 mov     [bp-CmdPtr+2], ds
  98.                 mov     ax, 2901h
  99.                 lea     di, [bp-Fcb1]
  100.                 mov     [bp-Fcb1Ptr], di
  101.                 mov     [bp-Fcb1Ptr+2], es
  102.                 inc     si
  103.                 int     21h             ;Build FCB 1 in PSP
  104.  
  105. FindWhite       label   near
  106.                 mov     al,[si]
  107.                 cmp     al,20h         ; Space
  108.                 je      NextFCB
  109.                 cmp     al,09h         ; Tab
  110.                 je      NextFCB
  111.                 cmp     al,0dh         ; Carriage Return
  112.                 je      NextFCB
  113.                 inc     si
  114.                 jmp     FindWhite
  115.  
  116. NextFCB         label   near
  117.                 mov     ax, 2901h
  118.                 lea     di, [bp-Fcb2]
  119.                 mov     [bp-Fcb2Ptr], di
  120.                 mov     [bp-Fcb2Ptr+2], es
  121.                 int     21h             ;Build FCB 2 in PSP
  122.                 popDS_
  123.  
  124.         ;/* DOS 2.xx likes DS to point to PSP, so copy pathP to PSP:80 which
  125.         ;/* allows us to move DS to point to the PSP
  126.  
  127.                 pushDS_
  128.                 push    es
  129. IFDEF   __HUGE__
  130.                 mov     ax, seg _psp@   ; Get segment of _psp variable
  131.                 mov     ds, ax          ; Setup DS to point to it
  132. ENDIF
  133.                 mov     es, _psp@       ; Get PSP segment
  134.                 LDS_    si, [bp+pathP]  ; Pathname of program to load
  135.                 mov     di, 80h         ; Point to argument area
  136.                 mov     cx, 7Fh         ; Limit length so we don't trash things
  137.                 cld                     ; Forward copy
  138. CopyPathP:      lodsb                   ; Get a char
  139.                 test    al, al          ; End of string yet ?
  140.                 jz      CopyPathPDone   ; Yes
  141.                 stosb                   ; Nope, copy character
  142.                 loop    CopyPathP       ; Next character
  143.                 mov     al, 0           ; Place null at end of string
  144. CopyPathPDone:  stosb
  145.                 pop     es
  146.                 popDS_
  147.  
  148.         ;/* Load and Execute the program */
  149.  
  150.                 push    bp              ; Save our context
  151.                 push    ds
  152.                 lea     bx, [bp-EnvSeg] ; Load descriptor
  153. IFDEF   __HUGE__
  154.                 mov     ax, seg _psp@   ; Get segment of _psp variable
  155.                 mov     ds, ax
  156. ENDIF
  157.                 mov     ds, _psp@       ; Pathname is in the PSP now
  158.                 mov     dx, 80h
  159.                 mov     ax, 4B00h       ; Load and Execute a program
  160.                 push    word ptr ss:[02Eh] ; DOS 2.xx destroy these 2 words
  161.                 push    word ptr ss:[030h]
  162.                 mov     SaveSS, ss      ; SS and SP also
  163.                 mov     SaveSP, sp
  164.                 int     21h
  165.                 cli
  166.                 mov     ss, SaveSS      ; Restore our stack pointer
  167.                 mov     sp, SaveSP
  168.                 sti
  169.                 pop     word ptr ss:[030h]
  170.                 pop     word ptr ss:[02Eh]
  171.                 pop     ds
  172.                 pop     bp
  173.  
  174.         ;/* If no error, get child exit code */
  175.  
  176.                 jnc     SpawnOk
  177.                 push    ax
  178.                 call    __IOERROR
  179.                 jmp     short SpawnExit
  180. SpawnOk         label   near
  181.                 mov     ah, 4dh
  182.                 int     21h
  183. SpawnExit       label   near
  184.                 pop     es
  185.                 pop     di
  186.                 pop     ds
  187.                 pop     si
  188.                 mov     sp, bp
  189.                 pop     bp
  190.                 ret
  191.                 endp
  192. CSegEnd@
  193.         END
  194.