home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c065 / 2.ddi / CLIB2.ZIP / N_LXMUL.ASM < prev    next >
Encoding:
Assembly Source File  |  1990-06-07  |  1.7 KB  |  60 lines
  1. ;[]-----------------------------------------------------------------[]
  2. ;|      N_LXMUL.ASM -- long multiply routine                         |
  3. ;|                                                                   |
  4. ;|      Turbo-C Run Time Library        Version 3.0                  |
  5. ;|                                                                   |
  6. ;|      Copyright (c) 1987,1988,1990 by Borland International Inc.   |
  7. ;|      All Rights Reserved.                                         |
  8. ;[]-----------------------------------------------------------------[]
  9.  
  10.     INCLUDE    RULES.ASI
  11.  
  12. ; calls to this routine are generated by the compiler to perform
  13. ; long multiplications.
  14.  
  15. ; There is no check for overflow.  Consequently, the same routine
  16. ; is used for both signed and unsigned long multiplies.
  17.  
  18. ;
  19. ; in:
  20. ;    (dx:ax) - 32bit arg1
  21. ;    (cx:bx) - 32bit arg2
  22. ; out:
  23. ;    (dx:ax) - 32bit product
  24. ;
  25. ; reg use: bx,cx destroyed, all others preserved or contain result.
  26. ;
  27. ; hi(result) := lo(hi(arg1) * lo(arg2)) +
  28. ;        lo(hi(arg2) * lo(arg1)) +
  29. ;        hi(lo(arg1) * lo(arg2))
  30. ; lo(result) := lo(lo(arg1) * lo(arg2))
  31. ;
  32.  
  33. _TEXT    SEGMENT BYTE PUBLIC 'CODE'
  34.     ASSUME    CS:_TEXT
  35.  
  36.     public    N_LXMUL@
  37.  
  38. N_LXMUL@      PROC    NEAR
  39.         push    si
  40.         xchg    si, ax        ; save lo1
  41.         xchg    ax, dx
  42.         test    ax, ax        ; skip mul if hi1==0
  43.         jz    nohi1
  44.         mul    bx        ; hi1 * lo2
  45.  
  46. nohi1:        ; if we jumped here, ax==0 so the following swap works
  47.         jcxz    nohi2        ; skip mul if hi2==0
  48.         xchg    cx, ax        ; result <-> hi2
  49.         mul    si        ; lo1 * hi2
  50.         add    ax, cx        ; ax = hi1*lo2 + hi2*lo1
  51. nohi2:
  52.         xchg    ax, si
  53.         mul    bx        ; lo1 * lo2
  54.         add    dx, si        ; hi order result += partials
  55.         pop    si
  56.         ret
  57. N_LXMUL@       ENDP
  58. _TEXT    ENDS
  59.     END
  60.