home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a065 / 1.img / TBPRGS.EXE / TB01.PRG < prev    next >
Encoding:
Text File  |  1992-01-10  |  1.8 KB  |  58 lines
  1.     // Tb01.prg
  2.     //
  3.     // Simple database browse
  4.     // Compile with /a /m /n /w
  5.  
  6.     #include "inkey.ch"
  7.  
  8.     FUNCTION Tb01
  9.  
  10.     FIELD Lname, Fname, Addr1, Addr2, Addr3, Addr4 IN TbDbf1
  11.  
  12.     LOCAL oTbr  := TBrowseDb(1, 1, MaxRow() - 1, MaxCol() - 1)
  13.     LOCAL oTbc1 := TBColumnNew("Last name",  {|| Lname })
  14.     LOCAL oTbc2 := TBColumnNew("First name", {|| Fname })
  15.     LOCAL oTbc3 := TBColumnNew("Address 1",  {|| Addr1 })
  16.     LOCAL oTbc4 := TBColumnNew("Address 2",  {|| Addr2 })
  17.     LOCAL oTbc5 := TBColumnNew("Address 3",  {|| Addr3 })
  18.     LOCAL oTbc6 := TBColumnNew("Address 4",  {|| Addr4 })
  19.     LOCAL nKey
  20.     LOCAL lExitRequested
  21.  
  22.       CLEAR SCREEN
  23.       USE TbDbf1
  24.  
  25.       oTbr:addColumn(oTbc1)
  26.       oTbr:addColumn(oTbc2)
  27.       oTbr:addColumn(oTbc3)
  28.       oTbr:addColumn(oTbc4)
  29.       oTbr:addColumn(oTbc5)
  30.       oTbr:addColumn(oTbc6)
  31.  
  32.       lExitRequested := .F.
  33.       DO WHILE !lExitRequested
  34.         DO WHILE !oTbr:stabilize()
  35.         ENDDO
  36.         nKey := inkey(0)
  37.  
  38.         DO CASE
  39.           CASE nKey == K_DOWN;       oTbr:down()
  40.           CASE nKey == K_UP;         oTbr:up()
  41.           CASE nKey == K_PGDN;       oTbr:pageDown()
  42.           CASE nKey == K_PGUP;       oTbr:pageUp()
  43.           CASE nKey == K_CTRL_PGUP;  oTbr:goTop()
  44.           CASE nKey == K_CTRL_PGDN;  oTbr:goBottom()
  45.           CASE nKey == K_RIGHT;      oTbr:right()
  46.           CASE nKey == K_LEFT;       oTbr:left()
  47.           CASE nKey == K_HOME;       oTbr:home()
  48.           CASE nKey == K_END;        oTbr:end()
  49.           CASE nKey == K_CTRL_LEFT;  oTbr:panLeft()
  50.           CASE nKey == K_CTRL_RIGHT; oTbr:panRight()
  51.           CASE nKey == K_CTRL_HOME;  oTbr:panHome()
  52.           CASE nKey == K_CTRL_END;   oTbr:panEnd()
  53.           CASE nKey == K_ESC;        lExitRequested := .T.
  54.         ENDCASE
  55.       ENDDO
  56.  
  57.     RETURN NIL
  58.