Liren Large Software Subsidy 5/05.iso/a/a070/3.ddi/FOXPRO/SAMPLE/SALES.PRG

Text File | 1989-11-07 | 4.0 KB | 165 lines

* ┌─────────────────────────────────────────────────────────────────────┐ *
* │  PROG NAME: SALES.PRG - Sales person File Maintenance.              │ *
* │  Copyright (c) 1989 Tech III, Inc. All rights reserved.             │ *
* │  Tech III of San Pedro, California      [phone].             │ *
* │  "The bridge connecting people and technology."(tm)                 │ *
* └─────────────────────────────────────────────────────────────────────┘ *
DO setup_rep
SELECT salesrep
SET ORDER TO sal_sal
IF EOF()
  GO TOP
ENDIF
STORE soldby TO msoldby
DO disp_rep
DO show_rep
STORE .t. TO in_rep
DO WHILE in_rep
  ACTIVATE MENU salesrep PAD search
  IF .NOT. in_prodemo
      DEACTIVATE MENU
  ENDIF
ENDDO
SELECT invoice
CLEAR
RELEASE MENU salesrep
RETURN

PROCEDURE add_rep
  DO disp_rep
  STORE SPACE(3) TO msoldby
  @ 01,28 GET msoldby PICTURE '!!!'
  READ
  SEEK msoldby
  IF FOUND()
    DO show_rep
    DO standby WITH "Can't add this sales rep: rep is already on file."
    RETURN
  ELSE
    APPEND BLANK
    REPLACE NEXT 1 soldby WITH msoldby
  ENDIF
  DO edit_rep
  RETURN

PROCEDURE del_rep
  STORE .f. TO do_it
  ACTIVATE WINDOW msg2user
  @ 01,02 SAY 'Are you sure you want to delete this sales rep? ' GET do_it PICT 'Y'
  READ
  DEACTIVATE WINDOW msg2user
  IF .NOT. do_it
    RETURN
  ENDIF
  DELETE NEXT 1
  IF .NOT. EOF()
    SKIP
  ENDIF
  IF EOF()
    GO BOTTOM
  ENDIF
  DO show_rep
  RETURN

PROCEDURE disp_rep
  CLEAR
  @ 00,01 TO 02,35
  @ 01,03 SAY "Sales Rep Initials:"
  @ 02,01 TO 21,75
  @ 02,01 SAY "├"
  @ 02,35 SAY "┴"
  @ 08,11 SAY '           Name:'
  @ 09,11 SAY '     Date Hired:'
  @ 10,11 SAY '  Date of Birth:'
  @ 12,11 SAY 'Commission Rate:'
  RETURN

PROCEDURE edit_rep
  @ 01,28 GET soldby PICTURE '!!!'
  CLEAR GETS
  @ 08,28 GET salename
  @ 09,28 GET hiredate
  @ 10,28 GET birthdate
  @ 12,28 GET commrate PICTURE '##.##'
  READ

PROCEDURE last_rep
  GO BOTTOM
  DO show_rep
  RETURN

PROCEDURE next_rep
  SKIP
  IF EOF()
    GO BOTTOM
    DO standby WITH "End of file: there is no NEXT sales rep."
  ELSE
    DO show_rep
  ENDIF
  RETURN

PROCEDURE prev_rep
  SKIP -1
  IF BOF()
    GO TOP
    DO standby WITH "Beginning of file: there is no PREVIOUS sales rep."
  ELSE
    DO show_rep
  ENDIF
  RETURN

PROCEDURE quit_rep
  STORE .f. TO in_rep
  DEACTIVATE MENU
  RETURN

PROCEDURE setup_rep
  DEFINE MENU salesrep COLOR SCHEME 3
  DEFINE PAD NEXT   OF salesrep PROMPT '\<Next'   AT 17,3
  DEFINE PAD prev   OF salesrep PROMPT '\<Prev'   AT 17,10
  DEFINE PAD first  OF salesrep PROMPT '\<First'  AT 17,17
  DEFINE PAD LAST   OF salesrep PROMPT '\<Last'   AT 17,25
  DEFINE PAD search OF salesrep PROMPT '\<Search' AT 17,32
  DEFINE PAD EDIT   OF salesrep PROMPT '\<Edit'   AT 17,41
  DEFINE PAD APPEND OF salesrep PROMPT '\<Add'    AT 17,48
  DEFINE PAD DELETE OF salesrep PROMPT '\<Delete' AT 17,54
  DEFINE PAD QUIT   OF salesrep PROMPT '\<Quit'   AT 17,63
  ON SELECTION PAD NEXT       OF salesrep DO next_rep
  ON SELECTION PAD prev       OF salesrep DO prev_rep
  ON SELECTION PAD first      OF salesrep DO top_rep
  ON SELECTION PAD LAST       OF salesrep DO last_rep
  ON SELECTION PAD search     OF salesrep DO srch_rep
  ON SELECTION PAD EDIT       OF salesrep DO edit_rep
  ON SELECTION PAD APPEND     OF salesrep DO add_rep
  ON SELECTION PAD DELETE     OF salesrep DO del_rep
  ON SELECTION PAD QUIT       OF salesrep DO quit_rep
  RETURN

PROCEDURE show_rep
  @ 01,28 SAY soldby PICTURE '!!!'
  @ 08,28 SAY salename
  @ 09,28 SAY hiredate
  @ 10,28 SAY birthdate
  @ 12,28 SAY commrate PICTURE '##.##'
  RETURN

PROCEDURE srch_rep
  last_rec=RECNO()
  STORE SPACE(3) TO msoldby
  @ 01,28 GET msoldby PICTURE '!!!'
  READ
  SEEK msoldby
  IF .NOT. FOUND()
    DO standby WITH "There is no such sales rep on file."
    GO last_rec
  ENDIF
  DO show_rep
  RETURN

PROCEDURE top_rep
  GO TOP
  DO show_rep
  RETURN

  * EOF