home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 2.ddi / CLIBSRC3.ZIP / NHEAPCHK.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  16.1 KB  |  418 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      NHEAPCHK.ASM                                                 |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14.         LOCALS
  15.         INCLUDE _HEAP.INC
  16.  
  17. IF LPROG
  18.   EXTRADISP     equ     2         ; Allow for FAR returns when getting parms
  19.   DIST          equ     FAR
  20. ELSE
  21.   EXTRADISP     equ     0
  22.   DIST          equ     NEAR
  23. ENDIF
  24.  
  25. IF LDATA EQ false
  26.  
  27. ;-----------------------------------------------------------------------
  28. ; Memory Block Header (near heap)
  29. ;-----------------------------------------------------------------------
  30. ; Each block in the heap, whether allocated or free, has a header.
  31. ; For an allocated block, only the first two fields of the header are
  32. ; used. For a free block all eight bytes are used, thus the smallest
  33. ; possible block is the size of a free header.
  34. ;
  35. ; Field       Description
  36. ; ---------   ----------------------------------------------------------
  37. ; size        total size, in bytes, of this block (+1 if the block is in use)
  38. ; prev_real   pointer to the physically previous block in the heap
  39. ; prev_free   pointer to the logically previous free block
  40. ; next_free   pointer to the logically next free block
  41. ;
  42. ; Note that the size field is also used to indicate whether the block
  43. ; is allocated or free.  A doubly-linked queue is maintained of the
  44. ; free blocks and it is important to know that ordering of the blocks
  45. ; in this queue is logical rather than physical.  If there is only one
  46. ; free block on the heap prev_free and next_free point to itself.
  47. ;-----------------------------------------------------------------------
  48. Header          STRUC
  49. bsize           dw      ?
  50. prev_real       dw      ?
  51. prev_free       dw      ?
  52. next_free       dw      ?
  53.                 ENDS
  54.  
  55. ;-----------------------------------------------------------------------
  56. ; heapinfo structure (near heap)
  57. ;-----------------------------------------------------------------------
  58. ; Used by the heapwalk function.
  59. ; heapwalk accepts a pointer to a struct of this type.
  60. ; On entry, the pointer field contains the address of the previous
  61. ; memory block in the heap (NULL for the first call).  The next block
  62. ; in the heap is then found and its address is stored in the structure
  63. ; along with its size, in bytes, and a 'used' flag.
  64. ;-----------------------------------------------------------------------
  65. HeapInfo        STRUC
  66. hi_ptr          dw      ?
  67. hi_size         dw      ?
  68. hi_inuse        dw      ?
  69.                 ENDS
  70.  
  71. UsedHeaderSize  EQU     4
  72. FreeHeaderSize  EQU     8
  73.  
  74. ;-----------------------------------------------------------------------
  75. ; Only three variables are needed to efficiently manage the heap.
  76. ;-----------------------------------------------------------------------
  77.                 EXTRN __first:word        ;pointer to the first block
  78.                 EXTRN __last:word         ;pointer to the last block
  79.                 EXTRN __rover:word        ;pointer to an arbitrary free block
  80.  
  81.  
  82. _TEXT           SEGMENT PUBLIC 'CODE'
  83.                 ASSUME CS:_TEXT
  84.  
  85. ;-----------------------------------------------------------------------------
  86. ; C callable function which checks and verifies the heap.
  87. ; Walk through the physical heap and free block queue checking for
  88. ; bad links, adjacent free blocks, and sum the free block sizes both
  89. ; ways.  If the physical free block sum does not equal the free-block
  90. ; queue sum, there is an error.
  91. ;
  92. ; Args:                 void
  93. ; Returns:              _HEAPEMPTY, _HEAPOK, or _HEAPCORRUPT in ax
  94. ;-----------------------------------------------------------------------------
  95.                 PUBLIC  _heapcheck
  96. _heapcheck      PROC DIST
  97.                 push    si
  98.                 push    di
  99.                 push    bx
  100.                 push    cx
  101.                 push    dx
  102.  
  103.                 mov     bx,__first              ;bx = first block in heap
  104.                 or      bx,bx                   ;is it NULL?
  105.                 jz      @@EmptyHeap
  106.                 mov     si,[bx.bsize]           ;si = next block after bx
  107.                 and     si,0fffeh
  108.                 add     si,bx
  109.  
  110.                 xor     cx,cx                   ;cx = size sum of physical free blocks
  111.                 mov     dx,cx                   ;dx = size sum of free block queue
  112. @@SearchPhysicalLinks:
  113.                 test    BYTE PTR [bx.bsize],01h ;is this block used?
  114.                 jnz     @@CheckPhysicalLinks
  115.                 add     cx,[bx.bsize]           ;cx += size of this free block
  116.                 cmp     bx,[__last]             ;at the end of the heap?
  117.                 je      @@QueueCheck
  118.                 test    BYTE PTR [si.bsize],01h ;this block should be used
  119.                 jz      @@HeapCorrupt           ;Oh nooooo, Mr. Bill!
  120. @@CheckPhysicalLinks:
  121.                 cmp     bx,[__last]             ;at the end of the heap?
  122.                 je      @@QueueCheck
  123.                 cmp     si,bx                   ;check those links!
  124.                 jbe     @@HeapCorrupt
  125.                 cmp     [bx.bsize],FreeHeaderSize
  126.                 jb      @@HeapCorrupt
  127.                 cmp     si,[__first]
  128.                 jbe     @@HeapCorrupt
  129.                 cmp     si,[__last]
  130.                 ja      @@HeapCorrupt
  131.                 cmp     [si.prev_real],bx
  132.                 jne     @@HeapCorrupt
  133.                 mov     bx,si                   ;bx = next block in heap
  134.                 mov     si,[bx.bsize]           ;si = next block after bx
  135.                 and     si,0fffeh
  136.                 add     si,bx
  137.                 jmp     SHORT @@SearchPhysicalLinks
  138. @@QueueCheck:
  139.                 mov     bx,[__rover]
  140.                 or      bx,bx
  141.                 jz      @@EvaluateResults
  142. @@QueueLoop:
  143.                 mov     ax,[bx.bsize]           ;this block should be free
  144.                 test    al,01h                  ;well, is it?
  145.                 jnz     @@HeapCorrupt           ;Oh nooooo, Mr. Bill!
  146.                 add     dx,ax                   ;dx += size of this block
  147.                 cmp     bx,[__first]
  148.                 jb      @@HeapCorrupt
  149.                 cmp     bx,[__last]
  150.                 jae     @@HeapCorrupt
  151.                 mov     si,[bx.next_free]       ;si = the next free block
  152.                 cmp     si,[__rover]            ;done?
  153.                 je      @@EvaluateResults
  154.                 cmp     si,bx                   ;check those links!
  155.                 je      @@HeapCorrupt
  156.                 mov     bx,si
  157.                 jmp     SHORT @@QueueLoop
  158. @@EmptyHeap:
  159.                 mov     ax,_HEAPEMPTY
  160.                 jmp     SHORT @@AllDone
  161.  
  162. @@EvaluateResults:
  163.                 cmp     dx,cx
  164.                 jne     @@HeapCorrupt
  165. @@HeapOK:
  166.                 mov     ax,_HEAPOK
  167.                 jmp     SHORT @@AllDone
  168. @@HeapCorrupt:
  169.                 mov     ax,_HEAPCORRUPT
  170. @@AllDone:
  171.                 pop     dx
  172.                 pop     cx
  173.                 pop     bx
  174.                 pop     di
  175.                 pop     si
  176.                 ret
  177.                 ENDP
  178.  
  179. ;-----------------------------------------------------------------------------
  180. ; C callable function which checks and verifies a node on the heap.
  181. ;-----------------------------------------------------------------------------
  182. ; Args:                 node to check (stack)
  183. ; Returns:              _HEAPCORRUPT, _BADNODE, _FREEENTRY, or _USEDENTRY in ax
  184. ;-----------------------------------------------------------------------------
  185.                 PUBLIC  _heapchecknode
  186. _heapchecknode  PROC DIST
  187.                 push    si
  188.                 push    di
  189.                 push    bp
  190.  
  191.                 mov     bp,sp
  192.  
  193.                 mov     ax,[bp+8+EXTRADISP]     ;ax = node to find
  194.                 sub     ax,UsedHeaderSize
  195.  
  196.                 mov     bx,[__first]            ;bx = first block in heap
  197.                 or      bx,bx                   ;is it NULL?
  198.                 jz      @@EmptyHeap
  199.                 mov     si,[bx.bsize]           ;si = next block after bx
  200.                 and     si,0fffeh
  201.                 add     si,bx
  202.  
  203. @@SearchPhysicalLinks:
  204.                 cmp     bx,ax
  205.                 je      @@Found
  206.                 test    BYTE PTR [bx.bsize],01h ;is this block used?
  207.                 jnz     @@CheckPhysicalLinks
  208.                 cmp     bx,[__last]             ;at the end of the heap?
  209.                 je      @@NotFound
  210.                 test    BYTE PTR [si.bsize],01h ;this block should be used
  211.                 jz      @@HeapCorrupt           ;Oh nooooo, Mr. Bill!
  212. @@CheckPhysicalLinks:
  213.                 cmp     bx,[__last]             ;at the end of the heap?
  214.                 je      @@NotFound
  215.                 cmp     si,bx                   ;check those links!
  216.                 jbe     @@HeapCorrupt
  217.                 cmp     [bx.bsize],FreeHeaderSize
  218.                 jb      @@HeapCorrupt
  219.                 cmp     si,[__first]
  220.                 jbe     @@HeapCorrupt
  221.                 cmp     si,[__last]
  222.                 ja      @@HeapCorrupt
  223.                 cmp     si,bx
  224.                 jbe     @@HeapCorrupt
  225.                 cmp     [si.prev_real],bx
  226.                 jne     @@HeapCorrupt
  227.                 mov     bx,si                   ;bx = next block in heap
  228.                 mov     si,[bx.bsize]           ;si = next block after bx
  229.                 and     si,0fffeh
  230.                 add     si,bx
  231.                 jmp     SHORT @@SearchPhysicalLinks
  232. @@EmptyHeap:
  233.                 mov     ax,_HEAPEMPTY
  234.                 jmp     SHORT @@AllDone
  235. @@HeapCorrupt:
  236.                 mov     ax,_HEAPCORRUPT
  237.                 jmp     SHORT @@AllDone
  238. @@NotFound:
  239.                 mov     ax,_BADNODE
  240.                 jmp     SHORT @@AllDone
  241. @@Found:
  242.                 test    BYTE PTR [bx.bsize],01
  243.                 jnz     @@UsedEntry
  244. @@FreeEntry:
  245.                 mov     ax,_FREEENTRY
  246.                 jmp     SHORT @@AllDone
  247. @@UsedEntry:
  248.                 mov     ax,_USEDENTRY
  249. @@AllDone:
  250.                 pop     bp
  251.                 pop     di
  252.                 pop     si
  253.                 ret
  254.                 ENDP
  255.  
  256. ;-----------------------------------------------------------------------------
  257. ; C callable function which fills the free areas with a given value
  258. ;-----------------------------------------------------------------------------
  259. ; Args:                 unsigned int, fill value (stack)
  260. ; Returns:              _HEAPEMPTY, _HEAPOK, or _HEAPCORRUPT in ax
  261. ;-----------------------------------------------------------------------------
  262.                 PUBLIC  _heapfillfree
  263. _heapfillfree   PROC DIST
  264.                 push    bp
  265.                 mov     bp,sp
  266.                 mov     ax,[bp+4+EXTRADISP]
  267.  
  268.                 push    si
  269.                 push    di
  270.  
  271.                 cmp     __first,0
  272.                 je      @@EmptyHeap
  273.  
  274.                 mov     bx,__rover
  275.                 or      bx,bx
  276.                 jz      @@HeapOK
  277.                 cld
  278. @@QueueLoop:
  279.                 mov     cx,[bx.bsize]
  280.                 sub     cx,FreeHeaderSize
  281.                 shr     cx,1
  282.                 lea     di,[bx+8]
  283.                 rep
  284.                 stosw
  285.                 mov     cx,[bx.next_free]       ;cx = next free block
  286.                 cmp     cx,[__rover]            ;done?
  287.                 je      @@HeapOK
  288.                 cmp     bx,cx                   ;check links
  289.                 je      @@HeapCorrupt
  290.                 or      cx,cx
  291.                 jz      @@HeapCorrupt
  292.                 mov     bx,cx                   ;get the next free block
  293.                 jmp     SHORT @@QueueLoop
  294. @@HeapOK:
  295.                 mov     ax,_HEAPOK
  296.                 jmp     SHORT @@AllDone
  297. @@EmptyHeap:
  298.                 mov     ax,_HEAPEMPTY
  299.                 jmp     SHORT @@AllDone
  300. @@HeapCorrupt:
  301.                 mov     ax,_HEAPCORRUPT
  302. @@AllDone:
  303.                 pop     di
  304.                 pop     si
  305.                 pop     bp
  306.                 ret
  307.                 ENDP
  308.  
  309. ;-----------------------------------------------------------------------------
  310. ; C callable function which checks the free areas of the heap for a given value
  311. ;-----------------------------------------------------------------------------
  312. ; Args:                 unsigned int, fill value (stack)
  313. ; Returns:              _HEAPOK, _HEAPEMPTY, _BADVALUE, or _HEAPCORRUPT in ax
  314. ;-----------------------------------------------------------------------------
  315.                 PUBLIC  _heapcheckfree
  316. _heapcheckfree  PROC DIST
  317.                 push    bp
  318.                 mov     bp,sp
  319.                 mov     ax,[bp+4+EXTRADISP]
  320.  
  321.                 push    si
  322.                 push    di
  323.  
  324.                 cmp     __first,0
  325.                 je      @@EmptyHeap
  326.  
  327.                 mov     bx,__rover
  328.                 or      bx,bx
  329.                 jz      @@HeapOK
  330.                 cld
  331. @@QueueLoop:
  332.                 mov     cx,[bx.bsize]
  333.                 sub     cx,FreeHeaderSize
  334.                 shr     cx,1
  335.                 lea     di,[bx+8]
  336.                 repe
  337.                 scasw
  338.                 jnz     @@BadValue
  339.                 mov     cx,[bx.next_free]       ;cx = next free block
  340.                 cmp     cx,[__rover]            ;done?
  341.                 je      @@HeapOK
  342.                 cmp     bx,cx                   ;check links
  343.                 je      @@HeapCorrupt
  344.                 or      cx,cx
  345.                 jz      @@HeapCorrupt
  346.                 mov     bx,cx                   ;get the next free block
  347.                 jmp     SHORT @@QueueLoop
  348. @@HeapOK:
  349.                 mov     ax,_HEAPOK
  350.                 jmp     SHORT @@AllDone
  351. @@EmptyHeap:
  352.                 mov     ax,_HEAPEMPTY
  353.                 jmp     SHORT @@AllDone
  354. @@BadValue:
  355.                 mov     ax,_BADVALUE
  356.                 jmp     SHORT @@AllDone
  357. @@HeapCorrupt:
  358.                 mov     ax,_HEAPCORRUPT
  359. @@AllDone:
  360.                 pop     di
  361.                 pop     si
  362.                 pop     bp
  363.                 ret
  364.                 ENDP
  365.  
  366. ;-----------------------------------------------------------------------------
  367. ; C callable function to walk through the heap node by node
  368. ;-----------------------------------------------------------------------------
  369. ; Args:                 pointer to a heapinfo structure (stack)
  370. ; Returns:              _HEAPOK, _HEAPEMPTY, _HEAPEND in ax
  371. ;-----------------------------------------------------------------------------
  372.                 PUBLIC  _heapwalk
  373. _heapwalk       PROC DIST
  374.                 push    bp
  375.                 push    si
  376.  
  377.                 mov     bp,sp
  378.                 mov     bx,[bp+6+EXTRADISP]     ;bx = address of heapinfo struct
  379.                 mov     si,[bx.hi_ptr]          ;si = previous block
  380.                 or      si,si                   ;si == NULL?
  381.                 je      @@FirstBlock
  382.                 sub     si,UsedHeaderSize
  383.                 cmp     si,[__last]             ;last block?
  384.                 je      @@HeapEnd
  385. @@InnerBlock:
  386.                 add     si,[si.bsize]           ;si = next block
  387.                 and     si,0fffeh               ;strip 'used' bit
  388.                 jmp     SHORT @@SaveInfo
  389. @@FirstBlock:
  390.                 mov     si,[__first]
  391.                 or      si,si
  392.                 jz      @@HeapEmpty
  393. @@SaveInfo:
  394.                 mov     [bx.hi_ptr],si
  395.                 add     [bx.hi_ptr],UsedHeaderSize
  396.                 mov     ax,[si.bsize]
  397.                 and     ax,0fffeh               ;strip 'used' bit
  398.                 mov     [bx.hi_size],ax
  399.                 mov     ax,[si.bsize]
  400.                 and     ax,0001h                ;retrieve 'used' bit
  401.                 mov     [bx.hi_inuse],ax
  402. @@HeapOK:
  403.                 mov     ax,_HEAPOK
  404.                 jmp     SHORT @@AllDone
  405. @@HeapEmpty:
  406.                 mov     ax,_HEAPEMPTY
  407.                 jmp     SHORT @@AllDone
  408. @@HeapEnd:
  409.                 mov     ax,_HEAPEND
  410. @@AllDone:
  411.                 pop     si
  412.                 pop     bp
  413.                 ret
  414.                 ENDP
  415.                 ENDS
  416. ENDIF
  417.                 END
  418.