home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c082_122 / 1.ddi / CLIBSRC1.ZIP / F_LXMUL.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-06-10  |  1.9 KB  |  64 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      F_LXMUL.ASM -- long multiply routine                         |
  3. ;[]-----------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 5.0
  7. ; 
  8. ;       Copyright (c) 1987, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.         INCLUDE RULES.ASI
  13.  
  14. ; calls to this routine are generated by the compiler to perform
  15. ; long multiplications.
  16.  
  17. ; There is no check for overflow.  Consequently, the same routine
  18. ; is used for both signed and unsigned long multiplies.
  19.  
  20. ;
  21. ; in:
  22. ;       (dx:ax) - 32bit arg1
  23. ;       (cx:bx) - 32bit arg2
  24. ; out:
  25. ;       (dx:ax) - 32bit product
  26. ;
  27. ; reg use: bx,cx destroyed, all others preserved or contain result.
  28. ;
  29. ; hi(result) := lo(hi(arg1) * lo(arg2)) +
  30. ;               lo(hi(arg2) * lo(arg1)) +
  31. ;               hi(lo(arg1) * lo(arg2))
  32. ; lo(result) := lo(lo(arg1) * lo(arg2))
  33. ;
  34. ;
  35. _TEXT   SEGMENT BYTE PUBLIC 'CODE'
  36.         ASSUME  CS:_TEXT
  37.  
  38.         public  LXMUL@
  39.         public  F_LXMUL@
  40.  
  41. LXMUL@          PROC    FAR
  42. F_LXMUL@:
  43.                 push    si
  44.                 xchg    si,ax           ; save lo1
  45.                 xchg    ax,dx
  46.                 test    ax,ax           ; skip mul if hi1==0
  47.                 jz      nohi1
  48.                 mul     bx              ; hi1 * lo2
  49.  
  50. nohi1:          ; if we jumped here, ax==0 so the following swap works
  51.                 jcxz    nohi2           ; skip mul if hi2==0
  52.                 xchg    cx, ax          ; result <-> hi2
  53.                 mul     si              ; lo1 * hi2
  54.                 add     ax, cx          ; ax = hi1*lo2 + hi2*lo1
  55. nohi2:
  56.                 xchg    ax,si
  57.                 mul     bx              ; lo1 * lo2
  58.                 add     dx,si           ; hi order result += partials
  59.                 pop     si
  60.                 ret
  61. LXMUL@          ENDP
  62. _TEXT   ENDS
  63.         END
  64.