home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 5 / 05.iso / a / a003 / 1.ddi / OVSTACK.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-04  |  3.7 KB  |  120 lines
  1. ;*
  2. ;***************************************************************************
  3. ;*                                                                         *
  4. ;*       OVSTACK.ASM:  Access Routines for Overlay Manager Reload Stack    *
  5. ;*          Copyright (C) 1986 by Phoenix Software Associates Ltd.         *
  6. ;*                                                                         *
  7. ;***************************************************************************
  8. ;*
  9. ;*
  10. ;*      The RELOAD & TRACK commands request PLINK86 to include an overlay
  11. ;*  manager capable of vectoring returns from overlays, as well as the usual
  12. ;*  calls to overlays.  In order to trap returns, the subroutine's return
  13. ;*  address is copied to an internal stack along with the current overlay
  14. ;*  number.  The return address is replaced with the address of an overlay
  15. ;*  manager subroutine.
  16. ;*
  17. ;*      Any stack manipulations should be done with care:  in particular,
  18. ;*  setjmp/longjmp in C bypass normal stack discipline.  To keep the
  19. ;*  internal overlay stack consistent with the application stack, call
  20. ;*  $OVSAVE() just before calling setjmp(), and $OVRESTORE() just before
  21. ;*  calling longjmp().  Make sure that your link file includes a command
  22. ;*  to suppress vectors for $OVSAVE & setjmp, ie "never $OVSAVE, setjmp".
  23. ;*  Also, note that $OVRESTORE loads overlays, possibly smashing the currently
  24. ;*  executing overlay.  Always call $OVRESTORE from your root.  See the sample
  25. ;*  C implementation in the read.me notes.
  26. ;*      Some C implementations allow the application to mark several
  27. ;*  stack locations to return to; others allow only one.  These routines
  28. ;*  support a single location: feel free to customize it if you need that
  29. ;*  complexity.
  30. ;*
  31. ;*
  32.  
  33. name        OVSTACK
  34. PL148    equ    0
  35. CACHING equ    0
  36. include ovtb.h
  37.  
  38. OVcode segment para public 'OVLOADER'
  39.     extrn   $LOAD$: far
  40.     extrn   $$getovnum: near    ; procedures available in reloading versions
  41.     extrn   $$Normalize: near    ; of the overlay loader: these will not
  42.                 ; appear on your map.
  43.     public  $OVSAVE
  44.     public  $OVRESTORE
  45. OVcode ends
  46.  
  47.  
  48. OVdata segment para public 'OVLOADER'
  49.     assume  ds: OVdata
  50.  
  51.     extrn   $OVRSEG$: word
  52.     extrn   $OVROFF$: word
  53.     extrn   $OVRLEV$: word
  54.  
  55.     $$rssegsaved    dw  (?)
  56.     $$rsoffsaved    dw  (?)
  57.     $$rslevsaved    dw  (?)
  58.     $$ovnumsaved    dw (?)    ; saved ov number for reloading
  59. OVdata ends
  60.  
  61.  
  62. OVcode segment para public 'OVLOADER'
  63.     assume  cs: OVcode, ds: OVdata
  64.  
  65. ; ovsave needs to save the ov number of the calling routine.
  66. ; we'll use the return address on the stack for this. Don't vector!
  67. ;
  68.     $OVSAVE proc far
  69.     push    bp
  70.     mov    bp, sp        ; use bp to access ret addr
  71.     push    ES
  72.         push    DS
  73.         push    AX
  74.     push    BX
  75.     mov AX, $OVTB$
  76.     mov ES, AX
  77.         mov AX, OVdata
  78.         mov DS, AX
  79.         mov AX, $OVRSEG$
  80.         mov $$rssegsaved, AX
  81.         mov AX, $OVROFF$
  82.         mov $$rsoffsaved, AX
  83.         mov AX, $OVRLEV$
  84.         mov $$rslevsaved, AX
  85.     mov BX, [bp+2]        ; return offset
  86.     mov AX, [bp+4]        ; paragraph
  87.     call    $$Normalize    ; convert to canonic segment
  88.     call    $$getovnum    ; save current overlay number for 
  89.                 ; later reload by ovrestore
  90.     mov    $$ovnumsaved, ax
  91.     pop BX
  92.         pop AX
  93.         pop DS
  94.     pop ES
  95.     pop bp
  96.         ret
  97.     $OVSAVE endp
  98.  
  99.     $OVRESTORE proc far
  100.         push    DS
  101.         push    AX
  102.         mov AX, OVdata
  103.         mov DS, AX
  104.         mov AX, $$rssegsaved
  105.         mov $OVRSEG$, AX
  106.         mov AX, $$rsoffsaved
  107.         mov $OVROFF$, AX
  108.         mov AX, $$rslevsaved
  109.         mov $OVRLEV$, AX
  110.     mov cx, $$ovnumsaved    ; reload saved overlay context
  111.     call    $LOAD$
  112.         pop AX
  113.         pop DS
  114.         ret
  115.     $OVRESTORE endp
  116.  
  117. OVcode ends
  118.  
  119. end
  120.