Liren Large Software Subsidy 7/07.iso/c/c005/5.ddi/DOS.ASM

Assembly Source File | 1986-08-05 | 6.8 KB | 258 lines

;
; Name        dos -- Access to DOS functions
;
; Synopsis    ercode = dos(preg);
;
;        int ercode      Error code returned by DOS function
;                  calls which set the carry flag in case
;                  of error.
;        DOSREG *preg      Standard registers
;
; Description    dos() is the gate to the DOS functions.  All registers
;        may be set.  All register values are returned in the
;        structure pointed to by preg except for the DS register
;        (whose value remains unchanged).  Any actual machine
;        registers may be changed by the function except for SS,
;        SP, DS, ES, and any other registers which the C
;        environment requires to be preserved.
;
; Limitation    This function takes special steps to avoid a bug in DOS
;        function 0x4b (Load or Execute a Program).  These steps
;        involve preserving the state of the stack in the local
;        variables savess and savesp.  Therefore this function is
;        NOT RE-ENTRANT in the following limited sense:    If
;        function 0x4b is in progress, then the same copy of
;        dos() should not be used to perform an additional 0x4b
;        call because that would corrupt the original values
;        stored in savess and savesp.
;
;        This limitation does not apply to other DOS functions.
;
; Returns    ercode          Error code returned by DOS function
;                  calls which set the carry flag in case
;                  of error.
;        *preg          The values of the registers may be altered
;                  by some of the DOS function calls.
;
; Version    3.0 (C)Copyright Blaise Computing Inc. 1983,1984,1985,1986
;

popff     macro                ;; Simulate POPF instruction
     local    do_call,do_iret
     jmp    short do_call
do_iret: iret                ;; Pop IP, CS, flags.
do_call: push    cs            ;; Push CS
     call    do_iret         ;; Push IP & jump.
     endm

     name       dosgate

     LONGPROG  = 0               ; initialize constants for
     LONGDATA  = 0               ; Pass1 of the assembler

     include   compiler.mac        ; Specifies the C compiler

     if LAT200 or LAT210 or LAT300
     include  dos.mac
     LONGPROG = LPROG
     LONGDATA = LDATA

     pseg
     public   dos
     if      LPROG
     x   equ  6             ; parameter offset
dos     proc      far
     else
     x   equ  4
dos     proc      near
     endif
     endif

     if MSC300
     include  dos.mac
     LONGPROG = LPROG
     LONGDATA = LDATA

     pseg      dos
     public   _dos
     if      LPROG
     x   equ  6             ; parameter offset
_dos     proc      far
     else
     x   equ  4
_dos     proc      near
     endif
     endif

                       ; Begin the code.

     jmp       short begin_dos

savess     dw       0               ; Storage for stack segment
savesp     dw       0               ; Storage for stack pointer

begin_dos:
     push       bp
     mov       bp,sp
     if       MSC300
     push       di               ; Save register variables
     push       si
     endif
     push       es               ; Save data segment DS and
     push       ds               ; ES

     if       LONGDATA
     les       si,dword ptr [bp + x]  ; Retrieve the parameter
     mov       ax,es:[si]          ; address information.
     mov       bx,es:[si+2]
     mov       cx,es:[si+4]
     mov       dx,es:[si+6]
     mov       di,es:[si+10]
     push       di
     mov       di,si
     mov       si,es:[di+8]
     mov       ds,es:[di+12]
     mov       es,es:[di+14]
     pop       di
     else
     mov       si,[bp+x]
     mov       ax,[si]
     mov       bx,[si+2]
     mov       cx,[si+4]
     mov       dx,[si+6]
     mov       di,[si+10]
     push       di
     mov       di,si
     mov       si,[di+8]
     mov       es,[di+14]
     mov       ds,[di+12]
     pop       di
     endif
     cmp       ah,4bh           ; Check for the EXEC call
     jne       start           ; Different call so begin

;  The EXEC function call under DOS 2.00 can trash part of the data
;  segment.  The purpose of the following code is to change the
;  stack segment to one paragraph "above" the current stack.  Then
;  a 256 byte stack is allocated (which is sufficient for DOS).
;  Giving DOS its own stack avoids the problem.  It does mean that
;  the calling program must have sufficient stack space; worst case
;  begin 256 + 16 bytes.  First we check if 2.00 is the current version;
;  the bug has been fixed in DOS 2.10 and greater.

     mov       cs:savess,ss        ; Save location of stack
     mov       cs:savesp,sp
     push       ax               ; EXEC needs AX and BX so we
     push       bx               ; save them.
     mov       ah,30h
     int       21h
     cmp       al,2            ; Problem only if version 2.00
     jne       stack_ok           ; It is not 2.x, so continue
     cmp       ah,10           ; Is it version 2.10 or greater?
     jae       stack_ok           ; It is, so continue

                       ; Now we know it's version 2.00.
     pop       bx               ; Restore BX and AX
     pop       ax

     cli                   ; No interrupts while constructing
     mov       cl,4            ; new stack segment
     shr       bp,cl           ; Turn into segment address, and
     sub       bp,17           ; one more for safety
     mov       di,ss
     add       di,bp
     mov       ss,di           ; New stack segment,
     mov       sp,256           ; and allow for 256 byte stack
     jmp       short do_4bh

stack_ok:
     pop       bx               ; Restore BX and AX
     pop       ax

do_4bh:
     clc                   ; Clear carry flag for error ret
     cld                   ; Some DOS functions allegedly
                       ; require that DF == 0.
     int       21h
     cli
     mov       ss,cs:savess        ; Restore normal stack.
     mov       sp,cs:savesp
     sti

     jmp       short finish

start:
     clc                   ; Clear carry flag for error ret
     cld                   ; Some DOS functions allegedly
                       ; require that DF == 0.
     int       21h               ; Invoke DOS function (AH)

finish:                    ; Common exit code:

     pop       ds               ; Recover the data segment, DS
     pushf                   ; Save the carry flag
     mov       bp,sp
     if       MSC300
     add       bp,8            ; ES, DI, SI, and flags are on stack
     else
     add       bp,4            ; ES and flags are on the stack
     endif
     push       si

     if       LONGDATA           ; Recover the register information
     push       ax               ; Used to store ES
     push       es
     les       si,dword ptr [bp + x]
     mov       es:[si],ax
     mov       es:[si+2],bx
     mov       es:[si+4],cx
     mov       es:[si+6],dx
     mov       es:[si+10],di
     pop       ax
     mov       es:[si+14],ax       ; Return the value of ES
     pop       ax               ; Recover value of AX
     pop       si
     les       di,dword ptr [bp + x]
     mov       es:[di+8],si
     else
     mov       si,[bp+x]
     mov       [si],ax
     mov       [si+2],bx
     mov       [si+4],cx
     mov       [si+6],dx
     mov       [si+10],di
     mov       [si+14],es
     pop       si               ; Restore SI and use DI to address
     mov       di,[bp+x]           ; the return structure
     mov       [di+8],si
     endif

     popff                   ; Restore the flags and check for
     jc       error           ; a return error code.
     mov       ax,0            ; Returned function value is 0
error:                       ; otherwise value of AX register
     pop       es               ; Recover ES
     if       MSC300
     pop       si               ; Recover index registers
     pop       di               ; (used for register variables)
     cld                   ; MSC 3 expects DF cleared
     endif

     pop       bp
     ret
     if MSC300
_dos     endp
     else
dos     endp
     endif

     if LAT200 or LAT210 or LAT300
     endps
     endif

     if MSC300
     endps      dos
     endif

     end