home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a066 / 1.img / CYLIST.PRG < prev    next >
Encoding:
Text File  |  1992-03-20  |  1.8 KB  |  90 lines
  1. /*
  2.     cylist.prg
  3.  
  4.     Copyright (c) 1991 Anton van Straaten
  5.  
  6.     06/02/1991 02:42 avs - creation
  7.  
  8.     A linked list class.  Used by the windows class.
  9. */
  10.  
  11. #include "class(y).ch"
  12.  
  13.  
  14. create class List
  15.     instvar items
  16.     instvar currPos
  17.  
  18. export:
  19.     instvar nSize   noassign
  20.  
  21.     method  head
  22.     method  tail
  23.  
  24.     method  next
  25.     method  prev
  26.     method  current
  27.  
  28.     method  add
  29.     method  insert
  30.     method  delete  = listdelete        // delete() is a reserved function name in Clipper
  31.     method  replace
  32. endclass
  33.  
  34.  
  35. constructor new (aItems)
  36.     if valtype(aItems) == 'A'
  37.         ::items := aItems
  38.     elseif aItems != NIL
  39.         ::items := { aItems }
  40.     else
  41.         ::items := {}
  42.     end
  43.     ::nSize := len(::items)
  44.     ::currPos := if(::nSize > 0, 1, 0)
  45. return
  46.  
  47. method function head
  48. return if(::nSize > 0, ::items[::currPos := 1], nil)
  49.  
  50. method function tail
  51. return if(::nSize > 0, ::items[::currPos := ::nSize], nil)
  52.  
  53. method function next
  54. return if(::currPos < ::nSize, ::items[++::currPos], nil)
  55.  
  56. method function prev
  57. return if(::currPos > 1, ::items[--::currPos], nil)
  58.  
  59. method function current
  60. return if(::currPos > 0, ::items[::currPos], nil)
  61.  
  62. method function add(item)
  63.     aadd(::items, item)
  64.     ::currPos := ++::nSize
  65. return item
  66.  
  67. method procedure listdelete
  68.     if ::nSize > 0
  69.         adel(::items, ::currPos)
  70.         asize(::items, --::nSize)
  71.         if ::nSize == 0
  72.             ::currPos := 0
  73.         end
  74.     end
  75. return
  76.  
  77. method function insert(item)
  78.     asize(::items, ++::nSize)
  79.     if ::currPos == 0
  80.         ++::currPos
  81.     end
  82.     ains(::items, ::currPos)
  83. return ::items[::currPos] := item
  84.  
  85. method function replace(item)
  86. return if(::currPos > 0, ::items[::currPos] := item, nil)
  87.  
  88.  
  89. // eof cylist.c
  90.