home *** CD-ROM | disk | FTP | other *** search
/ PCDisk Magazine Disks / PCDisk Magazine - Disk 1.img / BUGFEAST.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  11.9 KB  |  176 lines
  1. 100  REM BUGFEAST Copyright (c) 1983 by Paul Somerson
  2. 390  KEY1,CHR$(27)+"cls:list"+CHR$(13):KEY2,CHR$(27)+"run"+CHR$(13):KEY9,"":KEY10,"":ONKEY(6)GOSUB2530:KEY(6)ON:ONKEY(7)GOSUB2670:KEY(7)ON:ONKEY(8)GOSUB2430:KEY(8)ON:ONKEY(9)GOSUB2320:KEY(9)ON:ONKEY(10)GOSUB2230:KEY(10)ON:DEFINTA-Z
  3. 500  A$="* * * * * *":K$="Hit any key to continue":SCREEN0,1:WIDTH80:COLOR7,0,0:KEYOFF:CLS:LOCATE11,25,0:PRINT"Are you using a color monitor?
  4. 560  I$=INKEY$:IFI$=""THEN560
  5. 570  CLS:IFI$<>"Y"ANDI$<>"y"THEN590
  6. 580  C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C20=20:GOTO630
  7. 590  C1=7:C2=7:C3=7:C4=7:C5=0:C6=7:C7=7:C20=23
  8. 630  COLORC6,0,0:GOSUB4330:COLORC1,0,0:LOCATE24,1:PRINTSTRING$(32,247);:COLORC6,C4,0:LOCATE24,33:PRINTSTRING$(47,177);:COLORC6,0,0:LOCATE25,1:PRINTCHR$(32);:COLORC5,C2,0:TRUNK$=STRING$(4,176):FORTT=23TO6STEP-1:LOCATETT,69:PRINTTRUNK$
  9. 740  NEXT:LOCATE12,73:PRINTSTRING$(5,176):FORUU=12TO7STEP-1:LOCATEUU,78:PRINTSTRING$(2,176):NEXT:LOCATE13,63:PRINTSTRING$(6,176):FORVV=13TO7STEP-1:LOCATEVV,62:PRINTSTRING$(2,176):NEXT:COLORC2,0,0:LOCATE11,70:PRINTSTRING$(2,32)
  10. 870  FF=1:UNFROG$=SPACE$(4):FROG$="FROG":COLORC2,0,0:X$=CHR$(32)
  11. 890  FORLC=19TO1STEP-1:LOCATE20-LC,LC:PRINT"F":LOCATE20-LC,2*LC:PRINT"R":LOCATE20-LC,LC*3:PRINT"O":LOCATE20-LC,LC*4:PRINT"G":SOUNDLC*500,0.05:LOCATE20-LC,LC:PRINTX$:LOCATE20-LC,LC*2:PRINTX$:LOCATE20-LC,LC*3:PRINTX$
  12. 900  LOCATE20-LC,LC*4:PRINTX$:NEXT:FORV=1TO16:GOSUB2250:FORDLY=1TO150:NEXT:SOUND37,1:SOUND137,1:NEXT:LOCATE23,65:PRINTSTRING$(4,32):COLORC6,0,0:LOCATE10,21:PRINT"Would you like instructions?":COLORC2,0,0
  13. 940  Y$=INKEY$:IFY$=""THEN940
  14. 950  IFY$=CHR$(27)THENDIF=1:GOTO1650
  15. 960  IFY$="Y"ORY$="y"THEN980 ELSE1490
  16. 980  LOCATE6,5:PRINT"It ain't easy bein' green.  A frog just wants":LOCATE7,5:PRINT"his place in the moonlight, some flies, a nice":LOCATE8,5:PRINT"cool dip in the oasis every now and then...
  17. 1010  LOCATE10,5:PRINT"I tell you, it's tough out here in the desert.    ":LOCATE11,5:PRINT"They got snakes that wanna eat you.  They got":LOCATE12,5:PRINT"spiders the size of teacups that wanna bite you.
  18. 1020  LOCATE14,5:PRINT"They even got kids that wanna catch you and":LOCATE15,5:PRINT"put you in a tiny cage and watch you croak.
  19. 1030  LOCATE17,5:PRINT"Anyway, they say life is a game, so we'll see":LOCATE18,5:PRINT"how well you'd do as a frog all alone out here.":LOCATE20,5:PRINTA$:LOCATE20,17:COLORC20,0,0:PRINTK$:COLORC2,0,0:LOCATE20,41:PRINTA$
  20. 1050  INK$=INKEY$:IFINK$=""THEN1050
  21. 1060  FOR SS=20 TO 6 STEP-1:LOCATE SS,5:PRINT STRING$(48,32):NEXT:LOCATE 7,5:PRINT"Ok, some rules first.
  22. 1080  LOCATE7,28:PRINT"Since you've probably never":LOCATE8,5:PRINT"been a real frog before, I'll be a sport and give":LOCATE9,5:PRINT"you":LOCATE9,9:COLORC5,C7,0:PRINT"THREE":LOCATE9,15:COLORC2,0,0:PRINT"chances to survive.  And the best way
  23. 1100  LOCATE10,5:PRINT"to do this is to eat as many fat, juicy, delicious":LOCATE11,5:PRINT"flies as possible.  Of course, if you want to live":LOCATE12,5:PRINT"to be a ripe old frog, you have to watch out for
  24. 1110  LOCATE13,5:PRINT"the three scourges of the desert:":LOCATE15,8:PRINT"1.  Any time, whether you're on land or water,
  25. 1120  LOCATE16,12:PRINT"you gotta watch out for falling cages on":LOCATE17,12:PRINT"strings with little kids at the other end.":LOCATE20,6:PRINTA$:LOCATE20,18:COLORC20,0,0:PRINTK$:LOCATE20,42:COLORC2,0,0:PRINTA$
  26. 1140  INK$=INKEY$:IFINK$=""THEN1140
  27. 1150  FORER=20TO5STEP-1:LOCATEER,5:PRINTSTRING$(52,32):NEXT
  28. 1160  LOCATE5,8:PRINT"2.  If you chase a fly onto the land (near the":LOCATE6,12:PRINT"cactus) you gotta watch out for sinister":LOCATE7,12:PRINT"spiders--one bite and goodbye frog.  You can
  29. 1170  LOCATE8,12:PRINT"squish them by hopping on their furry":LOCATE9,12:PRINT"little bodies, but you have to be careful!!":LOCATE10,12:PRINT"(Every time you squish one you get 5 points).
  30. 1180  LOCATE12,8:PRINT"3.  If you dive under the water (left corner)":LOCATE13,12:PRINT"look out for poisonous water-snakes!  The":LOCATE14,12:PRINT"only thing to do when you spot one is head":LOCATE15,12:PRINT"for the surface p.d.q.
  31. 1190  LOCATE17,5:PRINT"So how is a frog supposed to hop around to catch":LOCATE18,5:PRINT"yummy flies and evade all of those nasty enemies?":LOCATE20,6:PRINTA$:LOCATE20,18:COLORC20,0,0:PRINT"Hit any key to find out
  32. 1200  LOCATE20,42:COLORC2,0,0:PRINTA$
  33. 1210  INK$=INKEY$:IFINK$=""THEN1210
  34. 1220  FORER=20TO5STEP-1:LOCATEER,5:PRINTSTRING$(52,32):NEXT:LOCATE6,5:PRINT"See those grey keys at the lower left corner of":LOCATE7,5:PRINT"your keyboard?
  35. 1240  LOCATE9,9:COLORC5,C7,0:PRINT"F10":LOCATE9,13:COLORC3,0,0:PRINT"hops you one hop to the right.":LOCATE11,9:COLORC5,C7,0:PRINT"F9":LOCATE11,13:COLORC3,0,0:PRINT"hops you one hop to the left.
  36. 1250  LOCATE13,9:COLORC5,C7,0:PRINT"F7":LOCATE13,13:COLORC3,0,0:PRINT"lets you dive when you're ON the water":LOCATE14,13:PRINT"and surface when you're UNDER the water.
  37. 1260  LOCATE16,9:COLORC5,C7,0:PRINT"F8":COLORC3,0,0:LOCATE16,13:PRINT"shoots out your frog tongue, while":LOCATE18,9:COLORC5,C7,0:PRINT"F6":LOCATE18,13:COLORC3,0,0:PRINT"shoots out a L-O-N-G tongue.
  38. 1280  COLORC2,0,0:LOCATE22,5:PRINTA$:LOCATE22,17:COLORC20,0,0:PRINTK$:LOCATE22,41:COLORC2,0,0:PRINTA$
  39. 1290  INK$=INKEY$:IFINK$=""THEN1290
  40. 1300  FORER=22TO5STEP-1:LOCATEER,5:PRINTSTRING$(51,32):NEXT
  41. 1310  LOCATE5,5:PRINT"Got it?  You get":LOCATE5,22:COLORC3,0,0:PRINT"5":LOCATE5,24:COLORC2,0,0:PRINT"points for stomping spiders,":LOCATE6,5:COLORC3,0,0:PRINT"25":LOCATE6,8:COLORC2,0,0:PRINT"for catching flies on your tongue.
  42. 1320  LOCATE8,5:PRINT"Each time you use your":LOCATE8,28:COLORC3,0,0:PRINT"short [F8]":LOCATE8,39:COLORC2,0,0:PRINT"tongue you use":LOCATE9,5:PRINT"up":LOCATE9,8:COLORC7,0,0:PRINT"ONE":LOCATE9,12:COLORC2,0,0:PRINT"lick--each time you use your
  43. 1330  LOCATE9,41:COLORC3,0,0:PRINT"long [F6]":LOCATE10,5:COLORC2,0,0:PRINT"tongue you use":LOCATE10,20:COLORC7,0,0:PRINT"FIVE":LOCATE10,25:COLORC2,0,0:PRINT"licks.":LOCATE12,5:PRINT"Each time you catch a fly you get a couple of":LOCATE13,5
  44. 1340  PRINT"extra licks added to your total.":LOCATE15,5:COLORC6,0,0:PRINT"One more thing:  Every now and then when you're":LOCATE16,5:COLORC5,C7,0:PRINT"UNDER WATER":LOCATE16,17:COLORC6,0,0:PRINT", a strange":LOCATE16,29:COLORC4,0,0
  45. 1350  PRINT"red-eyed":LOCATE16,38:COLORC6,0,0:PRINT"creature peeks":LOCATE17,5
  46. 1360  PRINT"out from a hole in the cactus.  When you see":LOCATE18,5:PRINT"those two horrible blood-crazed eyes, try like":LOCATE19,5:PRINT"crazy to slurp down flies, since each one is":LOCATE20,5:PRINT"momentarily worth a staggering":LOCATE20,36
  47. 1370  COLORC3,0,0:PRINT"250":LOCATE20,40:COLORC6,0,0:PRINT"points!":LOCATE22,5:COLORC2,0,0:PRINTA$:LOCATE22,17:COLORC20,0,0:PRINTK$:LOCATE22,41:COLORC2,0,0:PRINTA$
  48. 1380  INK$=INKEY$:IFINK$=""THEN1380
  49. 1390  FORER=22TO5STEP-1:LOCATEER,5:PRINTSTRING$(48,32):NEXT
  50. 1400  LOCATE5,5:PRINT"Hit `":LOCATE5,10:COLORC5,C7,0:PRINT"A":LOCATE5,12:COLORC2,0,0:PRINT"' if you want to go through all those":LOCATE6,5:PRINT"instructions all over again--or hit any other key":LOCATE7,5:PRINT"to continue...
  51. 1410  INK$=INKEY$:IFINK$=""THEN1410
  52. 1420  IFINK$="A"ORINK$="a"THENINKTR=INKTR+1 ELSE1490
  53. 1430  IFINKTR=2THEN1440 ELSE1450
  54. 1440  IFINKTR>0THENLOCATE5,5:PRINTSTRING$(45,32):LOCATE6,5:PRINT"And you own an IBM PC? ":GOTO1080 ELSE1490
  55. 1450  IFINKTR>0THENLOCATE5,5:PRINTSTRING$(45,32):LOCATE6,5:PRINT"Ok, here we go again:  ":GOTO1080
  56. 1490  FORER=5TO7:LOCATEER,5:PRINTSTRING$(49,32):NEXT
  57. 1500  LOCATE8,5:PRINT"Ok, hotshot, select a level of difficulty:":LOCATE10,8:COLORC5,C7,0:PRINT"1":LOCATE10,11:COLORC3,0,0:PRINT"A tadpole"+STRING$(29,32):LOCATE12,8:COLORC5,C7,0:PRINT"2":LOCATE12,11:COLORC3,0,0:PRINT"Still wet behind the gills
  58. 1510  LOCATE14,8:COLORC5,C7,0:PRINT"3":LOCATE14,11:COLORC3,0,0:PRINT"Young and hot to hop":LOCATE16,8:COLORC5,C7,0:PRINT"4":LOCATE16,11:COLORC3,0,0:PRINT"The main course at Maxim's
  59. 1520  LOCATE18,8:COLORC5,C7,0:PRINT"5":LOCATE18,11:COLORC3,0,0:PRINT"The meanest son-of-a-toad in the pond
  60. 1530  FKY$=INKEY$:IFFKY$=""THEN1530
  61. 1540  DIF=VAL(FKY$):IFDIF<1ORDIF>5THEN1550 ELSE1560
  62. 1550  LOCATE20,5:COLORC20,0,0:PRINT"I said from ONE to FIVE--now pick one!":GOTO1530
  63. 1560  COLORC20,0,0:LOCATEDIF*2+8,6:PRINTCHR$(16):COLORC6,0,0:LOCATE20,5:ONDIFGOTO1570,1580,1590,1600,1610
  64. 1570  PRINT"Ok, we'll go easy on you this time, kid":GOTO1650
  65. 1580  PRINT"Good choice, junior, you'll pick it up fast":GOTO1650
  66. 1590  PRINT"Do you always pick the one in the middle?":GOTO1650
  67. 1600  PRINT"Here goes one green sucker down the tubes...":GOTO1650
  68. 1610  PRINT"Ok, greenmeat, you're on--let's see your stuff.
  69. 1650  Z$=CHR$(236):LICKS=50:FROGS=3:BUGS=0:FRGLFT=0:SQUISH=0:SCORE=0:A=18:B=DIF:AA=5:BB=DIF:FF=65:S=66:LOCATE1,1:PRINTSTRING$(80,205):LOCATE4,1:PRINTSTRING$(80,205):LOCATE3,1:COLOR7,0,0:PRINTSTRING$(80,219)
  70. 1680  LOCATE2,1:COLORC4,0,0:PRINT"F9":LOCATE2,3:COLORC3,0,0:PRINT" moves left;":LOCATE2,16:COLORC4,0,0:PRINT"F10":LOCATE2,19:COLORC3,0,0:PRINT" moves right;":LOCATE2,33:COLORC4,0,0:PRINT"F7":LOCATE2,35:COLORC3,0,0:PRINT" dives/surfaces;
  71. 1690  LOCATE2,52:COLORC4,0,0:PRINT"F8":LOCATE2,54:COLORC3,0,0:PRINT" = tongue;":LOCATE2,65:COLORC4,0,0:PRINT"F6":LOCATE2,67:COLORC3,0,0:PRINT" = supertongue
  72. 1700  LOCATE3,2:COLOR0,C7,0:PRINT"LICKS LEFT":LOCATE3,18:PRINT"FROGS LEFT":LOCATE3,32:PRINT"BUGS CAUGHT":LOCATE3,48:PRINT"SPIDERS SQUISHED":LOCATE3,69:PRINT"SCORE
  73. 1710  LOCATE3,12:COLORC5,C7,0:PRINTLICKS:LOCATE3,28:PRINTFROGS:LOCATE3,43:PRINTBUGS:LOCATE3,64:PRINTSQUISH:LOCATE3,74:PRINTSCORE
  74. 1750  SNAKE$=CHR$(32)+STRING$(6,236)+CHR$(238):SPID1$=CHR$(214)+CHR$(148)+CHR$(183):SPID2$=CHR$(218)+CHR$(148)+CHR$(191)
  75. 1810  TOP$=CHR$(218)+CHR$(194)+CHR$(197)+CHR$(194)+CHR$(191):BOT$=CHR$(192)+STRING$(3,193)+CHR$(217):MDL$=CHR$(195)+STRING$(3,197)+CHR$(180):CORD$=STRING$(2,32)+CHR$(179)+STRING$(2,32)
  76. 1880  EYES$=CHR$(32)+STRING$(2,147):BODY$=CHR$(243)+STRING$(2,234)+CHR$(242):COLORC2,0,0:FROG$=CHR$(243)+STRING$(2,234)+CHR$(242)+CHR$(30)+STRING$(4,29)+CHR$(32)+STRING$(2,147)+CHR$(32):UNFROG$=STRING$(4,32)+CHR$(30)+STRING$(3,29)+STRING$(2,32)
  77. 1920  LOCATE18,76:PRINTEYES$:LOCATE19,76:PRINTBODY$:LOCATE20,76:PRINTEYES$:LOCATE21,76:PRINTBODY$:LOCATE22,76:PRINTEYES$:LOCATE23,76:PRINTBODY$;:UNF$=STRING$(4,32):STRT$="(Hit any key to begin)
  78. 1980  FORST=22TO1STEP-1:LOCATE22,ST+14:PRINTMID$(STRT$,ST,1):NEXT
  79. 1990  INK$=INKEY$:IFINK$=""THEN1990
  80. 2000  FORER=1TO9:LOCATEER+4,5:PRINTSTRING$(47,32):LOCATE23-ER,5:PRINTSTRING$(47,32):NEXT:LOCATE10,25:PRINTSTRING$(22,32):LOCATE18,76:PRINTUNF$:LOCATE19,76:PRINTUNF$:FORT=1TO14:GOSUB2320:NEXT:LOCATE6,61:PRINTCHR$(32)
  81. 2060  GOSUB4450:IFFF>32THENGOSUB3490
  82. 2080  LOCATEAA,BB:COLORC3,0,0:PRINTCHR$(32):LOCATEA,B:COLORC3,0,0:PRINTZ$:GOSUB4500:AA=A:BB=B
  83. 2120  F=INT(RND*4):R=INT(RND*200):IFR>60ANDR<65THENGOSUB2820
  84. 2140  IFRMOD50=0THENGOSUB3200
  85. 2150  ONF+1GOTO2160,2170,2180,2190
  86. 2160  A=A+1:IF (SCREEN(A,B)=32 OR SCREEN(A,B)=236) AND A>13 AND A<21 THEN 2060 ELSE A=A-1:GOTO 2120
  87. 2170  A=A-1:IF (SCREEN(A,B)=32 OR SCREEN(A,B)=236) AND A>13 AND A<21 THEN 2060 ELSE A=A+1:GOTO 2120
  88. 2180  B=B+DIF:IF (SCREEN(A,B)=32 OR SCREEN(A,B)=236) AND B>DIF AND B<80-DIF THEN 2060 ELSE B=B-DIF:GOTO 2120
  89. 2190  B=B-DIF:IF (SCREEN(A,B)=32 OR SCREEN(A,B)=236) AND B>DIF AND B<80-DIF THEN 2060 ELSE B=B+DIF:GOTO 2120
  90. 2230  KEY(9)OFF:GOSUB2770:IFDIVE=1THEN2300
  91. 2240  IFFF<61THEN2250 ELSE2300
  92. 2250  LOCATE23,FF:PRINTUNFROG$;:FF=FF+2:COLORC2,0,0:LOCATE21,FF:PRINTFROG$;:LOCATE21,FF:PRINTUNFROG$;:FF=FF+2:IFSCREEN(23,FF)>32THENSOUND37,2:GOSUB3940
  93. 2290  COLORC2,0,0:LOCATE23,FF:PRINTFROG$;
  94. 2300  KEY(9)ON:RETURN
  95. 2320  KEY(10)OFF:GOSUB2770:IFDIVE=1THEN2390
  96. 2330  IFFF>1THEN2340 ELSE2390
  97. 2340  LOCATE23,FF:PRINTUNFROG$;:FF=FF-2:COLORC2,0,0:LOCATE21,FF:PRINTFROG$;:LOCATE21,FF:PRINTUNFROG$;:FF=FF-2:IFSCREEN(23,FF)>32THENSOUND37,2:GOSUB3940
  98. 2380  COLORC2,0,0:LOCATE23,FF:PRINTFROG$;
  99. 2390  KEY(10)ON:RETURN
  100. 2430  KEY(9)OFF:KEY(10)OFF:GOSUB2770:IFDIVE=1THEN2510
  101. 2440  LICKS=LICKS-1:GOSUB3760:SOUND37,2:SOUND45,1:FORD=21TO18STEP-1:IFSCREEN(D,FF+1)=236ORSCREEN(D,FF+2)=236THENGOSUB3830
  102. 2480  COLORC4,0,0:LOCATED,FF+1:PRINTCHR$(222)+CHR$(221):NEXT:LOCATEAA,BB:PRINTCHR$(32):FORE=18TO21:LOCATEE,FF+1:PRINTSTRING$(2,32):NEXT
  103. 2510  KEY(9)ON:KEY(10)ON:RETURN
  104. 2530  KEY(9)OFF:KEY(10)OFF:GOSUB2770:IFDIVE=1THEN2630
  105. 2560  LICKS=LICKS-5:GOSUB3760:SOUND37,2:SOUND45,1:FORD=21TO9STEP-1:IFSCREEN(D,FF+1)=236ORSCREEN(D,FF+2)=236THENGOSUB3830
  106. 2600  COLORC4,0,0:LOCATED,FF+1:PRINTCHR$(222)+CHR$(221):NEXT:LOCATEAA,BB:PRINTCHR$(32):FORE=7TO21:LOCATEE,FF+1:PRINTSTRING$(2,32):NEXT
  107. 2630  KEY(9)ON:KEY(10)ON:RETURN
  108. 2670  GOSUB2770:IFDIVE<>1THEN2700
  109. 2690  GOSUB4450:LOCATE25,FF:PRINTUNFROG$;:LOCATE24,1:COLORC1,0,0:PRINTSTRING$(32,247);:LOCATE23,FF:COLORC2,0,0:PRINTFROG$;:GOTO2730
  110. 2700  IFFF<33THEN2710 ELSE2730
  111. 2710  GOSUB4450:LOCATE23,FF:PRINTUNFROG$:LOCATE25,FF:COLORC2,0,0:PRINTFROG$;:GOSUB4500
  112. 2730  RETURN
  113. 2770  IFSCREEN(25,1)=243ORSCREEN(25,5)=243ORSCREEN(25,9)=243ORSCREEN(25,13)=243ORSCREEN(25,17)=243ORSCREEN(25,21)=243ORSCREEN(25,25)=243ORSCREEN(25,29)=243THENDIVE=1 ELSEDIVE=0
  114. 2780  RETURN
  115. 2820  IFBONUS=1THEN3070
  116. 2830  GOSUB2770:IFRMOD2=0ANDDIVE=1THENGOSUB3120:GOTO3080
  117. 2850  IFFF>53ORDIVE=1THEN3070
  118. 2860  GOSUB3430:LOCF=FF:FORJ=5TO21STEP2:GOSUB4450:SOUND(22-J)*400,0.05:IFJ>6THEN2920 ELSE2930
  119. 2920  COLORC7,0,0:LOCATEJ-2,LOCF:PRINTCORD$:LOCATEJ-1,LOCF:PRINTCORD$:LOCATEJ,LOCF:PRINTCORD$
  120. 2930  COLORC7,0,0:LOCATEJ,LOCF:PRINTTOP$:LOCATEJ+1,LOCF:PRINTMDL$:LOCATEJ+2,LOCF:PRINTBOT$:GOSUB4500:NEXT:GOSUB2770:IFLOCF=FFANDDIVE=0THENGOSUB4070
  121. 3000  COLORC7,0,0:FORI=23TO5STEP-1:GOSUB4450:LOCATEI,LOCF:PRINTSTRING$(5,32):GOSUB4500:NEXT:IFDEAD=1THENGOSUB4240:GOTO3070
  122. 3050  IFDIVE=0THENGOSUB4450:LOCATE23,FF:COLORC2,0,0:PRINTFROG$
  123. 3060  LOCATE6,61:PRINTCHR$(32):GOSUB4500
  124. 3070  GOSUB3150
  125. 3080  DEAD=0:RETURN
  126. 3120  GOSUB4450:LOCATE11,70:COLORC20,0,0:PRINT"ONTRON":BONUS=1:GOSUB4500:RETURN
  127. 3150  GOSUB4450:LOCATE11,70:COLORC2,0,0:PRINT"  ":BONUS=0:GOSUB4500:RETURN
  128. 3200  GOSUB2770:IFDIVE=1ANDSCREEN(25,1)=32THEN3210 ELSE3390
  129. 3210  SNAKE2$=SNAKE$:GOSUB3430:FORW=1TO8:GOSUB4450
  130. 3240  IFSCREEN(25,W)=243THENOLDFF=FF:GOSUB4070:COLORC4,0,0:LOCATE25,6-W:PRINTSTRING$(W-1,32);:LOCATE25,OLDFF:PRINTUNFROG$;:LOCATE24,OLDFF:COLORC1,0,0:PRINTSTRING$(4,247);:GOSUB4240:GOTO3390
  131. 3250  LOCATE25,1:COLORC4,0,0:PRINTRIGHT$(SNAKE$,W);:SOUNDRND*9000+37,0.025:FORDLY=1TO40:NEXT:GOSUB4500:NEXT:FORW=9TO32:GOSUB4450:SNAKE2$=CHR$(32)+SNAKE2$
  132. 3320  IFSCREEN(25,W)=243THENOLDFF=FF:GOSUB4070:COLORC4,0,0:LOCATE25,W-7:PRINTSTRING$(7,32);:LOCATE25,OLDFF:PRINTUNFROG$;:LOCATE24,OLDFF:COLORC1,0,0:PRINTSTRING$(4,247);:GOSUB4240:GOTO3390
  133. 3330  LOCATE25,1:COLORC4,0,0:PRINTSNAKE2$;:SOUNDRND*9000+37,0.025:FORDLY=1TO40:NEXT:GOSUB4500:NEXT:GOSUB4450:LOCATE25,26:PRINTSTRING$(7,32);:LOCATE6,61:PRINTCHR$(32):GOSUB4500
  134. 3390  RETURN
  135. 3430  GOSUB4450:COLORC3,0,0:LOCATEA,B:PRINTCHR$(32):LOCATEAA,BB:PRINTCHR$(32):LOCATE6,61:PRINTCHR$(236):GOSUB4500:RETURN
  136. 3490  IFFROGS<1THEN3590
  137. 3500  COLORC4,0,0:IFS>33THEN3520 ELSES=66
  138. 3520  GOSUB4450:LOCATE23,S:PRINTSPID2$:FORDLY=1TO50:NEXT:LOCATE23,S:PRINTSTRING$(3,32):IFSCREEN(23,S-1)>32THENLOCATE23,S:PRINTSPID1$:OLDFF=FF:LOCATE23,OLDFF:PRINT"    ":LOCATE22,OLDFF:PRINT"    ":GOSUB4070:GOTO3630
  139. 3560  LOCATE23,S-1:PRINTSPID1$:S=S-1:IFSCREEN(23,33)=214THENLOCATE23,33:PRINTSTRING$(3,32)
  140. 3590  GOSUB4500:RETURN
  141. 3630  GOSUB4450
  142. 3640  IFSCREEN(23,S+1)<>148THENFORSW=32TO65STEP4:LOCATE23,SW:PRINTUNFROG$:NEXT:GOTO3720
  143. 3650  COLORC4,0,0:LOCATE23,S:PRINTSTRING$(3,32):S=S+1:IFS=66THEN3710
  144. 3670  LOCATE23,S:PRINTSPID1$:FORDLY=1TO50:NEXT:LOCATE23,S:PRINTSPID2$:GOTO3640
  145. 3710  LOCATE23,66:PRINTSTRING$(3,32)
  146. 3720  GOSUB4500:GOSUB4240:COLORC4,0,0:GOTO3590
  147. 3760  IFLICKS<1THENLICKS=0
  148. 3770  LOCATE3,12:COLORC5,C7,0:PRINTLICKS:COLORC7,0,0:IFLICKS<1THENFROGS=0:LOCATEA,B:PRINTCHR$(32):GOTO4080
  149. 3790  RETURN
  150. 3830  BUGS=BUGS+1:LOCATE3,43:COLORC5,C7,0:PRINTBUGS:IFBONUS=1THEN3860 ELSE3870
  151. 3860  SCORE=SCORE+250:GOSUB4020:BONUS=0:GOTO3880
  152. 3870  SCORE=SCORE+25:GOSUB4020
  153. 3880  LICKS=LICKS+5:GOSUB3760:BEEP:RETURN
  154. 3940  SQUISH=SQUISH+1:LOCATE3,64:COLORC5,C7,0:PRINTSQUISH:SCORE=SCORE+5:GOSUB4020:COLORC4,0,0:LOCATE23,S:PRINTSTRING$(3,32):S=66:RETURN
  155. 4020  LOCATE3,74:COLORC5,C7,0:PRINTSCORE:RETURN
  156. 4070  FROGS=FROGS-1:GOSUB3430
  157. 4080  PLAY"o2e8e8a2e8a8o3c+2":LOCATE3,28:COLORC5,C7,0:PRINTFROGS:COLORC2,0,0:IFFROGS=0THEN4110 ELSE4200
  158. 4110  IFFF<61THENFORGS=23TO5STEP-1:LOCATEGS,FF:PRINTSTRING$(5,32):NEXT
  159. 4120  FORGG=1TO56STEP4:LOCATE23,GG:PRINTUNFROG$:NEXT:IFFF<32THEN4140 ELSELOCATE23,33:PRINTSTRING$(35,32):GOTO4150
  160. 4140  IF FF>7 THEN COLOR C1,0,0:LOCATE 25,FF-7:PRINT STRING$(11,32);
  161. 4145  COLOR C1,0,0:LOCATE 24,FF:PRINT STRING$(4,247);
  162. 4150  NSP$=INKEY$:IF NSP$<>""THEN NSP$="":GOTO 4150 ELSE GOSUB 4450
  163. 4160  COLOR C3,0,0:LOCATE 2,1:PRINT"....that's all folks.  Hit ":LOCATE 2,28:COLOR C20,0,0:PRINT"Q":COLOR C3,0,0:LOCATE 2,29:PRINT" to quit, or any other key to start this game again.
  164. 4170  U$=INKEY$:IFU$=""THEN4170
  165. 4180  IFU$="Q"ORU$="q"THENLOCATE1,1:END
  166. 4190  COLORC1,0,0:LOCATE6,5:PRINT"(Last time around you selected level":LOCATE6,41:COLORC6,0,0:PRINTDIF:COLORC1,0,0:LOCATE6,43:PRINT")":COLORC2,0,0:GOTO1500
  167. 4200  DEAD=1:FF=65:RETURN
  168. 4240  LOCATE20,76:PRINTUNF$:LOCATE21,76:PRINTUNF$:IFFROGS<2THENLOCATE22,76:PRINTUNF$:LOCATE23,76:PRINTUNF$;
  169. 4260  FORT=1TO14:GOSUB2320:NEXT:LOCATE6,61:PRINTCHR$(32):RETURN
  170. 4330  FORAB=1TO50
  171. 4340  HORND=13-(RND*26):VERND=3-(RND*6):IFVERS+VERND>1ANDVERS+VERND<23THENVERS=VERS+VERND ELSE4340
  172. 4360  IFHORS+HORND>1ANDHORS+HORND<76THENHORS=HORS+HORND ELSE4340
  173. 4370  LOCATEVERS,HORS:PRINT"BUG";:SOUND37+VERS+AB*2,0.5:SOUND37+HORS+AB*2,0.5:LOCATEVERS,HORS:PRINTSTRING$(3,32);:NEXT:CLS:RETURN
  174. 4450  FORKF=6TO10:KEY(KF)STOP:DEFSEG:POKE1050,PEEK(1052):NEXT:RETURN
  175. 4500  FORKF=6TO10:KEY(KF)ON:DEFSEG:POKE1050,PEEK(1052):NEXT:RETURN
  176.