home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c005 / 5.ddi / KBQUEUE.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-08-05  |  3.8 KB  |  189 lines
  1. ;
  2. ; Name        kbqueue -- Return total and remaining capacity of
  3. ;               BIOS keyboard queue
  4. ;
  5. ; Synopsis    avail = kbqueue(ptotal);
  6. ;
  7. ;        int  avail      Number of available spaces in
  8. ;                  type-ahead queue.
  9. ;        int  *ptotal      Pointer to variable to receive
  10. ;                  total capacity of queue.
  11. ;
  12. ; Description    This function reports the total capacity of the of the
  13. ;        BIOS type-ahead buffer and the number of unfilled spaces
  14. ;        available in it.
  15. ;
  16. ;        If the returned value ("avail") is to be used, then
  17. ;        KBQUEUE should probably be called with interrupts turned
  18. ;        off (via UTINTOFF).  That will prevent further
  19. ;        keystrokes or other processes from changing the number
  20. ;        of available spaces.  Once the value is used, interrupts
  21. ;        may be turned back on via UTINTON.
  22. ;
  23. ;        KBQUEUE assumes that the BIOS type-ahead buffer is at
  24. ;        the standard location of 0x40:0x1e.  It will probably
  25. ;        malfunction otherwise.
  26. ;
  27. ; Returns    avail          Number of available spaces in
  28. ;                  type-ahead queue.
  29. ;        *ptotal       Pointer to variable to receive
  30. ;                  total size of queue.
  31. ;
  32. ; Version    3.0 (C)Copyright Blaise Computing Inc. 1986
  33.  
  34.      name       kbqueue
  35.  
  36.      LONGPROG  = 0            ; initialize constants for
  37.      LONGDATA  = 0            ; Pass1 of the assembler
  38.  
  39.      include   compiler.mac     ; Specifies the C compiler
  40.  
  41. popff     macro                ;; Simulate POPF instruction
  42.      local    do_call,do_iret
  43.  
  44.      jmp    short do_call
  45.  
  46. do_iret:
  47.      iret                ;; Pop IP, CS, flags.
  48.  
  49. do_call:
  50.      push    cs            ;; Push CS
  51.      call    do_iret         ;; Push IP & jump.
  52.  
  53.      endm
  54.  
  55.      if LAT200 or LAT210 or LAT300
  56.      include  dos.mac
  57.      LONGPROG = LPROG
  58.      LONGDATA = LDATA
  59.  
  60.      pseg
  61.      public   kbqueue
  62.      if      LPROG
  63.      x   equ  6            ; parameter offset
  64. kbqueue  proc      far
  65.      else
  66.      x   equ  4
  67. kbqueue  proc      near
  68.      endif
  69.      endif
  70.  
  71.      if CI201A
  72.      include  model.h
  73.      include  prologue.h
  74.      LONGPROG = @bigmodel
  75.      LONGDATA = @bigmodel
  76.  
  77.      public   kbqueue
  78.      if      @bigmodel
  79.      x   equ  6            ; parameter offset
  80. kbqueue  proc      far
  81.      else
  82.      x   equ  4
  83. kbqueue  proc      near
  84.      endif
  85.      endif
  86.  
  87.      if MSC300
  88.      include  dos.mac
  89.      LONGPROG = LPROG
  90.      LONGDATA = LDATA
  91.  
  92.      pseg      kbqueue
  93.      public   _kbqueue
  94.      if      LPROG
  95.      x   equ  6            ; parameter offset
  96. _kbqueue proc      far
  97.      else
  98.      x   equ  4
  99. _kbqueue proc      near
  100.      endif
  101.      endif
  102.  
  103.      if    LONGDATA
  104. ptotal     equ    dword ptr [bp + x]    ; Address of argument
  105.      else
  106. ptotal     equ    word ptr [bp + x]
  107.      endif
  108.  
  109. buffer_head   equ word ptr ds:1ah
  110. buffer_tail   equ word ptr ds:1ch
  111. kb_buffer     equ          1eh
  112. kb_buffer_end equ          3eh
  113.  
  114. ;   Beginning of actual code
  115.  
  116.      push    bp
  117.      mov    bp,sp
  118.  
  119.      push    ds
  120.  
  121.      pushf                ; Save interrupt state.
  122.  
  123.                     ; Measure buffer size.
  124.      mov    ax,((kb_buffer_end-kb_buffer)/2 - 1)
  125.      if    LONGDATA
  126.      push    es
  127.      les    bx,ptotal
  128.      assume es:nothing
  129.      mov    [es:bx],ax        ; Return buffer size.
  130.      pop    es
  131.      else
  132.      mov    bx,ptotal
  133.      mov    [bx],ax         ; Return buffer size.
  134.      endif
  135.  
  136.      mov    ax,40h            ; Segment address of BIOS data
  137.      mov    ds,ax
  138.      assume ds:nothing
  139.  
  140.      cli                ; Disable interrupts.
  141.  
  142.                     ; Ignoring wraparound, (tail-head) is
  143.                     ; number of characters in buffer, and
  144.                     ; (head-tail-1) is remaining capacity.
  145.      mov    ax,buffer_head
  146.      cmp    ax,buffer_tail
  147.      ja    measure
  148.  
  149.                     ; Compensate for wraparound.
  150.      add    ax,kb_buffer_end-kb_buffer
  151. measure:
  152.      sub    ax,buffer_tail
  153.      shr    ax,1            ; Convert byte count into word
  154.                     ; count.
  155.      dec    ax
  156.                     ; Now AX has remaining capacity.
  157.  
  158.                     ; Exit.
  159.      popff                ; Restore interrupt state.
  160.  
  161.      if MSC300
  162.      cld                ; Expected by MS C 3.0.
  163.      endif
  164.  
  165.      pop    ds
  166.  
  167.      pop    bp
  168.      ret
  169.  
  170.      if MSC300
  171. _kbqueue endp
  172.      else
  173. kbqueue  endp
  174.      endif
  175.  
  176.      if LAT200 or LAT210 or LAT300
  177.      endps
  178.      endif
  179.  
  180.      if CI201A
  181.      include  epilogue.h
  182.      endif
  183.  
  184.      if MSC300
  185.      endps      kbqueue
  186.      endif
  187.  
  188.      end
  189.