home *** CD-ROM | disk | FTP | other *** search
/ Quaaake Level & Editor 2 / Quaaake_2.iso / Quake / vbot / SRC.ZIP / BUTTONS.QC < prev    next >
Encoding:
Text File  |  1996-08-31  |  3.0 KB  |  143 lines
  1. // button and multiple button
  2.  
  3. void() button_wait;
  4. void() button_return;
  5.  
  6. void() button_wait =
  7. {
  8.     self.state = STATE_TOP;
  9.     self.nextthink = self.ltime + self.wait;
  10.     self.think = button_return;
  11.     activator = self.enemy;
  12.     SUB_UseTargets();
  13.     self.frame = 1;            // use alternate textures
  14. };
  15.  
  16. void() button_done =
  17. {
  18.     self.state = STATE_BOTTOM;
  19. };
  20.  
  21. void() button_return =
  22. {
  23.     self.state = STATE_DOWN;
  24.     SUB_CalcMove (self.pos1, self.speed, button_done);
  25.     self.frame = 0;            // use normal textures
  26.     if (self.health)
  27.         self.takedamage = DAMAGE_YES;    // can be shot again
  28. };
  29.  
  30.  
  31. void() button_blocked =
  32. {    // do nothing, just don't ome all the way back out
  33. };
  34.  
  35.  
  36. void() button_fire =
  37. {
  38.     if (self.state == STATE_UP || self.state == STATE_TOP)
  39.         return;
  40.  
  41.     sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
  42.  
  43.     self.state = STATE_UP;
  44.     SUB_CalcMove (self.pos2, self.speed, button_wait);
  45. };
  46.  
  47.  
  48. void() button_use =
  49. {
  50.     self.enemy = activator;
  51.     button_fire ();
  52. };
  53.  
  54. void() button_touch =
  55. {
  56. // BG Bot - bot recognition
  57.         if ((other.classname != "player") && (other.classname != "bot"))
  58.         return;
  59.     self.enemy = other;
  60.     button_fire ();
  61. };
  62.  
  63. void() button_killed =
  64. {
  65.     self.enemy = damage_attacker;
  66.     self.health = self.max_health;
  67.     self.takedamage = DAMAGE_NO;    // wil be reset upon return
  68.     button_fire ();
  69. };
  70.  
  71.  
  72. /*QUAKED func_button (0 .5 .8) ?
  73. When a button is touched, it moves some distance in the direction of it's angle, triggers all of it's targets, waits some time, then returns to it's original position where it can be triggered again.
  74.  
  75. "angle"        determines the opening direction
  76. "target"    all entities with a matching targetname will be used
  77. "speed"        override the default 40 speed
  78. "wait"        override the default 1 second wait (-1 = never return)
  79. "lip"        override the default 4 pixel lip remaining at end of move
  80. "health"    if set, the button must be killed instead of touched
  81. "sounds"
  82. 0) steam metal
  83. 1) wooden clunk
  84. 2) metallic click
  85. 3) in-out
  86. */
  87. void() func_button =
  88. {
  89. local float        gtemp, ftemp;
  90.  
  91.     if (self.sounds == 0)
  92.     {
  93.         precache_sound ("buttons/airbut1.wav");
  94.         self.noise = "buttons/airbut1.wav";
  95.     }
  96.     if (self.sounds == 1)
  97.     {
  98.         precache_sound ("buttons/switch21.wav");
  99.         self.noise = "buttons/switch21.wav";
  100.     }
  101.     if (self.sounds == 2)
  102.     {
  103.         precache_sound ("buttons/switch02.wav");
  104.         self.noise = "buttons/switch02.wav";
  105.     }
  106.     if (self.sounds == 3)
  107.     {
  108.         precache_sound ("buttons/switch04.wav");
  109.         self.noise = "buttons/switch04.wav";
  110.     }
  111.     
  112.     SetMovedir ();
  113.  
  114.     self.movetype = MOVETYPE_PUSH;
  115.     self.solid = SOLID_BSP;
  116.     setmodel (self, self.model);
  117.  
  118.     self.blocked = button_blocked;
  119.     self.use = button_use;
  120.  
  121.     if (self.health)
  122.     {
  123.         self.max_health = self.health;
  124.         self.th_die = button_killed;
  125.         self.takedamage = DAMAGE_YES;
  126.     }
  127.     else
  128.         self.touch = button_touch;
  129.  
  130.     if (!self.speed)
  131.         self.speed = 40;
  132.     if (!self.wait)
  133.         self.wait = 1;
  134.     if (!self.lip)
  135.         self.lip = 4;
  136.  
  137.     self.state = STATE_BOTTOM;
  138.  
  139.     self.pos1 = self.origin;
  140.     self.pos2 = self.pos1 + self.movedir*(fabs(self.movedir*self.size) - self.lip);
  141. };
  142.  
  143.