home *** CD-ROM | disk | FTP | other *** search
/ AppleDisk 6 / AppleDisk_006.dsk / TRADUTTORE.bas < prev    next >
Encoding:
BASIC Source File  |  1986-01-01  |  18.6 KB  |  297 lines
  1. 10  REM  **********************
  2. 20  REM  *     TRADUTTORE     *
  3. 30  REM  *   DI KEN PENNER    *
  4. 40  REM  * COPYRIGHT (C) 1986 *
  5. 50  REM  *  BY EDITRONICA &   *
  6. 60  REM  *  MICROSPARC, INC   *
  7. 70  REM  **********************
  8. 80  REM  VARIABILI IMPORTANTI-DW$(N)-MATRICE PAROLE DIZIONARIO, DF$(N)-MATRICE SIGNIFICATI DIZIONARIO, NT$(N)-MATRICE NOTE DIZIONARIO, NW-NUMERO PAROLE NEL DIZIONARIO
  9. 90  CLEAR : DIM DW$(1000),DF$(1000),NT$(1000)
  10. 100  DIM X$(1),SL(6):X$(0) = "   ":X$(1) = "-->": GOSUB 2670:SX = 4
  11. 110 D$ =  CHR$(4)
  12. 120  REM   MENU
  13. 130  HOME : INVERSE : HTAB 10: PRINT "*** IL TRADUTTORE ***": NORMAL : VTAB 8: HTAB 14: PRINT "DI KEN PENNER": VTAB 15: PRINT "(C) 1986 BY EDITRONICA & MICROSPARC,INC"
  14. 140  VTAB 23: HTAB 5: PRINT "PREMERE <RETURN> PER CONTINUARE";: GET Z$: PRINT 
  15. 150  GOSUB 230
  16. 160  ONERR  GOTO 2450
  17. 170  TEXT :TL = 1:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690: GOSUB 230
  18. 180  GOSUB 2740: IF Z = 20  THEN  PRINT  CHR$(7): GOTO 180
  19. 190  IF NW = 0  AND SL < >1  AND SL < >7  AND SL < >9  THEN  HOME : VTAB 12: PRINT "NESSUN DATO IN MEMORIA...": GOSUB 2660: GOTO 170
  20. 200  ON SL GOSUB 280,420,730,870,1220,1410,1930,2170,2520
  21. 210 B$ = "": ON A$ = "S"  AND SL = 8 GOTO 90: GOTO 170
  22. 220  GOTO 130
  23. 230  IF DW$ = ""  THEN 260
  24. 240  VTAB 1: HTAB 1: PRINT "LINGUA: "DW$"/"DF$;
  25. 250  VTAB 2: HTAB 1: PRINT "PAROLE NEL DIZIONARIO: "NW;
  26. 260  RETURN 
  27. 270  REM  INSERIMENTO NUOVE PAROLE    
  28. 280  HOME : VTAB 1: HTAB 1: INVERSE : PRINT "INSERIMENTO PAROLE": NORMAL : PRINT 
  29. 290  POKE 34,1
  30. 300 XX = 0: GOSUB 2090: IF XX = 27  THEN  RETURN 
  31. 310 NW = NW +1: IF NW >800  THEN  HOME : VTAB 12: PRINT "HAI RAGGIUNTO IL MASSIMO DI 800 PAROLE.": PRINT : PRINT "SALVA IL DIZIONARIO.": GOSUB 2660: RETURN 
  32. 320  GOSUB 2580: IF FM <100  THEN  RETURN 
  33. 330  VTAB 4: HTAB 1: CALL  -958: VTAB 4: PRINT "INTRODUCI NUOVA PAROLA/FRASE "DW$: PRINT "N.";NW;: INPUT "--> ";DW$(NW):DW$(NW) = " " +DW$(NW) +" ": IF DW$(NW) = "  "  THEN DW$(NW) = "":NW = NW -1: RETURN 
  34. 340  PRINT : PRINT "INTRODUCI SIGNIFICATO DELLA PAROLA/FRASE "DF$: INPUT "--> ";DF$(NW):DF$(NW) = " " +DF$(NW) +" ": IF DF$(NW) = "  "  THEN 330
  35. 350  PRINT : PRINT "INTRODUCI NOTE (IN "DF$") O <RC>": INPUT "--> ";NT$(NW): IF NT$(NW) < >""  THEN NT$(NW) = " " +NT$(NW) +" "
  36. 360  PRINT : PRINT "(C) PER CAMBIARE, <ESC> PER IL MENU": PRINT "<RETURN> PER CONTINUARE": GOSUB 2640:N = NW:B$ = "1"
  37. 370 N = NW:B$ = "1"
  38. 380  IF XX = 27  THEN  PRINT : RETURN 
  39. 390  IF XX = 67  THEN NW = NW -1: PRINT : GOTO 310
  40. 400  PRINT : GOTO 280
  41. 410  REM  MODIFICARE PAROLE/SIGNIFICATI
  42. 420  TEXT :TL = 2:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690
  43. 430  GOSUB 2740: IF Z = 20  THEN  RETURN 
  44. 440 N = 1:B$ =  STR$(SL(TL))
  45. 450  HOME : IF B$ = "2"  THEN KEY$ = "SIGNIFICATO"
  46. 460  IF B$ = "1"  THEN KEY$ = "PAROLA"
  47. 470 L =  LEN(KEY$)
  48. 480  VTAB 5: PRINT KEY$" DA MODIFICARE:": PRINT "--> ": PRINT : PRINT KEY$" N.--> "
  49. 490  VTAB 20: PRINT "-> E <- COMANDANO LO SCORRIMENTO": PRINT "<ESC> PER IL MENU": PRINT "<RETURN> PER MODIFICARE"
  50. 500  GOTO 570
  51. 510  VTAB 10: HTAB 34: WAIT  -16384,128:X =  PEEK( -16384) -128: IF X = 21  THEN N = N +1
  52. 520  IF X = 8  THEN N = N -1
  53. 530  IF X = 13  THEN 620
  54. 540  IF X = 27  THEN  GOTO 420
  55. 550  IF N < = 0  THEN N = NW: GOTO 570
  56. 560  IF N >NW  THEN N = 1
  57. 570  IF KEY$ = "PAROLA"  THEN EDIT$ = DW$(N)
  58. 580  IF KEY$ = "SIGNIFICATO"  THEN EDIT$ = DF$(N)
  59. 590  VTAB 6: HTAB 5: PRINT EDIT$"                               ";: REM  30 SPAZI 
  60. 600  VTAB 8: HTAB L +8: PRINT N"  "
  61. 610  POKE  -16368,0: GOTO 510
  62. 620  HOME : INVERSE : PRINT "MODO EDIT": NORMAL : PRINT : POKE 34,1: POKE  -16368,0
  63. 630  HTAB 1: VTAB 24: PRINT "<RETURN> ACCETTA  <CTRL>BDFINQZ=MODIFICA";: HTAB 1: VTAB 3
  64. 640  GOSUB 700: PRINT : PRINT "INTRODUCI NUOVA PAROLA/FRASE CORRETTA":M$ = DW$(N):T =  PEEK(37): PRINT : PRINT M$;: GOSUB 2200:DW$(N) = R$: GOSUB 700
  65. 650  PRINT : PRINT : PRINT "INRODUCI SIGNIFICATO CORRETTO":M$ = DF$(N):T =  PEEK(37): PRINT : PRINT M$;: GOSUB 2200:DF$(N) = R$: GOSUB 700
  66. 660  PRINT : PRINT : PRINT "INTRODUCI NOTA CORRETTA":M$ = NT$(N):T =  PEEK(37): PRINT : PRINT M$;: GOSUB 2200:NT$(N) = R$
  67. 670  HTAB 1: VTAB 23: CALL  -958: HTAB 1: PRINT "<ESC> PER IL MENU, (C) PER CAMBIARE": PRINT "<RETURN> PER CONTINUARE";: GOSUB 2640: IF XX = 27  OR N = NW  THEN 420
  68. 680  IF XX = 67  THEN 620
  69. 690  IF XX = 13  THEN  HOME :N = N +1: GOTO 450
  70. 700  IF  PEEK(37) >16  THEN N1 =  PEEK(37): FOR N2 = 1 TO N1 -16: CALL  -912: VTAB N1 -N: NEXT 
  71. 710  RETURN 
  72. 720  REM  ROUTINE ORDINAMENTO ALFABETICO
  73. 730  HOME : POKE 34,1: INVERSE : PRINT "ORDINAMENTO ALFABETICO": NORMAL : VTAB 12: HTAB 8: INVERSE : PRINT "UN MOMENTO, PREGO...": NORMAL :Y = NW +1:M3 = Y
  74. 740 M3 =  INT(M3/2): IF M3 = 0  THEN SS = 0: GOTO 850
  75. 750 K1 = Y -M3:J1 = 1
  76. 760 H1 = J1
  77. 770 L1 = H1 +M3
  78. 780  IF DW$(H1 -1) < = DW$(L1 -1)  THEN 830
  79. 790 T$ = DW$(H1 -1):DW$(H1 -1) = DW$(L1 -1):DW$(L1 -1) = T$
  80. 800 T$ = DF$(H1 -1):DF$(H1 -1) = DF$(L1 -1):DF$(L1 -1) = T$
  81. 810 T$ = NT$(H1 -1):NT$(H1 -1) = NT$(L1 -1):NT$(L1 -1) = T$
  82. 820 H1 = H1 -M3: IF H1 > = 1  THEN 770
  83. 830 J1 = J1 +1: IF J1 >K1  THEN 740
  84. 840  GOTO 760
  85. 850  HOME : NORMAL : VTAB 12: HTAB 8: PRINT "ORDINAMENTO ALFABETICO TERMINATO": GOSUB 2660: RETURN 
  86. 860  REM  RICERCA PAROLA O FRASE 
  87. 870 TL = 3:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690
  88. 880  GOSUB 2740: IF Z = 20  THEN  RETURN 
  89. 890 A$ =  STR$(SL(TL))
  90. 900  HOME :FD = 0
  91. 910  PRINT : PRINT "INTRODUCI PAROLA/FRASE DA CERCARE": INPUT "-->";SEARCH$:SEARCH$ = " " +SEARCH$ +" "
  92. 920 L =  LEN(SEARCH$): HOME 
  93. 930  HTAB 1: VTAB 4: PRINT "RICERCA PER LA VOCE N."N" NEL DIZIONARIO"
  94. 940  ON  VAL(A$) GOSUB 960,1000,1080
  95. 950  VTAB 23: HTAB 1: PRINT "TROVATO N.= "FD;: HTAB 20: PRINT "RICERCA TERMINATA": GOSUB 2660: GOTO 870
  96. 960  REM  RICERCA PAROLA DIZIONARIO
  97. 970  FOR N = 1 TO NW: VTAB 1: HTAB 33: PRINT N"  ";: IF SEARCH$ = DW$(N)  THEN  GOSUB 1170: IF XX = 27  THEN N = NW
  98. 980  NEXT : RETURN 
  99. 990  REM  RICERCA PAROLA NEL SIGNIFICATO
  100. 1000  VTAB 1: HTAB 13: PRINT "(VELOCE)"
  101. 1010  FOR N = 1 TO NW: VTAB 1: HTAB 33: PRINT N"  ";: IF SEARCH$ = DF$(N)  THEN  GOSUB 1170: IF XX = 27  THEN N = NW
  102. 1020  NEXT : IF FD >0  THEN  RETURN 
  103. 1030  VTAB 1: HTAB 13: PRINT "(LENTA) "
  104. 1040  FOR N = 1 TO NW: VTAB 1: HTAB 33: PRINT N"  ";: FOR N1 = 1 TO  LEN(DF$(N))
  105. 1050  IF SEARCH$ =  MID$ (DF$(N),N1,L)  THEN  GOSUB 1170: IF XX = 27  THEN N1 =  LEN(DF$(N)):N = NW
  106. 1060  NEXT : NEXT : RETURN 
  107. 1070  REM  RICERCA PAROLA NELLA NOTA
  108. 1080  VTAB 1: HTAB 13: PRINT "(VELOCE)"
  109. 1090  FOR N = 1 TO NW: VTAB 1: HTAB 33: PRINT N"  ";: IF SEARCH$ = NT$(N)  THEN  GOSUB 1170: IF XX = 27  THEN N = NW
  110. 1100  NEXT : IF FD >0  THEN  RETURN 
  111. 1110  VTAB 1: HTAB 13: PRINT "(LENTA) "
  112. 1120  FOR N = 1 TO NW: VTAB 1: HTAB 33: PRINT N"  ";
  113. 1130  FOR N1 = 1 TO  LEN(NT$(N))
  114. 1140  IF N1 +L > LEN(NT$(N))  THEN N = NW
  115. 1150  IF SEARCH$ =  MID$ (NT$(N),N1,L)  THEN  GOSUB 1170: IF XX = 27  THEN N1 =  LEN(NT$(N)):N = NW
  116. 1160  NEXT : NEXT : RETURN 
  117. 1170 FD = FD +1: PRINT : PRINT : PRINT SEARCH$: PRINT "TROVATA NELLA VOCE N."N" NEL DIZIONARIO ": PRINT : PRINT DW$(N)"-"DF$(N): PRINT "NOTE-"NT$(N)
  118. 1180  PRINT : PRINT "<ESC> FINE, <RETURN> CONTINUA: ": GOSUB 2620: IF XX = 27  THEN  RETURN 
  119. 1190  IF XX = 13  THEN  RETURN 
  120. 1200  REM  
  121. 1210  REM  STAMPA DIZIONARIO
  122. 1220 TL = 4:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690
  123. 1230  GOSUB 2740: IF Z = 20  THEN  RETURN 
  124. 1240 A$ =  STR$(SL(TL))
  125. 1250  HOME 
  126. 1260  IF A$ = "1"  THEN BEGIN$ = " A ":FINISH$ = " ZZZZ"
  127. 1270  IF A$ = "2"  THEN  GOSUB 1360
  128. 1280  VTAB 10: HTAB 1: CALL  -958: HTAB 1: INPUT " (E) ESPLORAZIONE O (C) CONTROLLO: ";CTRL$: IF CTRL$ < >"E"  AND CTRL$ < >"C"  THEN 1280
  129. 1290  VTAB 13: HTAB 1: CALL  -958: HTAB 1: INPUT "USCITA SU (P) STAMPANTE O (S) SCHERMO? ";SP$: IF SP$ < >"P"  AND SP$ < >"S" GOTO 1290
  130. 1300  HOME : FOR N = 1 TO NW: IF SP$ = "P"  THEN  PRINT D$"PR#1": IF N = 1  THEN  PRINT DW$"/"DF$" STAMPA DIZIONARIO": PRINT 
  131. 1310 FD = 0: IF (BEGIN$ =  <DW$(N))  AND (FINISH$ > = DW$(N))  THEN FD = 1: PRINT DW$(N)"-->"DF$(N);: IF NT$(N) < >""  AND NT$(N) < >" "  AND NT$(N) < >"  "  THEN  PRINT "("NT$(N)")";: REM  0,1,2 SPAZI FRA VIRGOLETTE
  132. 1320  IF FD  AND CTRL$ = "C"  AND N < >NW  THEN  PRINT D$: PRINT D$"PR#0": PRINT "<ESC> MENU, <RETURN> PER CONTINUARE": GOSUB 2620: IF XX = 27  THEN  RETURN 
  133. 1330  IF FINISH$ > = DW$(N)  THEN  PRINT : NEXT N
  134. 1340  PRINT D$"PR#0": PRINT : PRINT "STAMPA DIZIONARIO COMPLETA": GOSUB 2660: GOTO 1220
  135. 1350  GOTO 1220
  136. 1360  PRINT : INPUT "INRODUCI LETTERA INIZIALE (A-Z): ";BEGIN$:BEGIN$ = " " +BEGIN$
  137. 1370  PRINT : INPUT "INTRODUCI LETTERA FINALE (B-ZZZZ): ";FINISH$:FINISH$ = " " +FINISH$
  138. 1380  IF BEGIN$ >FINISH$  THEN 1360
  139. 1390  RETURN 
  140. 1400  REM    ROUTINE  DI TRADUZIONE 
  141. 1410 TL = 5:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690
  142. 1420  GOSUB 2740: IF Z = 20  THEN  RETURN 
  143. 1430 A$ =  STR$(SL(TL))
  144. 1440  HOME 
  145. 1450  VTAB 20: PRINT "LA TUA FRASE SARA' TRADOTTA PAROLA PER": PRINT "PAROLA SE LE PAROLE SONO SEPARATE": PRINT "DA SPAZI MA SARA' TRADOTTA COME FRASE": PRINT "SE SONO SEPARATE DA ASTERISCHI (*)."
  146. 1460  VTAB 12: HTAB 1: PRINT "PAROLA/FRASE DA TRADURRE (MAX 10 PAROLE)": INPUT "-->";T$:T$ = T$ +" ":C5 = 0:C6 = 1
  147. 1470  PRINT : INVERSE : PRINT "STO ANALIZZANDO": NORMAL 
  148. 1480  REM  SE LE PAROLE SONO DIVISE DA SPAZI/DIVIDE IN PAROLE/SE LE PAROLE SONO DIVISE DA ASTERISCHI, DIVIDE IN FRASI
  149. 1490 L =  LEN(T$): FOR N = 1 TO L
  150. 1500  ONERR  GOTO 1560
  151. 1510  IF  MID$ (T$,N,1) = " "  THEN C5 = C5 +1:T$(C5) =  MID$ (T$,C6,N -C6):C6 = N +1
  152. 1520 A =  ASC( MID$ (T$,N,1)): IF A >90  OR A <65  AND A < >42  AND A < >32  THEN  VTAB 17: HTAB 1: INPUT "SOLO CARATTERI MAIUSCOLI PER FAVORE: ";A$: GOTO 1410
  153. 1530 A =  LEN(T$(C5)): IF A >1  THEN  FOR N1 = 1 TO A: IF  MID$ (T$(C5),N1,1) = "*"  THEN T$(C5) =  LEFT$(T$(C5),N1 -1) +" " + RIGHT$(T$(C5),A -N1)
  154. 1540  IF A >1  THEN  NEXT N1
  155. 1550  NEXT N
  156. 1560  IF C5 >10  THEN  PRINT : INPUT "TROPPE PAROLE: ";A$: GOTO 1410
  157. 1570  FOR N = 1 TO C5:T$(N) = " " +T$(N) +" ": NEXT N
  158. 1580  POKE 216,0: ONERR  GOTO 2450
  159. 1590  ON  VAL(A$) GOSUB 1620,1710
  160. 1600  GOTO 1410
  161. 1610  REM  TRADUCE LE PAROLE DAL DIZIONARIO NELLA LINGUA SELEZIONATA
  162. 1620  HOME : PRINT : INVERSE : PRINT "STO TRADUCENDO": NORMAL : PRINT : GOSUB 1900
  163. 1630  FOR N = 1 TO C5:TRANS = 0: PRINT T$(N);
  164. 1640  FOR N1 = 1 TO NW: HTAB 20: PRINT "-->"N1;
  165. 1650  IF T$(N) = DW$(N1)  THEN  HTAB 20: PRINT "-->"DF$(N1)" ":TRANS = 1
  166. 1660  NEXT N1: IF TRANS = 0  THEN  HTAB 20: PRINT "-->PAROLA SCONOSCIUTA": PRINT 
  167. 1670  IF TRANS < >0  THEN  HTAB 20: PRINT "         ": REM     10 SPAZI
  168. 1680  NEXT N
  169. 1690  PRINT : PRINT "TRADUZIONE TERMINATA": GOSUB 2660: RETURN 
  170. 1700  REM  TRADUCE LE PAROLE DALLA LINGUA SELEZIONATA AL DIZIONARIO
  171. 1710  POKE 216,0: HOME : PRINT : INVERSE : PRINT "STO TRADUCENDO": NORMAL : PRINT : GOSUB 1900
  172. 1720  ONERR  GOTO 2450
  173. 1730  FOR N3 = 1 TO C5:YES = 0:FIRST = 0:FD = 0:SEARCH$ = T$(N3):L =  LEN(SEARCH$)
  174. 1740  REM   ROUTINE TRADUZIONE LENTA
  175. 1750  PRINT T$(N3);: GOSUB 1870: IF YES  THEN  GOTO 1830
  176. 1760  FOR N = 1 TO NW: HTAB 20: PRINT "-->"N"  ";
  177. 1770  FOR N1 = 1 TO  LEN(DF$(N))
  178. 1780  IF N1 +L > LEN(DF$(N)) +1  THEN 1810
  179. 1790  IF SEARCH$ =  MID$ (DF$(N),N1,L)  THEN  HTAB 20: PRINT "-->"DW$(N):YES = 1: GOTO 1810
  180. 1800  NEXT N1
  181. 1810  NEXT N
  182. 1820  IF YES = 0  THEN  HTAB 20: PRINT "-->PAROLA SCONOSCIUTA": PRINT 
  183. 1830  IF YES  THEN  HTAB 20: PRINT "            ": REM  12 SPAZI
  184. 1840  NEXT N3
  185. 1850  PRINT : PRINT "TRADUZIONE TERMINATA": GOSUB 2660: RETURN 
  186. 1860  REM   ROUTINE TRADUZIONE VELOCE
  187. 1870  FOR N4 = 1 TO NW
  188. 1880  HTAB 20: PRINT "-->"N4"  ";: IF SEARCH$ = DF$(N4)  THEN  HTAB 20: PRINT "-->"DW$(N4):YES = 1
  189. 1890  NEXT N4: RETURN 
  190. 1900  REM  OUTPUT TRADUZIONE
  191. 1910  HTAB 1: VTAB 5: PRINT "PAROLA              TRADUZIONI POSSIBILI":TRANS = 1: REM   13 SPAZI
  192. 1920  RETURN 
  193. 1930 TL = 6:MX = MITEMS(TL):PX = 31:SL(TL) = SL(TL) +(SL(TL) = 0): GOSUB 2690
  194. 1940  GOSUB 2740: IF Z = 20  THEN  RETURN 
  195. 1950 A = SL(TL)
  196. 1960  HOME : IF A = 3  THEN  PRINT : PRINT D$ LEFT$("CATALOG",7 -4 *( PEEK(48896) = 76)): GOSUB 2660: GOTO 1930
  197. 1970  IF A = 2  AND NW = 0  THEN  PRINT : INPUT "NON POSSO SALVARE UN FILE VUOTO: ";A$: GOTO 1930
  198. 1980  IF A = 1  AND NW >0  THEN  PRINT : PRINT "VUOI CANCELLARE IL DIZIONARIO  "DW$"/"DF$"?";: INPUT "(S/N): ";A$: IF A$ < >"S"  THEN  GOTO 1940
  199. 1990  PRINT : PRINT "INTRODUCI NOME DIZIONARIO-(C) CATALOG": INPUT "-->";B$: IF  RIGHT$(B$,4) = ".DIZ"  THEN B$ =  LEFT$(B$, LEN(B$) -4)
  200. 2000  IF B$ = ""  THEN  RETURN 
  201. 2010  IF B$ = "C"  THEN  PRINT D$ LEFT$("CATALOG",7 -4 *( PEEK(48896) = 76)): GOTO 1990
  202. 2020 B$ = B$ +".DIZ"
  203. 2030  ON A GOTO 2040,2060
  204. 2040  PRINT D$"VERIFY"B$: PRINT : PRINT "STO CARICANDO": PRINT D$"OPEN"B$: PRINT D$"READ"B$: INPUT DW$: INPUT DF$: INPUT NW: FOR N = 1 TO NW: INPUT DW$(N): INPUT DF$(N): INPUT NT$(N)
  205. 2050 DW$(N) = " " +DW$(N):DF$(N) = " " +DF$(N):NT$(N) = " " +NT$(N): NEXT : PRINT D$"CLOSE": PRINT : GOSUB 2800: RETURN 
  206. 2060  PRINT D$"OPEN"B$: PRINT D$"CLOSE"B$: PRINT D$"DELETE"B$
  207. 2070  PRINT D$"OPEN"B$: PRINT D$"WRITE"B$: PRINT DW$: PRINT DF$: PRINT NW: FOR N = 1 TO NW: PRINT DW$(N): PRINT DF$(N): PRINT NT$(N): NEXT : PRINT D$"CLOSE": PRINT : INPUT "DIZIONARIO SALVATO SUL DISCHETTO: ";A$: RETURN 
  208. 2080  REM    CONTROLLA PER VEDERE IL TIPO DI DIZIONARIO
  209. 2090  IF DF$ < >""  AND DW$ < >""  THEN  RETURN 
  210. 2100  HOME : VTAB 8: HTAB 1: PRINT "<RETURN> PER INIZIARE NUOVO DIZIONARIO, ": PRINT "<ESC> PER IL MENU PRINCIPALE": GOSUB 2620: IF XX = 27  THEN  RETURN 
  211. 2110  PRINT : VTAB 11: HTAB 1: INPUT "LINGUA DELLE DEFINIZIONI: ";DF$: IF DF$ = "" GOTO 2100
  212. 2120  VTAB 14: HTAB 1: PRINT "LINGUA DELLE PAROLE DEL DIZIONARIO: "
  213. 2125  INPUT "";DW$: IF DW$ = ""  THEN 2125
  214. 2130  GOSUB 2800: REM  ADATTA LE VOCI DEL MENU
  215. 2140  HOME : PRINT : PRINT : RETURN 
  216. 2150  REM   COMPLETA CON SPAZI
  217. 2160  REM    PULISCE MEMORIA
  218. 2170  HOME : VTAB 12: PRINT : INPUT "SEI SICURO? (S/N): ";A$
  219. 2180  RETURN 
  220. 2190  REM   EDITOR INPUT LINEA
  221. 2200 L = 2
  222. 2210 E = 1
  223. 2220  VTAB T +2: HTAB L: POKE  -16388,0: GET Z1$:X =  PEEK( -16384): VTAB T +2
  224. 2230  IF X <32  THEN  ON X GOTO 2220,2200,2220,2350,2220,2410,2220,2360,2400,2220,2220,2220,2300,2440,2220,2220,2430,2220,2220,2220,2380,2220,2220,2220,2220,2420: GOTO 2220
  225. 2240  IF E = 1  THEN M$ =  LEFT$(M$,L -1) +Z1$ + MID$ (M$,L +1): HTAB L: PRINT Z1$;:L = L +1: GOTO 2220
  226. 2250  IF E = 2  THEN M$ =  LEFT$(M$,L -1) +Z1$ + MID$ (M$,L): HTAB L: PRINT  MID$ (M$,L);:L = L +1: GOTO 2220
  227. 2260 F = W:W = X: IF F < >X  AND F  THEN E = 1: GOTO 2240
  228. 2270  FOR J3 = L +1 TO  LEN(M$): IF Z1$ < > MID$ (M$,J3,1)  THEN  NEXT : GOTO 2220
  229. 2280  IF E  THEN L = J3: GOTO 2220
  230. 2290 M$ =  LEFT$(M$,L -1) + MID$ (M$,J): POKE 35,20: HTAB L: CALL  -958: PRINT  MID$ (M$,L): POKE 35,24: GOTO 2220
  231. 2300 R$ =  MID$ (M$,2)
  232. 2310 C5 = 1: IF  LEN(R$) >1  THEN  FOR C5 =  LEN(R$) TO 1  STEP  -1: IF  MID$ (R$,C5,1) = " "  THEN  NEXT 
  233. 2320 R$ =  MID$ (R$,1,C5): IF  LEN(R$) < >0  THEN R$ = " " +R$ +" "
  234. 2330  RETURN 
  235. 2340  REM   ELIMINA UN CARATTERE
  236. 2350 M$ =  LEFT$(M$,L -1) + MID$ (M$,L +1): HTAB L: CALL  -868: PRINT  MID$ (M$,L);: GOTO 2210
  237. 2360  IF L = 2  THEN 2210
  238. 2370 L = L -1: GOTO 2210
  239. 2380  IF L <1 + LEN(M$)  THEN L = L +1
  240. 2390  GOTO 2210
  241. 2400 E = 2: GOTO 2220
  242. 2410 E = 3:W = 0: GOTO 2220
  243. 2420 E = 0:W = 0: GOTO 2220
  244. 2430 M$ =  LEFT$(M$,L -1): HTAB L: CALL  -868: GOTO 2210
  245. 2440 L =  LEN(M$): GOTO 2210
  246. 2450  REM    ROUTINE GESTIONE ERRORI
  247. 2460  PRINT : PRINT D$"CLOSE": PRINT D$"PR#0": PRINT  CHR$(7):X =  PEEK(222)
  248. 2470  IF X = 6  OR X = 5  THEN  PRINT "FILE NOT FOUND";:X = 257
  249. 2480  IF X = 8  OR X = 9  OR X = 10  THEN  PRINT "I/O ERROR";:X = 257
  250. 2490  IF X = 254  OR X = 255  OR X = 53  OR X = 176  THEN  PRINT "BAD INPUT ERROR";:X = 257
  251. 2500  IF X < >257  THEN  PRINT "ERRORE NUMERO " PEEK(222)" A LINEA " PEEK(218) + PEEK(219) *256: PRINT "VEDERE MANUALE APPLESOFT";
  252. 2510  GOSUB 2660: GOTO 170
  253. 2520  HOME : VTAB 12: INPUT "SEI SICURO? (S/N): ";A$: IF A$ < >"S"  THEN  RETURN 
  254. 2530  IF NW = 0  THEN 2560
  255. 2540  PRINT : IF NW < >0  THEN  PRINT : PRINT "VUOI SALVARE IL DIZIONARIO SUL DISCO": INPUT "PRIMA DI SMETTERE? (S/N): ";A$: IF A$ < >"S"  THEN 2560
  256. 2550 A = 2: GOSUB 1990
  257. 2560  HOME : PRINT : PRINT "FATTO...": PRINT "(R) PER RICOMINCIARE": PRINT : PRINT "(M) MENU APPLEDISK"
  258. 2563  VTAB 6: HTAB 1: INPUT "";H$: IF H$ < >"R"  AND H$ < >"M"  THEN 2563
  259. 2565  IF H$ = "R"  THEN  GOTO 110
  260. 2568  IF H$ = "M"  THEN  PRINT D$"RUN HELLO2"
  261. 2570  END 
  262. 2580 FM = ( PEEK(111) +256 * PEEK(112)) -( PEEK(109) +256 * PEEK(110))
  263. 2585  IF FM <200  THEN  ON ( PEEK(48896) = 76) +1 GOSUB 2600,2610: IF FM <100  THEN  HOME : VTAB 12: PRINT "STO ESAURENDO LA MEMORIA": PRINT : PRINT "SALVA IL CONTENUTO DEL DIZIONARIO": GOSUB 2660
  264. 2590  RETURN 
  265. 2600 FM =  FRE(0): RETURN 
  266. 2610  PRINT D$"FRE":FM =  PEEK(111) +256 * PEEK(112) - PEEK(109) -256 * PEEK(110): RETURN 
  267. 2620  POKE  -16368,0: WAIT  -16384,128:XX =  PEEK( -16384) -128: IF XX < >27  AND XX < >13  THEN  PRINT  CHR$(7);: GOTO 2620
  268. 2630  POKE  -16368,0: RETURN 
  269. 2640  POKE  -16368,0: WAIT  -16384,128:XX =  PEEK( -16384) -128: IF XX < >27  AND XX < >13  AND XX < >67  THEN  PRINT  CHR$(7);: GOTO 2640
  270. 2650  POKE  -16368,0: RETURN 
  271. 2660  VTAB 24: HTAB 8: PRINT "PREMERE <RETURN> PER CONTINUARE";: GET Z$: PRINT : RETURN 
  272. 2670  RESTORE : READ NMENUS: DIM MENU$(NMENUS,9): FOR I = 1 TO NMENUS: READ MITEMS(I): FOR J = 0 TO MITEMS(I): READ MENU$(I,J): NEXT J,I
  273. 2680  RETURN 
  274. 2690  HOME : IF TL >1  THEN  PRINT "<";: INVERSE : PRINT "ESC";: NORMAL : PRINT "> PER IL MENU PRINCIPALE"
  275. 2700 TL$ = MENU$(TL,0): VTAB 3: HTAB  INT((40 - LEN(TL$))/2)
  276. 2710  INVERSE : PRINT TL$: NORMAL 
  277. 2720  FOR I = 1 TO MITEMS(TL): VTAB 3 +2 *I: HTAB 8: PRINT I". "MENU$(TL,I): NEXT 
  278. 2730  VTAB 23: HTAB 1: INVERSE : PRINT " USA LE FRECCE O SCEGLI UN NUMERO ": HTAB 10: PRINT " E PREMI <RETURN>:";: NORMAL : RETURN 
  279. 2740 SL = SL(TL)
  280. 2750 N = SL:OS = SL: GOSUB 2780:Z = 0: VTAB 24: HTAB PX: CALL  -868: POKE  -16368,0
  281. 2760  VTAB 24: HTAB PX: PRINT SL;: GET Z$: IF Z$ > = "1"  AND Z$ < =  STR$(MX)  THEN SL =  VAL(Z$):N = OS: GOSUB 2780: GOTO 2750
  282. 2770 Z = (Z$ =  CHR$(21)  OR Z$ =  CHR$(10)) -(Z$ =  CHR$(8)  OR Z$ =  CHR$(11)) +10 *(Z$ =  CHR$(13)) +20 *(Z$ =  CHR$(27)): ON   NOT Z GOTO 2760:SL = SL +Z *(Z <10):SL = SL -MX *(SL >MX) +MX *(SL <1):N = OS: GOSUB 2780: ON Z <10 GOTO 2750:SL(TL) = SL: RETURN 
  283. 2780  VTAB 3 +2 *N: HTAB SX: PRINT X$(SL = OS);: RETURN 
  284. 2790  REM   ADATTA I MENU AL DIZIONARIO CORRENTE
  285. 2800 MENU$(3,1) = "VOCABOLO    " +DW$
  286. 2810 MENU$(3,2) = "SIGNIFICATO " +DF$
  287. 2820 MENU$(3,3) = "NOTA        " +DF$
  288. 2830 MENU$(5,1) = DW$ +"-->" +DF$
  289. 2840 MENU$(5,2) = DF$ +"-->" +DW$
  290. 2850  RETURN 
  291. 2860  DATA    6,9,MENU PRINCIPALE,INTRODURRE NUOVA PAROLA/FRASE,CAMBIARE PAROLA/FRASE,ORDINE ALFABETICO DIZIONARIO,CERCARE PAROLA/FRASE
  292. 2865  DATA     VISUALIZZARE/STAMPARE DIZ.,TRADURRE PAROLA/PROPOSIZIONE,OPERAZIONI SU DISCO,TOGLIERE DIZ. DALLA MEMORIA,FINE
  293. 2870  DATA   2,CAMBIARE PAROLA/FRASE,CAMBIARE PAROLA,CAMBIARE SIGNIFICATO
  294. 2880  DATA   3,CERCARE PAROLA/FRASE,CERCARE PAROLA DIZIONARIO,CERCARE PAROLA SIGNIFICATO,CERCARE SIGNIFICATO NOTA
  295. 2890  DATA   2,VISUALIZZARE/STAMPARE DIZIONARIO,INTERO DIZIONARIO,PARTE DEL DIZIONARIO
  296. 2900  DATA   2,TRADURRE PAROLA/PROPOSIZIONE,DIZIONARIO -> SIGNIFICATO,SIGNIFICATO -> DIZIONARIO
  297. 2910  DATA   3,OPERAZIONI SU DISCO,CARICARE DIZIONARIO,SALVARE DIZIONARIO,CATALOG