home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 2.ddi / CLIBSRC3.ZIP / FHEAPCHK.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  19.0 KB  |  516 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      FEAPCHK.ASM                                                  |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14.         LOCALS
  15.         INCLUDE _HEAP.INC
  16.  
  17. IF LPROG
  18.   EXTRADISP     equ     2         ; Allow for FAR returns when getting parms
  19.   DIST          equ     FAR
  20. ELSE
  21.   EXTRADISP     equ     0
  22.   DIST          equ     NEAR
  23. ENDIF
  24.  
  25. ;-----------------------------------------------------------------------
  26. ; Memory Block Header (far heap)
  27. ;-----------------------------------------------------------------------
  28. ; Each block in the heap, whether allocated or free, has a header.
  29. ; For an allocated block, only the first two fields of the header are
  30. ; used. For a free block all ten bytes are used.  Blocks are aligned on
  31. ; paragraph boundaries, thus the smallest possible block sixteen bytes.
  32. ;
  33. ; Field       Description
  34. ; ---------   ----------------------------------------------------------
  35. ; size        total size, in paragraphs, of this block
  36. ; prev_real   segment of the physically previous block in the heap
  37. ;             prev_real is 0 this block is free, get the prev_real from prev_real2
  38. ; prev_free   segment of the logically previous free block
  39. ; next_free   segment of the logically next free block
  40. ; prev_real2  segment of the physically previous block in the heap
  41. ; free_space  first byte of free space available
  42. ;
  43. ; A doubly-linked queue is maintained of the free blocks and it is important
  44. ; to know that ordering of the blocks in this queue is logical rather than
  45. ; physical.  If there is only one free block on the heap prev_free and
  46. ; next_free point to itself.
  47. ;-----------------------------------------------------------------------
  48. bsize           EQU     0
  49. prev_real       EQU     2
  50. prev_free       EQU     4
  51. next_free       EQU     6
  52. prev_real2      EQU     8
  53. free_space      EQU     10
  54.  
  55. ;-----------------------------------------------------------------------
  56. ; heapinfo structure (far heap)
  57. ;-----------------------------------------------------------------------
  58. ; Used by the heapwalk function.
  59. ; heapwalk accepts a pointer to a struct of this type.
  60. ; On entry, the pointer field contains the address of the previous
  61. ; memory block in the heap (NULL for the first call).  The next block
  62. ; in the heap is then found and its address is stored in the structure
  63. ; along with its size, in bytes, and a 'used' flag.
  64. ;-----------------------------------------------------------------------
  65. HeapInfo        STRUC
  66. hi_ptr          dd      ?
  67. hi_size         dd      ?
  68. hi_inuse        dw      ?
  69.                 ENDS
  70.  
  71. UsedHeaderSize  EQU     4
  72. FreeHeaderSize  EQU     10
  73.  
  74.                 EXTRN   __brk:NEAR, __sbrk:NEAR
  75.  
  76. _TEXT           SEGMENT PUBLIC 'CODE'
  77.                 ASSUME CS:_TEXT
  78.  
  79. ;-----------------------------------------------------------------------
  80. ; Only three variables are needed to efficiently manage the heap.
  81. ; These reside in our own code segment for speed.
  82. ; We also set aside some scratch save areas.
  83. ;-----------------------------------------------------------------------
  84.                 EXTRN ___first:word        ;segment of the first block
  85.                 EXTRN ___last:word         ;segment of the last block
  86.                 EXTRN ___rover:word        ;segment of an arbitrary free block
  87.  
  88. ;-----------------------------------------------------------------------------
  89. ; C callable function which checks and verifies the heap.
  90. ; Walk through the physical heap and free block queue checking for
  91. ; bad links, adjacent free blocks, and sum the free block sizes both
  92. ; ways.  If the physical free block sum does not equal the free-block
  93. ; queue sum, there is an error.
  94. ;
  95. ; Args:                 void
  96. ; Returns:              _HEAPEMPTY, _HEAPOK, or _HEAPCORRUPT in ax
  97. ;-----------------------------------------------------------------------------
  98. IF LDATA
  99.                 PUBLIC  _heapcheck
  100. _heapcheck      LABEL   DIST
  101. ENDIF
  102.                 PUBLIC  _farheapcheck
  103. _farheapcheck   PROC    DIST
  104.                 push    si
  105.                 push    di
  106.                 push    bp
  107.                 push    ds
  108.  
  109.                 mov     ax,cs:[___first]
  110.                 or      ax,ax
  111.                 jnz     @@HeapNotEmpty
  112.                 jmp     @@EmptyHeap
  113.  
  114. @@HeapNotEmpty:
  115.                 xor     bx,bx
  116.                 push    bx
  117.                 push    bx
  118.                 call    __sbrk                  ;retrieve the break level
  119.                 add     sp,4
  120.                 or      ax,ax
  121.                 jz      @@GoodOffset
  122.                 jmp     @@HeapCorrupt
  123. @@GoodOffset:
  124.                 mov     bx,cs:[___last]
  125.                 mov     ds,bx
  126.                 add     bx,ds:[bsize]
  127.                 cmp     bx,dx
  128.                 je      @@CheckHeap
  129.                 jmp     @@HeapCorrupt
  130. @@CheckHeap:
  131.                 mov     ax,cs:[___first]
  132.  
  133.                 xor     cx,cx                   ;cx = sum of physical free
  134.                 mov     dx,cx                   ;dx = sum of logical free
  135.  
  136.                 mov     ds,ax                   ;ds = first block in the heap
  137.                 add     ax,WORD PTR ds:[bsize]
  138.                 mov     es,ax                   ;ax,es = next block in the heap
  139. @@SearchPhysicalLinks:
  140.                 cmp     WORD PTR ds:[prev_real],0  ;is this block used?
  141.                 jne     @@CheckPhysicalLinks       ;yep, skip this section
  142.                 add     cx,ds:[bsize]
  143.                 mov     si,ds                   ;si = ds
  144.                 cmp     si,cs:[___last]         ;end-of-heap?
  145.                 je      @@QueueCheck
  146.                 cmp     WORD PTR es:[prev_real],0  ;is the next block free?
  147.                 jnz     @@CheckPhysicalLinks
  148.                 jmp     @@HeapCorrupt
  149. @@CheckPhysicalLinks:
  150.                 mov     si,ds                   ;si = ds
  151.                 mov     di,es                   ;di = es
  152.                 cmp     si,cs:[___last]         ;end-of-heap?
  153.                 je      @@QueueCheck
  154.                 cmp     si,di                   ;check those links!
  155.                 je      @@HeapCorrupt
  156.                 cmp     WORD PTR ds:[bsize],0
  157.                 je      @@HeapCorrupt
  158.                 cmp     di,cs:[___first]
  159.                 jbe     @@HeapCorrupt
  160.                 cmp     di,cs:[___last]
  161.                 ja      @@HeapCorrupt
  162.                 cmp     WORD PTR es:[prev_real],0
  163.                 je      @@NextBlockIsFree
  164. @@NextBlockIsUsed:
  165.                 cmp     es:[prev_real],si
  166.                 jmp     @@CheckPrevReal
  167. @@NextBlockIsFree:
  168.                 cmp     es:[prev_real2],si
  169. @@CheckPrevReal:
  170.                 jne     @@HeapCorrupt
  171.                 mov     ds,di                   ;ds = es
  172.                 add     di,WORD PTR ds:[bsize]
  173.                 mov     es,di                   ;es = next block in the heap
  174.                 jmp     SHORT @@SearchPhysicalLinks
  175.  
  176. @@QueueCheck:
  177.                 mov     ax,cs:[___rover]        ;ax = rover pointer
  178.                 or      ax,ax
  179.                 jz      @@EvaluateResults
  180.                 mov     ds,ax                   ;ds = free block
  181.                 mov     si,ax                   ;si = ds
  182. @@QueueLoop:
  183.                 cmp     WORD PTR ds:[prev_real],0       ;this block should be free
  184.                 jne     @@HeapCorrupt
  185.                 cmp     si,cs:[___first]
  186.                 jb      @@HeapCorrupt
  187.                 cmp     si,cs:[___last]
  188.                 jae     @@HeapCorrupt
  189.                 add     dx,ds:[bsize]           ;dx += size of this block
  190.                 mov     es,ds:[next_free]       ;es = next free block
  191.                 mov     di,es                   ;di = es
  192.                 cmp     di,ax                   ;done?
  193.                 je      @@EvaluateResults
  194.                 cmp     si,di                   ;check those links?
  195.                 je      @@HeapCorrupt
  196.                 cmp     es:[prev_free],si
  197.                 jne     @@HeapCorrupt
  198.                 mov     si,es                   ;ds = es
  199.                 mov     ds,si
  200.                 jmp     SHORT @@QueueLoop
  201.  
  202. @@HeapCorrupt:
  203.                 mov     ax,_HEAPCORRUPT
  204.                 jmp     SHORT @@AllDone
  205. @@EmptyHeap:
  206.                 mov     ax,_HEAPEMPTY
  207.                 jmp     SHORT @@AllDone
  208.  
  209. @@EvaluateResults:
  210.                 cmp     cx,dx
  211.                 jne     @@HeapCorrupt
  212. @@HeapOK:
  213.                 mov     ax,_HEAPOK
  214. @@AllDone:
  215.                 pop     ds
  216.                 pop     bp
  217.                 pop     di
  218.                 pop     si
  219.                 ret
  220.                 ENDP
  221.  
  222. ;-----------------------------------------------------------------------------
  223. ; C callable function which checks and verifies a node on the heap.
  224. ;-----------------------------------------------------------------------------
  225. ; Args:                 node to check (stack)
  226. ; Returns:              _HEAPCORRUPT, _BADNODE, _FREEENTRY, or _USEDENTRY in ax
  227. ;-----------------------------------------------------------------------------
  228. IF LDATA
  229.                 PUBLIC  _heapchecknode
  230. _heapchecknode  LABEL   DIST
  231. ENDIF
  232.                 PUBLIC  _farheapchecknode
  233. _farheapchecknode       PROC DIST
  234.                 ARG     O:word, S:word
  235.  
  236.                 push    bp
  237.                 mov     bp,sp
  238.                 push    si
  239.                 push    di
  240.                 push    ds
  241.  
  242.                 call    _farheapcheck           ;make sure heap is OK first
  243.                 cmp     ax, _HEAPOK
  244.                 jne     @@AllDone
  245.  
  246.                 mov     ax,[S]                  ;ax = segment to search for
  247.  
  248.                 mov     si,cs:[___first]        ;si = first block
  249.                 mov     di,cs:[___last]         ;di = last block
  250.                 mov     bx,si                   ;bx = first block
  251.  
  252. @@SearchPhysicalLinks:
  253.                 mov     ds,bx
  254.                 cmp     bx,ax                   ;is this it?
  255.                 je      @@Found
  256.                 cmp     WORD PTR ds:[prev_real],0
  257.                 je      @@BlockIsFree
  258. @@BlockIsUsed:
  259.                 cmp     ds:[prev_real],si
  260.                 jb      @@HeapCorrupt
  261.                 jmp     SHORT @@Around
  262. @@BlockIsFree:
  263.                 cmp     ds:[prev_real2],si
  264.                 jb      @@HeapCorrupt
  265. @@Around:
  266.                 cmp     bx,di
  267.                 je      @@NotFound
  268.                 ja      @@HeapCorrupt
  269.                 mov     cx,bx
  270.                 add     bx,ds:[bsize]
  271.                 cmp     bx,cx
  272.                 jne     @@SearchPhysicalLinks
  273. @@HeapCorrupt:
  274.                 mov     ax,_HEAPCORRUPT
  275.                 jmp     SHORT @@AllDone
  276. @@EmptyHeap:
  277.                 mov     ax,_HEAPEMPTY
  278.                 jmp     SHORT @@AllDone
  279. @@NotFound:
  280.                 mov     ax,_BADNODE
  281.                 jmp     SHORT @@AllDone
  282. @@Found:
  283.                 cmp     WORD PTR ds:[prev_real],0
  284.                 jnz     @@UsedEntry
  285. @@FreeEntry:
  286.                 mov     ax,_FREEENTRY
  287.                 jmp     SHORT @@AllDone
  288. @@UsedEntry:
  289.                 mov     ax,_USEDENTRY
  290. @@AllDone:
  291.                 pop     ds
  292.                 pop     di
  293.                 pop     si
  294.                 pop     bp
  295.                 ret
  296.                 ENDP
  297.  
  298. ;-----------------------------------------------------------------------------
  299. ; C callable function which fills the free areas with a given value
  300. ;-----------------------------------------------------------------------------
  301. ; Args:                 unsigned int, fill value (stack)
  302. ; Returns:              _HEAPEMPTY, _HEAPOK, or _HEAPCORRUPT in ax
  303. ;-----------------------------------------------------------------------------
  304. IF LDATA
  305.                 PUBLIC  _heapfillfree
  306. _heapfillfree   LABEL   DIST
  307. ENDIF
  308.                 PUBLIC  _farheapfillfree
  309. _farheapfillfree        PROC DIST
  310.                 ARG     fill:word
  311.  
  312.                 push    bp
  313.                 mov     bp,sp
  314.                 push    si
  315.                 push    di
  316.  
  317.                 call    _farheapcheck           ;make sure heap is OK first
  318.                 cmp     ax, _HEAPOK
  319.                 jne     @@AllDone
  320.  
  321.                 mov     bx,cs:___rover          ;bx = rover pointer
  322.                 or      bx,bx
  323.                 jz      @@HeapOK
  324.  
  325.                 cld
  326.                 mov     ax,[fill]               ;ax = fill value
  327. @@QueueLoop:
  328.                 mov     es,bx                   ;es,bx = free block
  329.                 mov     dx,es:[bsize]           ;dx = size of block (in para)
  330.                 mov     si,es:[next_free]       ;si = next free block
  331.                 mov     di,free_space
  332.                 mov     cx,8 - (free_space/2)
  333. @@FillHerUp:
  334.                 rep
  335.                 stosw
  336.                 xor     di,di
  337.                 mov     cx,8
  338.                 inc     bx
  339.                 mov     es,bx
  340.                 dec     dx
  341.                 jnz     @@FillHerUp
  342. @@NextBlock:
  343.                 cmp     si,cs:[___rover]
  344.                 je      @@HeapOK
  345.                 or      si,si
  346.                 jz      @@HeapCorrupt
  347.                 mov     bx,si
  348.                 jmp     SHORT @@QueueLoop
  349.  
  350. @@HeapCorrupt:
  351.                 mov     ax,_HEAPCORRUPT
  352.                 jmp     SHORT @@AllDone
  353. @@EmptyHeap:
  354.                 mov     ax,_HEAPEMPTY
  355.                 jmp     SHORT @@AllDone
  356. @@HeapOK:
  357.                 mov     ax,_HEAPOK
  358. @@AllDone:
  359.                 pop     di
  360.                 pop     si
  361.                 pop     bp
  362.                 ret
  363.                 ENDP
  364.  
  365. ;-----------------------------------------------------------------------------
  366. ; C callable function which checks the free areas of the heap for a given value
  367. ;-----------------------------------------------------------------------------
  368. ; Args:                 unsigned int, fill value (stack)
  369. ; Returns:              _HEAPOK, _HEAPEMPTY, _BADVALUE, or _HEAPCORRUPT in ax
  370. ;-----------------------------------------------------------------------------
  371. IF LDATA
  372.                 PUBLIC  _heapcheckfree
  373. _heapcheckfree  LABEL   DIST
  374. ENDIF
  375.                 PUBLIC  _farheapcheckfree
  376. _farheapcheckfree       PROC DIST
  377.                 ARG     fill:word
  378.  
  379.                 push    bp
  380.                 mov     bp,sp
  381.                 push    si
  382.                 push    di
  383.  
  384.                 call    _farheapcheck           ;make sure heap is OK first
  385.                 cmp     ax, _HEAPOK
  386.                 jne     @@AllDone
  387.  
  388.                 mov     bx,cs:___rover          ;bx = rover pointer
  389.                 or      bx,bx
  390.                 jz      @@HeapOK
  391.  
  392.                 mov     ax,[fill]               ;ax = fill value
  393.                 cld
  394. @@QueueLoop:
  395.                 mov     es,bx                   ;es,bx = free block
  396.                 mov     dx,es:[bsize]           ;dx = size of block (in para)
  397.                 mov     si,es:[next_free]       ;si = next free block
  398.                 mov     di,free_space
  399.                 mov     cx,8 - (free_space/2)
  400. @@CheckHerOut:
  401.                 repe
  402.                 scasw
  403.                 jnz     @@BadValue
  404.                 xor     di,di
  405.                 mov     cx,8
  406.                 inc     bx
  407.                 mov     es,bx
  408.                 dec     dx
  409.                 jnz     @@CheckHerOut
  410. @@NextBlock:
  411.                 cmp     si,cs:[___rover]
  412.                 je      @@HeapOK
  413.                 or      si,si
  414.                 jz      @@HeapCorrupt
  415.                 mov     bx,si
  416.                 jmp     SHORT @@QueueLoop
  417.  
  418. @@BadValue:
  419.                 mov     ax,_BADVALUE
  420.                 jmp     SHORT @@AllDone
  421. @@HeapCorrupt:
  422.                 mov     ax,_HEAPCORRUPT
  423.                 jmp     SHORT @@AllDone
  424. @@EmptyHeap:
  425.                 mov     ax,_HEAPEMPTY
  426.                 jmp     SHORT @@AllDone
  427. @@HeapOK:
  428.                 mov     ax,_HEAPOK
  429. @@AllDone:
  430.                 pop     di
  431.                 pop     si
  432.                 pop     bp
  433.                 ret
  434.                 ENDP
  435.  
  436. ;-----------------------------------------------------------------------------
  437. ; C callable function to walk through the heap node by node
  438. ;-----------------------------------------------------------------------------
  439. ; Args:                 pointer to a heapinfo structure (stack)
  440. ; Returns:              _HEAPOK, _HEAPEMPTY, _HEAPEND in ax
  441. ;-----------------------------------------------------------------------------
  442. IF LDATA
  443.                 PUBLIC  _heapwalk
  444. _heapwalk       LABEL   DIST
  445. ENDIF
  446.                 PUBLIC  _farheapwalk
  447. _farheapwalk    PROC DIST
  448.                 ARG     O:word, S:word
  449.  
  450.                 push    bp
  451.                 mov     bp,sp
  452.                 push    si
  453.                 push    di
  454.  
  455.                 mov     di,[O]                  ;di = offset of struct
  456. IF LDATA
  457.                 push    ds
  458.                 mov     bx,[S]                  ;bx = segment of struct
  459.  
  460.                 cmp     di,0FFF0h               ;psuedo-normalize it
  461.                 jb      @@Normalized
  462.                 inc     bx
  463.                 sub     di,16d
  464. @@Normalized:
  465.                 mov     ds,bx                   ;ds:di = struct
  466. ENDIF
  467.                 mov     bx,WORD PTR [di+hi_ptr+2]       ;bx = previous block
  468.                 or      bx,bx
  469.                 jz      @@FirstBlock
  470.                 cmp     bx,cs:[___last]         ;last block?
  471.                 je      @@HeapEnd
  472.                 or      bx,bx                   ;first?
  473.                 jne     @@InnerBlock
  474. @@FirstBlock:
  475.                 mov     bx,cs:[___first]
  476.                 or      bx,bx
  477.                 jz      @@HeapEmpty
  478.                 mov     es,bx                   ;es = first block
  479.                 jmp     SHORT @@SaveInfo
  480. @@InnerBlock:
  481.                 mov     es,bx                   ;es = block
  482.                 add     bx,es:[bsize]           ;bx = next block
  483.                 mov     es,bx                   ;es = next block
  484. @@SaveInfo:
  485.                 mov     WORD PTR ds:[di+hi_ptr+2],es    ;save address
  486.                 mov     WORD PTR ds:[di+hi_ptr],UsedHeaderSize
  487.                 mov     ax,WORD PTR es:[bsize]          ;multiply size * 16
  488.                 mov     bx,16d
  489.                 mul     bx
  490.                 mov     WORD PTR ds:[di+hi_size],ax     ;save it
  491.                 mov     WORD PTR ds:[di+hi_size+2],dx
  492.                 mov     WORD PTR ds:[di+hi_inuse],0     ;clear in-use flag
  493.                 cmp     WORD PTR es:[prev_real], 0      ;is it free?
  494.                 je      @@HeapOK
  495.                 inc     WORD PTR ds:[di+hi_inuse]      ;set in-use flag
  496. @@HeapOK:
  497.                 mov     ax,_HEAPOK
  498.                 jmp     SHORT @@AllDone
  499. @@HeapEmpty:
  500.                 mov     ax,_HEAPEMPTY
  501.                 jmp     SHORT @@AllDone
  502. @@HeapEnd:
  503.                 mov     ax,_HEAPEND
  504. @@AllDone:
  505. IF LDATA
  506.                 pop     ds
  507. ENDIF
  508.                 pop     di
  509.                 pop     si
  510.                 pop     bp
  511.                 ret
  512.                 ENDP
  513.  
  514.                 ENDS
  515.                 END
  516.