home *** CD-ROM | disk | FTP | other *** search
/ Quaaake Level & Editor 1 / Quaaake_1.iso / quake / bort1 / holo.qc next >
Encoding:
Text File  |  1996-08-22  |  3.3 KB  |  107 lines
  1. //====================================================================
  2. //
  3. // HOLOGRAPHIC SELF            by: Perecli Manole AKA Bort
  4. //
  5. //====================================================================
  6. // Aside from this new file, the following are the modifications
  7. // done to id's original source files:
  8. //--------------------------------------------------------------------
  9. // File: Progs.src
  10. // Location: before the "weapons.qc" line
  11. // Added: holo.qc
  12. //--------------------------------------------------------------------
  13. // File: Weapons.qc
  14. // Procedure: ImpulseCommands
  15. // Location: first line in the function
  16. // Added: CheckHoloCommand ();
  17. //--------------------------------------------------------------------
  18.  
  19.  
  20. float   ACTIVATE_HOLO = 99;    // impulse constant
  21. float    SEC = 10;        // number of seconds holo is on
  22. float    COST = 10;        // number of power cells holo costs
  23. float    IT_HOLO = 8388608;    // holo bit mask flageee
  24.  
  25.  
  26. //--------------------------------------------------------------------
  27. // When time expires holograph gets deactivated
  28. //--------------------------------------------------------------------
  29. void() RemoveHolo =
  30. {
  31.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  32.     WriteByte (MSG_BROADCAST, TE_TELEPORT);
  33.     WriteCoord (MSG_BROADCAST, self.origin_x);
  34.     WriteCoord (MSG_BROADCAST, self.origin_y);
  35.     WriteCoord (MSG_BROADCAST, self.origin_z);
  36.     sound (self, CHAN_BODY, "misc/r_tele1.wav", 1, ATTN_NORM);
  37.     SUB_Remove();
  38.     self.owner.items = self.owner.items - IT_HOLO;
  39.     sprint(self.owner,"holograph expired\n");
  40. };
  41.  
  42.  
  43. //--------------------------------------------------------------------
  44. // Frames for holograph self
  45. //--------------------------------------------------------------------
  46. void() holo_stand1 = [12, holo_stand2] {};  
  47. void() holo_stand2 = [13, holo_stand3] {};
  48. void() holo_stand3 = [14, holo_stand4] {};
  49. void() holo_stand4 = [15, holo_stand5] {};
  50. void() holo_stand5 = [16, holo_stand1] 
  51. {
  52.     self.health = self.health - 0.5;
  53.     if (self.health <= 0)    
  54.         RemoveHolo();    
  55. };
  56.  
  57.  
  58. //--------------------------------------------------------------------
  59. // Spawns holograph self
  60. //--------------------------------------------------------------------
  61. void(entity myself) ActivateHolo =
  62. {
  63.     local entity    newholo;
  64.  
  65.     newholo = spawn();
  66.     newholo.solid = SOLID_NOT;
  67.     newholo.movetype = MOVETYPE_NOCLIP;
  68.     setmodel (newholo, "progs/player.mdl");
  69.     setorigin (newholo,myself.origin);
  70.     newholo.classname = "holo";
  71.     newholo.angles = myself.angles;
  72.     newholo.colormap = myself.colormap;
  73.     newholo.skin = myself.skin;
  74.     newholo.owner=myself;
  75.     newholo.health = SEC;
  76.     myself.currentammo = myself.ammo_cells = myself.ammo_cells - COST;
  77.     myself.items = myself.items | IT_HOLO;
  78.     stuffcmd (newholo.owner, "bf\n");
  79.     sprint(newholo.owner,"holograph activated\n");
  80.     newholo.nextthink = time;    
  81.     newholo.think = holo_stand1;    
  82. };
  83.  
  84.  
  85.  
  86. //--------------------------------------------------------------------
  87. // Checks if holograph should be activated
  88. //--------------------------------------------------------------------
  89. void() CheckHoloCommand = 
  90. {
  91.     if (self.impulse != ACTIVATE_HOLO )
  92.         return;
  93.  
  94.     if ((self.items & IT_HOLO) == IT_HOLO)
  95.     {
  96.         sprint(self,"holograph active\n");
  97.         return;
  98.     }
  99.  
  100.     if (self.ammo_cells < 10)
  101.     {
  102.         sprint(self,"cells are low\n");
  103.         return;
  104.     }
  105.     
  106.     ActivateHolo (self);
  107. };