home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a112 / 1.img / DEMO.PRG < prev    next >
Encoding:
Text File  |  1986-06-16  |  3.8 KB  |  122 lines
  1. * DEMO.PRG ... a program to demonstrate dBASE utilities 
  2. *              CURSOR2, DELAY, FADE, MENUBAR, SAVESCR and SPORT
  3. *              By.. Anton Byers  and friend
  4. set talk off
  5. set escape off
  6. load CURSOR2
  7. load DELAY
  8. load FADE
  9. load MENUBAR
  10. load SAVESCR
  11. load SPORT
  12. call CURSOR2 with 'Off'
  13. use  DEMOFONE index DEMOFONE
  14. if ISCOLOR()
  15.    set  COLOR to W+/B, /W
  16.    BARCOLOR = chr(79)
  17.    STDVIDEO = chr(31)
  18. else
  19.    set  COLOR TO W+/ , /W
  20.    BARCOLOR = chr(120)
  21.    STDVIDEO = chr(15)
  22. endif
  23. clear
  24. @       1, 1 TO 24,78 DOUBLE
  25. @       8,15 TO 20,63 DOUBLE
  26. @       9,17 say 'This program is designed to demonstrate'
  27. @ row()+1,17 say 'a number of the dBASE assembly utilities.'
  28. @ row()+1,17 say 'Utilities used by this program are'
  29. @ row()+1,17 say 'CURSOR2,DELAY, FADE, MENUBAR, SAVESCR, SPORT'
  30. @ row()+1,17 say 'The program is a menu driven autodialer for '
  31. @ row()+1,17 say 'the Hayes SMARTMODEM 1200.  Follow the    '
  32. @ row()+1,17 say 'instructions on your screen'
  33. @ row()+2,17 say '....please wait or press any key to continue'
  34.  
  35. call SAVESCR with 'S1'
  36. call DELAY   with chr(5)
  37. call FADE
  38.  
  39. @  1,20 clear to 24,57
  40. @  1,20 TO 24,57 DOUBLE
  41. @  2,28 say 'DEMO AUTO DIALER'
  42. @ 20,22 say replicate(chr(196),32)
  43. @ 21,22 say 'Use the arrow keys to highlight'
  44. @ 22,22 say 'a selection.  Press RETURN to '
  45. @ 23,22 say 'dial a number  - Esc to Abort'
  46.  
  47. PREVRECS = .F.
  48. do while .T.
  49.    PREVRECS = .F.
  50.    skip - 1 
  51.       if .not. bof()
  52.          skip
  53.          PREVRECS = .T.
  54.       endif
  55.    STARTSCRN = recno()
  56.    @ 6,21 clear to 19,56
  57.    @ 5,22 say replicate(chr(196),32)
  58.    do while row() < 17 .and. .not. eof()
  59.        @ row()+1,22 say NAME + '  '+AREACODE+' '+PHONENUM
  60.        skip
  61.    enddo
  62.    MORERECS = iif(eof(),.F.,.T.)
  63.    if PREVRECS
  64.        @ row()+1,22 say 'Previous Page ...'
  65.    endif
  66.    if MORERECS
  67.        @ row()+1,22 say '    Next Page ...'
  68.    endif
  69.    ONSCREEN = row() - 5
  70.    go STARTSCRN
  71.    MENUBAR = chr(ONSCREEN) + space(1) + chr(7)       + chr(22) +;
  72.              chr(ONSCREEN) + chr(1)   + chr(ONSCREEN)+ chr(1)  +;
  73.              chr(36)       + stdvideo + barcolor
  74.    call MENUBAR with MENUBAR 
  75.    KEY    = substr(MENUBAR,2,1)
  76.    CHOICE = substr(MENUBAR,1,1)
  77.    CHOICE = iif(KEY = chr(27), 0, asc(CHOICE))
  78.    do case
  79.    case CHOICE = 0
  80.         exit
  81.    case MORERECS .and. CHOICE  = ONSCREEN
  82.       skip 12
  83.    case PREVRECS .and. MORERECS .and. CHOICE  = ONSCREEN - 1
  84.       skip - 12
  85.    case PREVRECS .and. CHOICE  = ONSCREEN   
  86.       skip - 12
  87.    otherwise
  88.       skip CHOICE - 1
  89.       if AREACODE = '818' .or. AREACODE = '  '   && local areacode
  90.          DIALCODE = PHONENUM
  91.       else
  92.          DIALCODE = '1 '+ AREACODE + ' '+ PHONENUM
  93.       endif  
  94.       MODEM_MSG = 'WATDT' + DIALCODE + chr(13) + chr(10)  && for smartmodem
  95.       call SAVESCR with 'S2'
  96.       call FADE
  97.       @ 10,10 clear to 16,65
  98.       @ 10,10 to 16,65
  99.       @ 11,12 say 'NAME:      '+NAME
  100.       @ 12,12 say 'Phone #:   ('+AREACODE +') '+ PHONENUM
  101.       @ 13,12 say 'Address:   '+ADDRESS
  102.       @ 14,12 say '           '+trim(CITY)+', '+STATE+'  '+ZIP
  103.       @ 15,12 say 'ATTENTION: '+ATTENTION
  104.       call SPORT with 'P1'
  105.       call SPORT with 'V 1200, N, 8, 1'
  106.       call SPORT with MODEM_MSG
  107.       @ 22,00 clear to 24,79 
  108.       @ 22,00 to 24,79 double
  109.       call DELAY with chr(5)
  110.       @ 23,16 say 'Press ESC when your party answers or to HANG UP'
  111.       MSGBAR = chr(1) + space(1) + chr(24) + chr(2) + chr(1) + chr(1) +;
  112.                chr(1) + chr(1)   + chr(78) + stdvideo + barcolor
  113.       HANGUP = 'WATH' + chr(13)  + chr(10)
  114.       call MENUBAR with MSGBAR
  115.       call SPORT   with HANGUP
  116.       call SAVESCR with 'R2'
  117.       go startscrn
  118.    endcase
  119. enddo
  120. call SAVESCR with 'R1'
  121. call CURSOR2 with 'Normal'
  122.