home *** CD-ROM | disk | FTP | other *** search
/ Internet Magazine 2003 October / INTERNET108.ISO / pc / software / windows / building / xmlspy / xmlspyentcomplete5.exe / Data1.cab / _03DB63B8A67F4E2280544289A021A802 < prev    next >
Encoding:
Text File  |  2002-09-24  |  27.0 KB  |  1,055 lines
  1. <!-- XSLT for converting from gcapaper format to HTML + CSS
  2.      Written by Philip Mansfield
  3.      10 November 2001 - Created to handle gcapaper 6.0 (for XML 2001 Conference)
  4.      25 February 2002 - Modified to also handle gcapaper 6.1 (for XML Europe 2002)
  5.      (c) 2001-2 Schema Software Inc.
  6.      You may use, reproduce, modify or redistribute this software under
  7.      the condition that you do not sell it and you include this copyright
  8.      notice in all copies.  For more information, visit
  9.      http://www.schemasoft.com or write to info@schemasoft.com -->
  10. <!-- Slightly modified by Lauren Wood, SoftQuad.
  11.      As per instructions, keywords should not be rendered.
  12.      Included Schemasoft's CSS styling for the HTML in the XSLT -->
  13.  
  14. <xsl:stylesheet version="1.0"
  15.     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  16.  
  17. <xsl:output method="html" doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"
  18. doctype-system="http://www.w3.org/TR/html4/loose.dtd" indent="yes"/>
  19.  
  20. <xsl:template match="gcapaper">
  21.    <html>
  22.       <xsl:apply-templates/>
  23.       <xsl:text disable-output-escaping="yes"></body></xsl:text>
  24.    </html>
  25. </xsl:template>
  26.  
  27. <!-- Front matter -->
  28. <xsl:template match="front">
  29.     <head>
  30.         <xsl:apply-templates select="title|keyword[1]|author" mode="head"/>
  31.         <meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1"/>
  32.         <meta http-equiv="Content-Style-Type" content="text/css"/>
  33.         <style type="text/css">
  34. /* Stylesheet for gca2html output */
  35. /* Produced by Schemasoft (www.schemasoft.com) to go with their XSLT */
  36. body {
  37.   background-color: white;
  38.   color: black;
  39.   font-family: Times, serif;
  40.   margin-left: 2em;
  41.   margin-top: 2em
  42. }
  43. h1, h2, h3, h4, h5, caption { 
  44.   font-family: Arial, Helvetica, sans-serif;
  45.   color: green
  46. }
  47. h1 {
  48.   text-align: center;
  49.   font-size: 1.6em;
  50.   font-weight: bold;
  51.   margin-top: 2em;
  52.   margin-bottom: 2em
  53. }
  54. h2 {
  55.   font-size: 1.3em; 
  56.   margin-top: 4em;
  57.   padding: 2px;
  58.   color: white;
  59.   background-color: green
  60. }
  61. h2.subt {
  62.   text-align: center;
  63.   margin-top: -1.8em;
  64.   margin-bottom: 2em;
  65.   padding: 0px;
  66.   color: green;
  67.   background-color: white;
  68.   font-family: Times, serif
  69. }
  70. h2.abstractHeader, h2.tocHeader {
  71.   text-align: center;
  72.   color: green;
  73.   background-color: white;
  74.   margin-top: 0em;
  75.   margin-bottom: 0em
  76. }
  77. h3 {
  78.   font-size: 1.2em;
  79.   margin-top: 2em
  80. }
  81. h4 {
  82.   font-size: 1.1em;
  83.   margin-top: 2em
  84. }
  85. h5 {
  86.   font-size: 1em; 
  87.   margin-top: 1em; 
  88.   margin-bottom: 0em; 
  89.   background-color: #EEEEEE 
  90. }
  91. dl { margin-top: 2em }
  92. dt {
  93.   margin-top: 0.4em;
  94.   font-family: Arial, Helvetica, sans-serif;
  95.   font-weight: bold;
  96.   font-size: 0.95em
  97. }
  98. dt.bib {
  99.   color: red;
  100.   font-size: 1em
  101. }
  102. dd { margin-top: 0.2em }
  103. dt.termHeading, dd.defHeading { color: red }
  104. code { font-family: monospace }
  105. pre {
  106.   margin-top: 0.5em;
  107.   margin-bottom: 0.5em;
  108.   font-family: monospace
  109. } 
  110. ul li, p { line-height: 1.3em }
  111. .authorName {
  112.   font-family: Arial, Helvetica, sans-serif;
  113.   font-weight: bold
  114. }
  115. p.keyword {
  116.   color: #000099;
  117.   background-color: #DDDDDD
  118. }
  119. p.sectKeyword { color: #000099 }
  120. p.author { margin-top: 1.5em}
  121. p.toc { 
  122.   margin-left: 2em;
  123.   line-height: 1.5em
  124. }
  125. p.abstract {
  126.   margin-left: 2em;
  127.   margin-right: 2em
  128. }
  129. p.figcaptionPara {
  130.   font-size: 0.8em;
  131.   text-align: justify
  132. }
  133. ul.simple { list-style-type: none }
  134. ul.bulleted { list-style-type: disc }
  135. ul.dashed { list-style-type: square }
  136. ol.arabic { list-style-type: decimal }
  137. ol.ualpha { list-style-type: upper-alpha }
  138. ol.uroman { list-style-type: upper-roman }
  139. ol.lalpha { list-style-type: lower-alpha }
  140. ol.lroman { list-style-type: lower-roman }
  141. ol.ftnote {
  142.   list-style-type: decimal;
  143.   font-family: Arial, Helvetica, sans-serif;
  144.   font-size: 0.8em
  145. }
  146. blockquote {
  147.   margin-left: 2em;
  148.   margin-right: 2em;
  149.   background-color: white;
  150.   color: black;
  151.   font-family: Times, serif;
  152.   font-style: normal;
  153.   font-weight: normal;
  154.   font-variant: normal;
  155.   font-size: 1em
  156. }
  157. blockquote.lquote {
  158.   font-family: Arial, Helvetica, sans-serif;
  159.   font-size: 0.8em
  160. }
  161. blockquote.figcaption, blockquote.figurePara, blockquote.figureCodeBlock, blockquote.figureTitle {
  162.   margin-left: 4em;
  163.   margin-right: 4em
  164. }
  165. blockquote.tableHeader {
  166.   margin-top: 1em;
  167.   margin-left: 4em;
  168.   margin-right: 4em;
  169.   margin-bottom: 2em
  170. }
  171. .figure {
  172.   margin-top: 2em;
  173.   margin-bottom: 2em
  174. }
  175. table.note {
  176.   width: 98%;
  177.   border: 1px solid #000099;
  178.   color: #000099
  179. }
  180. table.note td { padding: 0.75em }
  181. .noteHeader {
  182.   font-family: Arial, Helvetica, sans-serif;
  183.   font-weight: bold
  184. }
  185. table.codeBlock {
  186.   width: 98%;
  187.   color: green; 
  188.   background-color: #EEEEEE
  189. }
  190. table.table {
  191.   color: #000099;
  192.   margin-top: 2em;
  193.   empty-cells: show
  194. }
  195. table.table caption {
  196.   caption-side: top;
  197.   margin-left: 4em;
  198.   margin-right: 4em;
  199.   text-align: justify;
  200.   font-size: 0.95em
  201. }
  202. table.table th {
  203.   font-size: 1em;
  204.   font-weight: bold;
  205.   background-color: #000099;
  206.   color: white;
  207.   padding: 0.5em
  208. }
  209. table.table td { padding: 0.5em }
  210. hr { color: #000099 } 
  211. hr.upperBorder {
  212.   margin-top: 2em;
  213.   margin-bottom: 0em
  214. }
  215. hr.lowerBorder {
  216.   margin-top: 0em;
  217.   margin-bottom: 0em
  218. }
  219. cite { color: green }
  220. :link {
  221.   background: none transparent scroll repeat 0% 0%;
  222.   color: #000099
  223. }
  224. :visited {
  225.   background: none transparent scroll repeat 0% 0%;
  226.   color: purple
  227. }
  228. :active {
  229.   background: none transparent scroll repeat 0% 0%;
  230.   color: red
  231. }
  232. @media Screen {
  233. a:hover { background-color: #FFFFCC }
  234. }
  235. a.bibref {
  236.   font-family: Arial, Helvetica, sans-serif  
  237. }
  238. acronym a:link {
  239.   color: black;
  240.   text-decoration: none
  241. }
  242. acronym a:visited {
  243.   color: black;
  244.   text-decoration: none
  245. }
  246. acronym a:active {
  247.   color: black;
  248.   text-decoration: none
  249. }
  250. acronym a:hover {
  251.   color: black;
  252.   background-color: #FFFFCC;
  253.   text-decoration: none
  254. }
  255.             </style>
  256.     </head>
  257.     <xsl:text disable-output-escaping="yes"><body></xsl:text>
  258.     <xsl:apply-templates select="keyword[1]|*[not(self::keyword)]"/>
  259. </xsl:template>
  260.  
  261. <xsl:template match="title" mode="head">
  262.     <title><xsl:value-of select=".//text()"/></title>
  263. </xsl:template>
  264.  
  265. <xsl:template match="keyword[1]" mode="head">
  266.     <meta name="keywords">
  267.         <xsl:attribute name="content">
  268.             <xsl:apply-templates/>
  269.             <xsl:apply-templates select="following-sibling::keyword"/>
  270.         </xsl:attribute>
  271.     </meta>
  272. </xsl:template>
  273.  
  274. <xsl:template match="front/keyword[1]">
  275.     <p class="keyword">
  276.         <i class="keywordHeader"><xsl:text>Keywords: </xsl:text></i>
  277.         <xsl:apply-templates/>
  278.         <xsl:apply-templates select="following-sibling::keyword"/>
  279.     </p>
  280. </xsl:template>
  281.  
  282. <xsl:template match="front/keyword[position()>1]">
  283.     <xsl:text>, </xsl:text>
  284.     <xsl:apply-templates/>
  285. </xsl:template>
  286.  
  287. <xsl:template match="author" mode="head">
  288.     <meta name="author">
  289.         <xsl:attribute name="content">
  290.             <xsl:apply-templates select="fname|surname|suffix"/>
  291.         </xsl:attribute>
  292.     </meta>
  293. </xsl:template>
  294.  
  295. <xsl:template match="surname">
  296.     <xsl:text> </xsl:text>
  297.     <xsl:apply-templates/>
  298. </xsl:template>
  299.  
  300. <xsl:template match="suffix">
  301.     <xsl:text>, </xsl:text>
  302.     <xsl:apply-templates/>
  303. </xsl:template>
  304.  
  305. <xsl:template match="title">
  306.     <h1 class="title"><xsl:apply-templates/></h1>
  307. </xsl:template>
  308.  
  309. <xsl:template match="subt">
  310.     <h2 class="subt"><xsl:apply-templates/></h2>
  311. </xsl:template>
  312.  
  313. <xsl:template match="author">
  314.     <p class="author">
  315.         <span class="authorName"><xsl:apply-templates select="fname|surname|suffix"/></span>
  316.         <xsl:apply-templates select="jobtitle|address"/>
  317.     </p>
  318.     <xsl:apply-templates select="bio"/>
  319. </xsl:template>
  320.  
  321. <xsl:template match="jobtitle">
  322.     <br/><xsl:apply-templates/>
  323. </xsl:template>
  324.  
  325. <xsl:template match="address/*">
  326.     <br/><xsl:apply-templates/>
  327. </xsl:template>
  328.  
  329. <xsl:template match="address/email">
  330.     <br/>
  331.     <a class="email" href="mailto:{text()}">
  332.         <xsl:apply-templates/>
  333.     </a>
  334. </xsl:template>
  335.  
  336. <xsl:template match="address/web">
  337.     <br/>
  338.     <a class="web" href="{text()}">
  339.         <xsl:apply-templates/>
  340.     </a>
  341. </xsl:template>
  342.  
  343. <xsl:template match="bio">
  344.     <p class="bioHeader"><i>Biography</i></p>
  345.     <blockquote class="bio">
  346.         <xsl:apply-templates/>
  347.     </blockquote>
  348. </xsl:template>
  349.  
  350. <xsl:template match="abstract">
  351.     <hr class="upperBorder"/>
  352.     <h2 class="abstractHeader">Abstract</h2>
  353.     <hr class="lowerBorder"/>
  354.     <xsl:apply-templates/>
  355. </xsl:template>
  356.  
  357. <!-- Body -->
  358. <xsl:template match="body">
  359.     <hr class="upperBorder"/>
  360.     <h2 class="tocHeader">Table of Contents</h2>
  361.     <hr class="lowerBorder"/>
  362.     <p class="toc">
  363.         <xsl:apply-templates select=".//title" mode="toc"/>
  364.         <xsl:apply-templates select="/descendant::ftnote[position()=1]" mode="toc"/>
  365.         <xsl:apply-templates select="..//acknowl|..//bibliog" mode="toc"/>
  366.     </p>
  367.     <xsl:apply-templates/>
  368.     <xsl:apply-templates select="/descendant::ftnote[position()=1]" mode="footerStart"/>
  369. </xsl:template>
  370.  
  371. <!-- Rear matter -->
  372. <xsl:template match="acknowl">
  373.     <h2 class="acknowlHeader">
  374.         <a name="S.Acknowledgements">Acknowledgements</a>
  375.     </h2>
  376.     <xsl:apply-templates/>
  377. </xsl:template>
  378.  
  379. <xsl:template match="acknowl/title">
  380.    <h3 class="acknowlTitle">
  381.       <xsl:apply-templates/>
  382.    </h3>
  383. </xsl:template>
  384.  
  385. <xsl:template match="bibliog">
  386.     <h2 class="bibliogHeader">
  387.         <a name="S.Bibliography">Bibliography</a>
  388.     </h2>
  389.     <dl class="bibliog">
  390.         <xsl:apply-templates/>
  391.     </dl>
  392. </xsl:template>
  393.  
  394. <xsl:template match="bib">
  395.     <dt class="bib">
  396.         <xsl:apply-templates select="../@id"/>
  397.         <b>[<xsl:apply-templates/>]</b>
  398.     </dt>
  399. </xsl:template>
  400.  
  401. <xsl:template match="@id">
  402.     <a name="{.}"/>
  403. </xsl:template>
  404.  
  405. <xsl:template match="pub">
  406.     <dd class="pub">
  407.         <xsl:apply-templates/>
  408.     </dd>
  409. </xsl:template>
  410.  
  411. <xsl:template match="bibref">
  412.     <a href="#{@refloc}" class="bibref">
  413.         <b>[<xsl:value-of select="id(@refloc)/bib/text()"/>]</b>
  414.     </a>
  415.     <xsl:text> </xsl:text>
  416. </xsl:template>
  417.  
  418. <!-- Elements that get copied -->
  419. <xsl:template match="b|big|code|i|small|sub|sup|tt">
  420.    <xsl:copy>
  421.       <xsl:apply-templates/>
  422.    </xsl:copy>
  423. </xsl:template>
  424.  
  425. <!-- Paragraphs -->
  426. <xsl:template match="para">
  427.    <p>
  428.       <xsl:apply-templates/>
  429.    </p>
  430. </xsl:template>
  431.  
  432. <xsl:template match="abstract/para">
  433.    <p class="abstract">
  434.       <xsl:apply-templates/>
  435.    </p>
  436. </xsl:template>
  437.  
  438. <xsl:template match="acknowl/para">
  439.    <p class="acknowl">
  440.       <xsl:apply-templates/>
  441.    </p>
  442. </xsl:template>
  443.  
  444. <xsl:template match="li/para">
  445.    <li>
  446.       <xsl:apply-templates/>
  447.    </li>
  448. </xsl:template>
  449.  
  450. <!-- Citations -->
  451. <xsl:template match="cit">
  452.     <cite>
  453.         <xsl:apply-templates/>
  454.     </cite>
  455. </xsl:template>
  456.  
  457. <!-- Quotes -->
  458. <xsl:template match="lquote">
  459.     <blockquote class="lquote">
  460.         <xsl:apply-templates/>
  461.     </blockquote>
  462. </xsl:template>
  463.  
  464. <!-- Acronyms -->
  465. <xsl:template match="acronym">
  466.     <acronym>
  467.         <a>
  468.             <xsl:apply-templates select="@refid"/>
  469.             <xsl:apply-templates/>
  470.         </a>
  471.     </acronym>
  472. </xsl:template>
  473.  
  474. <xsl:template match="acronym/@refid">
  475.     <xsl:attribute name="href">
  476.         <xsl:text>#</xsl:text>
  477.         <xsl:value-of select="."/>
  478.     </xsl:attribute>
  479. </xsl:template>
  480.  
  481. <xsl:template match="acronym.grp/expansion">
  482.     <xsl:apply-templates select="@id"/>
  483.     <xsl:text> (</xsl:text>
  484.         <xsl:apply-templates/>
  485.     <xsl:text>) </xsl:text>
  486. </xsl:template>
  487.  
  488. <!-- Lists -->
  489. <xsl:template match="randlist">
  490.    <ul>
  491.       <xsl:apply-templates select="@style"/>
  492.       <xsl:apply-templates/>
  493.    </ul>
  494. </xsl:template>
  495.  
  496. <xsl:template match="randlist/@style"/>
  497.  
  498. <xsl:template match="randlist/@style[.='simple']">
  499.     <xsl:attribute name="class">simple</xsl:attribute>
  500.     <xsl:attribute name="type">circle</xsl:attribute>
  501. </xsl:template>
  502.  
  503. <xsl:template match="randlist/@style[.='bulleted']">
  504.     <xsl:attribute name="class">bulleted</xsl:attribute>
  505.     <xsl:attribute name="type">disc</xsl:attribute>
  506. </xsl:template>
  507.  
  508. <xsl:template match="randlist/@style[.='dashed']">
  509.     <xsl:attribute name="class">dashed</xsl:attribute>
  510.     <xsl:attribute name="type">square</xsl:attribute>
  511. </xsl:template>
  512.  
  513. <xsl:template match="seqlist">
  514.    <ol>
  515.       <xsl:apply-templates select="@number"/>
  516.       <xsl:apply-templates/>
  517.    </ol>
  518. </xsl:template>
  519.  
  520. <xsl:template match="seqlist/@number"/>
  521.  
  522. <xsl:template match="seqlist/@number[.='arabic']">
  523.     <xsl:attribute name="class">arabic</xsl:attribute>
  524.     <xsl:attribute name="type">1</xsl:attribute>
  525. </xsl:template>
  526.  
  527. <xsl:template match="seqlist/@number[.='ualpha']">
  528.     <xsl:attribute name="class">ualpha</xsl:attribute>
  529.     <xsl:attribute name="type">A</xsl:attribute>
  530. </xsl:template>
  531.  
  532. <xsl:template match="seqlist/@number[.='uroman']">
  533.     <xsl:attribute name="class">uroman</xsl:attribute>
  534.     <xsl:attribute name="type">I</xsl:attribute>
  535. </xsl:template>
  536.  
  537. <xsl:template match="seqlist/@number[.='lalpha']">
  538.     <xsl:attribute name="class">lalpha</xsl:attribute>
  539.     <xsl:attribute name="type">a</xsl:attribute>
  540. </xsl:template>
  541.  
  542. <xsl:template match="seqlist/@number[.='lroman']">
  543.     <xsl:attribute name="class">lroman</xsl:attribute>
  544.     <xsl:attribute name="type">i</xsl:attribute>
  545. </xsl:template>
  546.  
  547. <xsl:template match="deflist">
  548.    <xsl:apply-templates select="title"/>
  549.    <dl>
  550.       <xsl:apply-templates select="*[not(self::title)]"/>
  551.    </dl>
  552. </xsl:template>
  553.  
  554. <xsl:template match="deflist/title">
  555.    <h5 class="deflistTitle">
  556.       <xsl:apply-templates/>
  557.    </h5>
  558. </xsl:template>
  559.  
  560. <xsl:template match="term.heading">
  561.    <dt class="termHeading"><i>
  562.       <xsl:apply-templates/>
  563.    </i></dt>
  564. </xsl:template>
  565.  
  566. <xsl:template match="def.heading">
  567.    <dd class="defHeading"><i>
  568.       <xsl:apply-templates/>
  569.    </i></dd>
  570. </xsl:template>
  571.  
  572. <xsl:template match="def.term">
  573.    <dt>
  574.       <xsl:apply-templates/>
  575.    </dt>
  576. </xsl:template>
  577.  
  578. <xsl:template match="def/para">
  579.    <dd>
  580.         <xsl:apply-templates/>
  581.    </dd>
  582. </xsl:template>
  583.  
  584. <!-- Code blocks -->
  585. <xsl:template match="code.block">
  586.     <table class="codeBlock">
  587.         <tr><td><pre>
  588.             <xsl:apply-templates/>
  589.        </pre></td></tr>
  590.     </table>
  591. </xsl:template>
  592.  
  593. <!-- Notes -->
  594. <xsl:template match="note">
  595.     <table class="note">
  596.         <tr>
  597.             <td>
  598.                 <p>
  599.                     <span class="noteHeader">
  600.                         <xsl:text>NOTE: </xsl:text>
  601.                     </span>
  602.                     <xsl:apply-templates select="para[1]/node()"/>
  603.                 </p>
  604.                 <xsl:apply-templates select="para[position()>1]"/>
  605.            </td>
  606.         </tr>
  607.     </table>
  608. </xsl:template>
  609.  
  610. <!-- Hyperlinks -->
  611. <xsl:template match="a">
  612.     <a href="{@href}">
  613.         <xsl:value-of select="@href"/>
  614.     </a>
  615. </xsl:template>
  616.  
  617. <!-- Footnotes -->
  618. <xsl:template match="fnref">
  619.     <a href="#{@refloc}" class="fnref"><b>
  620.         <xsl:apply-templates select="id(@refloc)" mode="reference"/>
  621.     </b></a>
  622. </xsl:template>
  623.  
  624. <xsl:template match="ftnote" mode="reference">
  625.     <xsl:text>[</xsl:text>
  626.     <xsl:value-of select="count(preceding::ftnote)+count(ancestor::ftnote)+1"/>
  627.     <xsl:text>]</xsl:text>
  628. </xsl:template>
  629.  
  630. <xsl:template match="ftnote"/>
  631.  
  632. <xsl:template match="ftnote" mode="footerStart">
  633.     <h2 class="ftnoteHeader">
  634.         <a name="S.Footnotes">Footnotes</a>
  635.     </h2>
  636.     <ol class="ftnote" type="1">
  637.         <xsl:apply-templates select="//ftnote" mode="footer"/>
  638.     </ol>
  639. </xsl:template>
  640.  
  641. <xsl:template match="ftnote" mode="footer">
  642.     <li>
  643.         <xsl:apply-templates select="@id"/>
  644.         <xsl:apply-templates/>
  645.     </li>
  646. </xsl:template>
  647.  
  648. <!-- Internal links -->
  649. <xsl:template match="xref">
  650.     <a href="#{@refloc}" class="xref"><b>
  651.         <xsl:apply-templates select="id(@refloc)" mode="reference"/>
  652.     </b></a>
  653.     <xsl:text> </xsl:text>
  654. </xsl:template>
  655.  
  656. <xsl:template match="figure" mode="reference">
  657.     <xsl:text>Fig. </xsl:text>
  658.     <xsl:value-of select="count(preceding::figure)+1"/>
  659. </xsl:template>
  660.  
  661. <xsl:template match="table" mode="reference">
  662.     <xsl:text>Table </xsl:text>
  663.     <xsl:value-of select="count(preceding::table)+count(ancestor::table)+1"/>
  664. </xsl:template>
  665.  
  666. <xsl:template match="section" mode="reference">
  667.     <xsl:choose>
  668.         <xsl:when test="/gcapaper/@secnumbers='1'">
  669.             <xsl:text>Chapter </xsl:text>
  670.             <xsl:value-of select="count(preceding::section)+1"/>
  671.         </xsl:when>
  672.         <xsl:otherwise>
  673.             <xsl:value-of select="title//text()"/>
  674.         </xsl:otherwise>
  675.     </xsl:choose>
  676. </xsl:template>
  677.  
  678. <xsl:template match="subsec1|subsec2|subsec3" mode="reference">
  679.     <xsl:choose>
  680.         <xsl:when test="/gcapaper/@secnumbers='1'">
  681.             <xsl:text>Section </xsl:text>
  682.             <xsl:number level="multiple" format="1.1.1.1"
  683.                 count="section|subsec1|subsec2|subsec3"/>
  684.         </xsl:when>
  685.         <xsl:otherwise>
  686.             <xsl:value-of select="title//text()"/>
  687.         </xsl:otherwise>
  688.     </xsl:choose>
  689. </xsl:template>
  690.  
  691. <!-- The table element and its descendants are copied -->
  692. <xsl:template match="table">
  693.     <xsl:apply-templates select="@id"/>
  694.     <div align="center">
  695.         <xsl:copy>
  696.             <xsl:attribute name="class">table</xsl:attribute>
  697.             <xsl:apply-templates select="*|@*|text()" mode="copy"/>
  698.         </xsl:copy>
  699.     </div>
  700.     <blockquote class="tableHeader">
  701.         <div align="center">
  702.             <b>
  703.                 <xsl:text>Table </xsl:text>
  704.                 <xsl:value-of select="count(preceding::table)+count(ancestor::table)+1"/>
  705.             </b>
  706.         </div>
  707.     </blockquote>
  708. </xsl:template>
  709.  
  710. <xsl:template match="td|th|caption" mode="copy">
  711.     <xsl:copy>
  712.         <xsl:apply-templates select="@*" mode="copy"/>
  713.         <!-- Resume normal translation upon exit of table module -->
  714.         <xsl:apply-templates/>
  715.     </xsl:copy>
  716. </xsl:template>
  717.  
  718. <xsl:template match="*|@*|text()" mode="copy">
  719.     <xsl:copy>
  720.         <xsl:apply-templates select="*|@*|text()" mode="copy"/>
  721.     </xsl:copy>
  722. </xsl:template>
  723.  
  724. <!-- Figures -->
  725. <xsl:template match="figure">
  726.     <div class="figure">
  727.         <xsl:apply-templates select="@id"/>
  728.         <xsl:apply-templates select="graphic|code.block|para"/>
  729.         <xsl:apply-templates select="title|figcaption"/>
  730.     </div>
  731. </xsl:template>
  732.  
  733. <xsl:template match="figure/title">
  734.     <blockquote class="figureTitle">
  735.         <div align="center">
  736.             <b>
  737.                 <xsl:text>Fig. </xsl:text>
  738.                 <xsl:value-of select="count(preceding::figure)+1"/>
  739.                 <xsl:text>: </xsl:text>
  740.                 <xsl:apply-templates/>
  741.             </b>
  742.         </div>
  743.     </blockquote>
  744. </xsl:template>
  745.  
  746. <xsl:template match="figcaption">
  747.     <blockquote class="figcaption">
  748.         <xsl:apply-templates/>
  749.     </blockquote>
  750. </xsl:template>
  751.  
  752. <xsl:template match="figcaption/para">
  753.     <p align="justify" class="figcaptionPara">
  754.         <xsl:apply-templates/>
  755.     </p>
  756. </xsl:template>
  757.  
  758. <xsl:template match="figure/para">
  759.     <blockquote class="figurePara">
  760.         <xsl:apply-templates/>
  761.     </blockquote>
  762. </xsl:template>
  763.  
  764. <xsl:template match="figure/code.block">
  765.     <blockquote class="figureCodeBlock">
  766.         <pre>
  767.             <xsl:apply-templates/>
  768.         </pre>
  769.     </blockquote>
  770. </xsl:template>
  771.  
  772. <xsl:template match="graphic">
  773.     <div align="center" class="graphic">
  774.         <xsl:call-template name="Image"/>
  775.     </div>
  776. </xsl:template>
  777.  
  778. <xsl:template name="Image" match="inline.graphic">
  779.     <img>
  780.         <xsl:choose>
  781.             <xsl:when test="boolean(@href)">
  782.                 <!-- If there is an href attribute, use it directly -->
  783.                 <xsl:attribute name="alt">
  784.                     <xsl:value-of select="@href"/>
  785.                 </xsl:attribute>
  786.                 <xsl:attribute name="src">
  787.                     <xsl:value-of select="@href"/>
  788.                 </xsl:attribute>
  789.             </xsl:when>
  790.             <xsl:otherwise>
  791.                 <!-- Otherwise, there is a figname attribute that takes an entity -->
  792.                 <xsl:attribute name="alt">
  793.                     <xsl:value-of select="@figname"/>
  794.                 </xsl:attribute>
  795.                 <xsl:attribute name="src">
  796.                     <!-- Compute the relative URI of the graphic file -->
  797.                     <xsl:call-template name="SubstringAfterLast">
  798.                         <xsl:with-param name="string" select="unparsed-entity-uri(@figname)"/>
  799.                         <xsl:with-param name="token" select="'/'"/>
  800.                     </xsl:call-template>
  801.                 </xsl:attribute>
  802.             </xsl:otherwise>
  803.         </xsl:choose>
  804.         <!-- If scaled, use given height and width numbers as pixels.
  805.                 When height and width are given in CSS units (e.g. "6in"), compute
  806.                 pixels assuming 96dpi. When in unrecognized units, set width="100%" -->
  807.         <xsl:if test="@scalefit='1'">
  808.             <xsl:variable name="pixelWidth">
  809.                 <xsl:call-template name="ConvertToPixels">
  810.                     <xsl:with-param name="length" select="@width"/>
  811.                 </xsl:call-template>
  812.             </xsl:variable>
  813.             <xsl:variable name="pixelHeight">
  814.                 <xsl:call-template name="ConvertToPixels">
  815.                     <xsl:with-param name="length" select="@height"/>
  816.                 </xsl:call-template>
  817.             </xsl:variable>
  818.             <xsl:choose>
  819.                 <xsl:when test="number($pixelWidth) > 0 or number($pixelHeight) > 0">
  820.                     <xsl:if test="number($pixelWidth) > 0">
  821.                         <xsl:attribute name="width">
  822.                             <xsl:value-of select="$pixelWidth"/>
  823.                         </xsl:attribute>
  824.                     </xsl:if>
  825.                     <xsl:if test="number($pixelHeight) > 0">
  826.                         <xsl:attribute name="height">
  827.                             <xsl:value-of select="$pixelHeight"/>
  828.                         </xsl:attribute>
  829.                     </xsl:if>
  830.                 </xsl:when>
  831.                 <xsl:otherwise>
  832.                     <xsl:attribute name="width">100%</xsl:attribute>
  833.                 </xsl:otherwise>
  834.             </xsl:choose>
  835.         </xsl:if>
  836.     </img>
  837. </xsl:template>
  838.  
  839. <!-- Utility function to convert lengths to pixels -->
  840. <xsl:template name="ConvertToPixels">
  841.     <xsl:param name="length"/>
  842.     <xsl:variable name="pixels" select="number(substring-before($length,'px'))"/>
  843.     <xsl:variable name="inches" select="number(substring-before($length,'in'))"/>
  844.     <xsl:variable name="cms" select="number(substring-before($length,'cm'))"/>
  845.     <xsl:variable name="mms" select="number(substring-before($length,'mm'))"/>
  846.     <xsl:variable name="pts" select="number(substring-before($length,'pt'))"/>
  847.     <xsl:variable name="picas" select="number(substring-before($length,'pc'))"/>
  848.     <xsl:choose>
  849.         <xsl:when test="boolean(number($length))">
  850.             <xsl:value-of select="$length"/>
  851.         </xsl:when>
  852.         <xsl:when test="boolean($pixels)">
  853.             <xsl:value-of select="$pixels"/>
  854.         </xsl:when>
  855.         <xsl:when test="boolean($inches)">
  856.             <xsl:value-of select="96 * $inches"/>
  857.         </xsl:when>
  858.         <xsl:when test="boolean($cms)">
  859.             <xsl:value-of select="(96 * $cms) div 2.54"/>
  860.         </xsl:when>
  861.         <xsl:when test="boolean($mms)">
  862.             <xsl:value-of select="(96 * $mms) div 25.4"/>
  863.         </xsl:when>
  864.         <xsl:when test="boolean($pts)">
  865.             <xsl:value-of select="(96 * $pts) div 72"/>
  866.         </xsl:when>
  867.         <xsl:when test="boolean($picas)">
  868.             <xsl:value-of select="(96 * $picas) div 6"/>
  869.         </xsl:when>
  870.         <xsl:otherwise>0</xsl:otherwise>
  871.     </xsl:choose>
  872. </xsl:template>
  873.  
  874. <!-- Utility function to find the substring after the last occurrence of a token -->
  875. <xsl:template name="SubstringAfterLast">
  876.     <xsl:param name="string"/>
  877.     <xsl:param name="token"/>
  878.     <xsl:choose>
  879.         <xsl:when test="contains($string,$token)">
  880.             <xsl:call-template name="SubstringAfterLast">
  881.                 <xsl:with-param name="string" select="substring-after($string,$token)"/>
  882.                 <xsl:with-param name="token" select="$token"/>
  883.             </xsl:call-template>
  884.         </xsl:when>
  885.         <xsl:otherwise>
  886.             <xsl:value-of select="$string"/>
  887.         </xsl:otherwise>
  888.     </xsl:choose>
  889. </xsl:template>
  890.  
  891. <!-- Section/subsection titles become h1, h2, h3, h4
  892.      The titles are numbered if the secnumbers attribute is 1
  893.      Two kinds of anchors are generated at each heading:
  894.      1. An anchor whose name is the section id attribute, if it exists
  895.      2. A unique numerical anchor used by Table of Contents -->
  896. <xsl:template match="section|subsec1|subsec2|subsec3">
  897.     <xsl:apply-templates select="keyword[1]|*[not(self::keyword)]"/>
  898. </xsl:template>
  899.  
  900. <xsl:template match="section/title">
  901.     <h2>
  902.         <xsl:call-template name="anchoredNumberedTitle">
  903.             <xsl:with-param name="prefix">
  904.                 <xsl:number level="single" format="1."
  905.                     count="section"/>
  906.             </xsl:with-param>
  907.         </xsl:call-template>
  908.     </h2>      
  909. </xsl:template>
  910.  
  911. <xsl:template match="subsec1/title">
  912.     <h3>
  913.         <xsl:call-template name="anchoredNumberedTitle">
  914.             <xsl:with-param name="prefix">
  915.                 <xsl:number level="multiple" format="1.1"
  916.                     count="section|subsec1"/>
  917.             </xsl:with-param>
  918.         </xsl:call-template>
  919.     </h3>      
  920. </xsl:template>
  921.  
  922. <xsl:template match="subsec2/title">
  923.     <h4>
  924.         <xsl:call-template name="anchoredNumberedTitle">
  925.             <xsl:with-param name="prefix">
  926.                 <xsl:number level="multiple" format="1.1.1"
  927.                     count="section|subsec1|subsec2"/>
  928.             </xsl:with-param>
  929.         </xsl:call-template>
  930.     </h4>      
  931. </xsl:template>
  932.  
  933. <xsl:template match="subsec3/title">
  934.     <h5>
  935.         <xsl:call-template name="anchoredNumberedTitle">
  936.             <xsl:with-param name="prefix">
  937.                 <xsl:number level="multiple" format="1.1.1.1"
  938.                     count="section|subsec1|subsec2|subsec3"/>
  939.             </xsl:with-param>
  940.         </xsl:call-template>
  941.     </h5>      
  942. </xsl:template>
  943.  
  944. <xsl:template name="anchoredNumberedTitle">
  945.     <xsl:param name="prefix"/>
  946.     <xsl:apply-templates select="../@id"/>
  947.     <a name="S{$prefix}">
  948.         <xsl:if test="/gcapaper/@secnumbers='1'">
  949.             <xsl:value-of select="$prefix"/>
  950.             <xsl:text> </xsl:text>
  951.         </xsl:if>
  952.         <xsl:apply-templates/>
  953.     </a>
  954. </xsl:template>
  955.  
  956. <xsl:template match="section/keyword[1]|subsec1/keyword[1]
  957.     |subsec2/keyword[1]|subsec3/keyword[1]">
  958.     <p class="sectKeyword">
  959.         <i class="sectKeywordHeader"><xsl:text>Keywords: </xsl:text></i>
  960.         <xsl:apply-templates/>
  961.         <xsl:apply-templates select="following-sibling::keyword"/>
  962.     </p>
  963. </xsl:template>
  964.  
  965. <!-- Table of Contents -->
  966. <xsl:template match="title" mode="toc"/>
  967.  
  968. <xsl:template match="section/title" mode="toc">
  969.     <b>
  970.         <xsl:call-template name="linkedNumberedTitle">
  971.             <xsl:with-param name="prefix">
  972.                 <xsl:number level="single" format="1."
  973.                     count="section"/>
  974.             </xsl:with-param>
  975.         </xsl:call-template>
  976.     </b>
  977.     <br/>
  978. </xsl:template>
  979.  
  980. <xsl:template match="subsec1/title" mode="toc">
  981.     <xsl:text disable-output-escaping="yes">
  982.         <![CDATA[    ]]>
  983.     </xsl:text>
  984.         <xsl:call-template name="linkedNumberedTitle">
  985.             <xsl:with-param name="prefix">
  986.                 <xsl:number level="multiple" format="1.1"
  987.                     count="section|subsec1"/>
  988.             </xsl:with-param>
  989.         </xsl:call-template>
  990.     <br/>
  991. </xsl:template>
  992.  
  993. <xsl:template match="subsec2/title" mode="toc">
  994.     <xsl:text disable-output-escaping="yes">
  995.         <![CDATA[        ]]>
  996.     </xsl:text>
  997.         <xsl:call-template name="linkedNumberedTitle">
  998.             <xsl:with-param name="prefix">
  999.                 <xsl:number level="multiple" format="1.1.1"
  1000.                     count="section|subsec1|subsec2"/>
  1001.             </xsl:with-param>
  1002.         </xsl:call-template>
  1003.     <br/>
  1004. </xsl:template>
  1005.  
  1006. <xsl:template match="subsec3/title" mode="toc">
  1007.     <xsl:text disable-output-escaping="yes">
  1008.         <![CDATA[        
  1009.             ]]>
  1010.     </xsl:text>
  1011.         <xsl:call-template name="linkedNumberedTitle">
  1012.             <xsl:with-param name="prefix">
  1013.                 <xsl:number level="multiple" format="1.1.1.1"
  1014.                     count="section|subsec1|subsec2|subsec3"/>
  1015.             </xsl:with-param>
  1016.         </xsl:call-template>
  1017.     <br/>
  1018. </xsl:template>
  1019.  
  1020. <xsl:template name="linkedNumberedTitle">
  1021.     <xsl:param name="prefix"/>
  1022.     <a href="#S{$prefix}">
  1023.         <xsl:if test="/gcapaper/@secnumbers='1'">
  1024.             <xsl:value-of select="$prefix"/>
  1025.             <xsl:text> </xsl:text>
  1026.         </xsl:if>
  1027.         <xsl:apply-templates mode="titleText"/>
  1028.     </a>
  1029. </xsl:template>
  1030.  
  1031. <xsl:template match="expansion|ftnote" mode="titleText"/>
  1032.  
  1033. <xsl:template match="text()" mode="titleText">
  1034.   <xsl:value-of select="."/>
  1035. </xsl:template>
  1036.  
  1037. <xsl:template match="ftnote" mode="toc">
  1038.     <b><a href="#S.Footnotes">Footnotes</a></b>
  1039.     <br/>
  1040. </xsl:template>
  1041.  
  1042. <xsl:template match="acknowl" mode="toc">
  1043.     <b><a href="#S.Acknowledgements">Acknowledgements</a></b>
  1044.     <br/>
  1045. </xsl:template>
  1046.  
  1047. <xsl:template match="bibliog" mode="toc">
  1048.     <b><a href="#S.Bibliography">Bibliography</a></b>
  1049.     <br/>
  1050. </xsl:template>
  1051.  
  1052. <xsl:template match="keyword">
  1053. </xsl:template>
  1054. </xsl:stylesheet>
  1055.