home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c005 / 5.ddi / ISCT2INT.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-08-05  |  6.0 KB  |  251 lines
  1. ;
  2. ; Name        isct2int -- Interface function for C-TOOLS-2-style
  3. ;                interrupt service routines.
  4. ;
  5. ; Synopsis    isct2int(pregs,pisrblk,pmsg);
  6. ;
  7. ;        (Note:    this is not intended for direct use in C
  8. ;        programs.  It to be called from ISDISPAT.ASM,
  9. ;        the ISR dispatcher.)
  10. ;
  11. ;        ALLREG    *pregs      Address of register structure containing
  12. ;                  copies of machine registers in effect
  13. ;                  at the time of the interrupt.
  14. ;        ISRCTRL *pisrblk  Address of this ISR's control block.
  15. ;        ISRMSG    *pmsg      Address of message area between
  16. ;                  ISR dispatcher and this function.
  17. ;
  18. ; Description    This function allows interrupt service routines which
  19. ;        were built using C TOOLS 2 to be used without change
  20. ;        under C TOOLS PLUS.  ISCT2INT is installed by ISSETISR
  21. ;        as an ordinary C TOOLS PLUS interrupt service routine.
  22. ;        Whenever ISCT2INT is invoked, it passes control to the
  23. ;        real ISR in the manner of C TOOLS 2.  When the ISR
  24. ;        returns, ISCT2INT returns any changed register values to
  25. ;        the calling program.
  26. ;
  27. ; Returns    *pregs          Some register values in this structure
  28. ;                  may be changed by the underlying "real"
  29. ;                  ISR.
  30. ;
  31. ; Version    3.0 (C)Copyright Blaise Computing Inc. 1986
  32. ;
  33.  
  34.      name       isct2int
  35.  
  36.      LONGPROG  = 0               ; initialize constants for
  37.      LONGDATA  = 0               ; Pass1 of the assembler
  38.  
  39.      include   compiler.mac        ; Specifies the C compiler
  40.  
  41.      if LAT200 or LAT210 or LAT300
  42.      include  dos.mac
  43.      LONGPROG = LPROG
  44.      LONGDATA = LDATA
  45.  
  46.      pseg
  47.      public   isct2int
  48.  
  49.      if      LONGPROG
  50. isct2int proc      far
  51.      else
  52. isct2int proc      near
  53.      endif
  54.      endif
  55.  
  56.      if MSC300
  57.      include  dos.mac
  58.      LONGPROG = LPROG
  59.      LONGDATA = LDATA
  60.  
  61.      pseg      isct2int
  62.      public   _isct2int
  63.      if      LONGPROG
  64. _isct2int proc       far
  65.      else
  66. _isct2int proc       near
  67.      endif
  68.  
  69.      endif
  70.  
  71.      if    LONGPROG
  72.      x  equ  6
  73.      else
  74.      x  equ  4
  75.      endif
  76.  
  77.      if    LONGDATA
  78. pregs        equ  dword ptr [bp].x
  79. pisrblk     equ  dword ptr [bp].x+4
  80. pmsg        equ  dword ptr [bp].x+8
  81.      else
  82. pregs        equ  word ptr [bp].x
  83. pisrblk     equ  word ptr [bp].x+2
  84. pmsg        equ  word ptr [bp].x+4
  85.      endif
  86.  
  87. ISRCTRL struc                ; ISRCTRL:    ISR control block
  88.                     ; (This must match declaration in
  89.                     ; BISR.H.)
  90.                     ;
  91. icb_fcall_opcode    dw    ?        ; NOP + Far call opcode
  92.                     ;    (0x9A90)
  93. icb_isrdisp        dd    ?        ; Address of ISR dispatcher
  94. icb_iret_opcode     dw    ?        ; IRET + RETF opcodes (0xcbcf)
  95.                     ;    (Offset of icb_iret_opcode
  96.                     ;    is on stack on entry to ISDISPAT.)
  97.                     ;
  98. icb_isrstk_r        dw    ?        ; ISR stack region:  offset
  99. icb_isrstk_s        dw    ?        ;             segment
  100. icb_isrstksize        dw    ?        ; ISR stack size
  101. icb_isrsp        dw    ?        ; ISR SP value at start of
  102.                     ;    current ISR call
  103.                     ;
  104. icb_isrds        dw    ?        ; DS value required by ISR
  105. icb_isres        dw    ?        ; ES value required by ISR
  106. icb_isr         dd    ?        ; Address of this function
  107. icb_isrpsp        dw    ?        ; PSP of program containing ISR
  108.                     ;
  109. icb_prev_vec        dd    ?        ; Previous value of vector
  110.                     ;
  111. icb_level        dw    ?        ; Number of calls in progress
  112.                     ;    (0 if not in progress)
  113. icb_limit        dw    ?        ; Max number of nested calls
  114. icb_signature        dw    ?        ; Signature identifying this
  115.                     ;    structure
  116. icb_sign2        dw    ?        ; One's complement of
  117.                     ;    "signature"
  118. icb_ident        db    16 dup (?)  ; Identifying name
  119. icb_control        dw    ?        ; Bit fields to control
  120.                     ;    dispatcher options
  121. icb_status        dw    ?        ; Status info left by
  122.                     ;    dispatcher
  123. icb_ct2_isr_r        dw    ?        ; Offset  of "real" ISR.
  124. icb_ct2_isr_s        dw    ?        ; Segment of "real" ISR.
  125. icb_scratch        db    6 dup (?)   ; Scratch space for use by
  126.                     ;    dispatcher & related programs
  127. ISRCTRL ends
  128.  
  129. ;   Exit style codes -- these must match BISR.H.
  130.  
  131. IEXIT_NORMAL    equ    0
  132. IEXIT_RETF    equ    1
  133.  
  134. ALLREG     struc                ; ALLREG structure
  135. reg_ax     dw    ?            ; (This must match declaration in
  136. reg_bx     dw    ?            ; BUTILITY.H).
  137. reg_cx     dw    ?
  138. reg_dx     dw    ?
  139. reg_si     dw    ?
  140. reg_di     dw    ?
  141. reg_ds     dw    ?
  142. reg_es     dw    ?
  143. reg_ss     dw    ?
  144. reg_cs     dw    ?
  145. reg_flags dw    ?
  146. reg_bp     dw    ?
  147. reg_sp     dw    ?
  148. reg_ip     dw    ?
  149.  
  150. allreg_size    db  ?
  151. ALLREG     ends
  152.  
  153. ; ****************   BEGIN CODE HERE   ******************
  154.  
  155.      assume ds:nothing,es:nothing,ss:nothing
  156.  
  157.      push    bp            ; Save original BP
  158.      mov    bp,sp
  159.  
  160.      mov    cx,ds            ; Temporarily save entering DS.
  161.  
  162.      if    LONGDATA        ; Get address of control block.
  163.      lds    bx,pisrblk
  164.      else
  165.      mov    bx,pisrblk
  166.      endif
  167.  
  168.      mov    ax,[bx].icb_ct2_isr_s  ; Make sure code address is
  169.      or    ax,[bx].icb_ct2_isr_r  ; nonzero.
  170.      jz    exit            ; (If code address is 0:0,
  171.                     ; just return.)
  172.  
  173.      if    LONGPROG        ; Establish vector through which
  174.      push    [bx].icb_ct2_isr_s  ; we can call the ISR.
  175.      push    [bx].icb_ct2_isr_r
  176. vector     equ    dword ptr [bp-4]
  177.      else
  178.      push    [bx].icb_ct2_isr_r
  179. vector     equ    word ptr [bp-2]
  180.      endif
  181.  
  182.      if    LONGDATA        ; Get address of ALLREG structure.
  183.      lds    bx,pregs
  184.      else
  185.      mov    bx,pregs
  186.      endif
  187.  
  188.      push    [bx].reg_es        ; Push the register values where
  189.      push    [bx].reg_ds        ; the ISR expects to see them.
  190.      push    [bx].reg_di
  191.      push    [bx].reg_si
  192.      push    [bx].reg_dx
  193.      push    [bx].reg_cx
  194.      push    [bx].reg_bx
  195.      push    [bx].reg_ax
  196.  
  197.      mov    ds,cx            ; Restore DS value for ISR.
  198.  
  199.      call    vector            ; Call the ISR.
  200.  
  201.      mov    cx,ds            ; Save DS again.
  202.  
  203.      if    LONGDATA        ; Get address of ALLREG structure.
  204.      lds    bx,pregs
  205.      else
  206.      mov    bx,pregs
  207.      endif
  208.  
  209. ;   Pass resulting register values from ISR back to ALLREG structure.
  210.  
  211.      inc    sp            ; Discard copy of AX on stack,
  212.      inc    sp
  213.      mov    [bx].reg_ax,ax        ;    but return the value which is in
  214.                     ;    AX register.
  215.      pop    [bx].reg_bx
  216.      pop    [bx].reg_cx
  217.      pop    [bx].reg_dx
  218.      pop    [bx].reg_si
  219.      pop    [bx].reg_di
  220.      pop    [bx].reg_ds
  221.      pop    [bx].reg_es
  222.  
  223.      if    LONGPROG        ; Discard the vector
  224.      add    sp,4
  225.      else
  226.      inc    sp
  227.      inc    sp
  228.      endif
  229.  
  230. exit:
  231.      mov    ds,cx            ; Restore DS again.
  232.  
  233.      pop    bp
  234.      ret
  235.  
  236.      if MSC300
  237. _isct2int endp
  238.      else
  239. isct2int endp
  240.      endif
  241.  
  242.      if LAT200 or LAT210 or LAT300
  243.      endps
  244.      endif
  245.  
  246.      if MSC300
  247.      endps      isct2int
  248.      endif
  249.  
  250.      end
  251.