Amiga ISO Collection/AmigaUtilCD2.iso/WordProcessors/DCN-FW51.DMS/in.adf/HDInstall

Text File | 1996-08-05 | 21.6 KB | 924 lines

;;
;;  $Final Writer 5 Installation Script German Version $
;;  $Date: 1996/08/05 10:36:56 $
;;  $Revision: 1.3 $
;;

(set is_update 0)
(set @user-level 1)    ; force to use average mode
(complete 0)

; Installation Disk Names
;  (Actual volume name)
(set #install_disk_1 "Disk 1")
(set #install_disk_2 "Disk 2")
(set #install_disk_3 "Disk 3")
(set #install_disk_4 "Disk 4")
(set #install_disk_5 "Disk 5")
(set #install_disk_6 "Disk 6")
(set #install_disk_7 "Disk 7")

; File/drawer names to change with different versions.
;
(set #fw_drawer        "FinalWriter_D")
(set #old_hyph_file    "FWFiles/grm.hyp")
(set #ud_file            "userdict.grm")
(set #save_ud_file    "userdict.grm.save")

; --------------------------------------------------------------
; TEXT TRANSLATION BEGINS HERE - Translate everything in quotes.
;
(set #name_disk_1 "Diskette 1")
(set #name_disk_2 "Diskette 2")
(set #name_disk_3 "Diskette 3")
(set #name_disk_4 "Diskette 4")
(set #name_disk_5 "Diskette 5")
(set #name_disk_6 "Diskette 6")
(set #name_disk_7 "Diskette 7")

(set #which_drawer_prompt
(cat    "In welcher Disk/Schublade soll Final Writer erstellt werden?"
))

(set #which_drawer_help
(cat    "Das Installationsprogramm erstellt die Schublade \""
        #fw_drawer
        "\" "
        "in diesem Verzeichnis. Alle Dateien von \"Final Writer\" "
        "werden in dieses Verzeichnis gestellt.\n\n"
        @askdir-help
))

(set #min_or_comp_prompt
(cat    "Wünschen Sie eine \"Vollständige\" oder \"minimale\" Installation "
        "von Final Writer? Die vollständige Installation erfordert ca. 9,5 MByte "
        "freien Speicherplatz auf der Disk, die Minimal- Installation ca. 2,5 MByte."
))

(set #min_or_comp_help
(cat    "Bei Auswahl von \"Vollständig\" werden alle Dateien des Diskettensatzes "
        "von Final Writer installiert. Dafür sind ca. 9,5 MByte freier Speicherplatz "
        "auf der Disk erforderlich. Bei Auswahl von \"Minimal\" werden die ARexx-"
        "Makros, EPS Clip Art, Vorlagen und zusätzliche Schriftarten nicht installiert. "
        "Die Minimalinstallation erfordert ca. 2,5 MByte freien Speicherplatz auf der Disk."
))

(set #option_complete "Vollständig")
(set #option_minimal "Minimal")

(set #disk_space_prompt
(cat    "Auf dem Laufwerk ist möglicherweise nicht genügend Platz für die Installation "
        "von \"Final Writer\".  Dennoch fortsetzen?"
))

(set #disk_space_help
(cat    "Final Writer benötigt für die vollständige Installation ca. 9,5 MByte freien "
        "Speicherplatz auf der Disk, für die Minimalinstallation ca. 2,5 MByte. Wenn "
        "Final Writer auf dieser Partition bereits installiert ist, können Sie die "
        "Installation fortsetzen. Andernfalls drücken Sie ABBRUCH oder NEIN und "
        "schaffen danach entweder Platz auf dieser Partition oder wählen eine andere "
        "Partition für die Installation aus."
))

(set #disk_space_abort
(cat    "Installation von Final Writer abgebrochen. Zu wenig Speicherplatz auf dem "
        "Datenträger \""
))

(set #update_options_prompt
(cat    "Welche Komponenten sollen aktualisiert werden?"
))

(set #update_program        "Final Writer - Programm")
(set #update_macros        "ARexx-Makros")
(set #update_sysfiles    "Systemdatendateien")
(set #update_syslibs        "Systembibliotheken")
(set #update_sysfonts    "Systemschriftarten")
(set #update_spellhyph    "Rechtschreibprüfung & Silbentrennung")
(set #update_thes            "Thesaurus")
(set #update_clipart        "EPS Clip Art")
(set #update_xfonts        "Zusätzliche Schriftarten")
(set #update_templates    "Vorlagen")

(set #ask_disk_prompt
(cat    "Bitte \"%s\" einlegen."
))

(set #ask_disk1_help
(cat    "\"%s\" enthält das Programm Final Writer, Makros, Daten-Dateien, und Vorlagen "
        "die installiert werden.\n\n"
        @askdisk-help
))

(set #ask_disk2_help
(cat    "\"%s\" enthält die auf dem System zu installierenden Final Writer Systembibliotheken, Systemschriftarten, "
        "Rechtschreib- und Silbentrennungshilfen.\n\n"
        @askdisk-help
))

(set #ask_disk3_help
(cat    "\"%s\" enthält die auf dem System zu installierenden Thesaurusdateien von Final Writer "
        "und die EPS Clip Art.\n\n"
        @askdisk-help
))

(set #ask_disk4_help
(cat    "\"%s\" enthält die auf dem System zu installierende EPS Clip Art."
))

(set #ask_disk5_help
(cat    "\"%s\" enthält die auf dem System zu installierende EPS Clip Art sowie zusätzliche "
        "dekorative und Serif-Schriftarten."
))

(set #ask_disk6_help
(cat    "\"%s\" enthält auf dem System zu installierende, zusätzliche Serif-Schriftarten."
))

(set #ask_disk7_help
(cat    "\"%s\" enthält auf dem System zu installierende, zusätzliche serifenlose Schriftarten."
))

(set #install_program        "Programm Final Writer wird von \"%s\" installiert.")
(set #install_program_icon    "Programm und Piktogramm Final Writer werden von \"%s\" installiert.")
(set #install_macros            "ARexx-Makros werden von \"%s\" installiert.")
(set #install_datafiles        "Datendateien werden von \"%s\" installiert.")
(set #install_templates        "Vorlagen werden von \"%s\" installiert.")
(set #install_libs            "Bibliotheken werden von \"%s\" installiert.")
(set #install_sysfonts        "Systemschriftarten werden von \"%s\" installiert.")
(set #install_spell            "Dateien für Rechtschreibprüfung & Silbentrennung werden von \"%s\" installiert.")
(set #install_thes            "Thesaurusdateien werden von \"%s\" installiert.")
(set #install_clipart        "EPS Clip Art wird von \"%s\" installiert.")
(set #install_deco            "Dekorative Schriftarten werden von \"%s\" installiert.")
(set #install_serif            "Serif-Schriftarten werden von \"%s\" installiert.")
(set #install_sans            "Serifenlose Schriftarten werden von \"%s\" installiert.")

(set #install_program_err        "Fehler bei Installation des Programms FinalWriter.")
(set #install_macros_err        "Fehler bei Installation der ARexx-Makros.")
(set #install_datafiles_err    "Fehler bei Installation der Datendateien.")
(set #install_templates_err    "Fehler bei Installation der Vorlagen.")
(set #install_libs_err            "Fehler bei Installation der Bibliotheken.")
(set #install_sysfonts_err        "Fehler bei Installation der Systemschriftarten.")
(set #install_spell_err            "Fehler bei Installation der Dateien für die Rechtschreibprüfung.")
(set #install_thes_err            "Fehler bei Installation der Thesaurusdateien.")
(set #install_clipart_err        "Fehler bei Installation der EPS Clip Art.")
(set #install_deco_err            "Fehler bei Installation der Dekorativen Schriftarten.")
(set #install_serif_err            "Fehler bei Installation der Serif-Schriftarten.")
(set #install_sans_err            "Fehler bei Installation der Serifenlosen Schriftarten.")
;
; TEXT TRANSLATION ENDS HERE - nothing below needs translation.
; -------------------------------------------------------------

(set FW_dest
    (askdir
        (prompt    #which_drawer_prompt)
        (help        #which_drawer_help)
        (default @default-dest)
    )
)

; Check if this is an update
; the FWLibs directory is a tell-tale sign
; that FW is already installed here
(if (exists (tackon FW_dest "FWLibs"))
    (set is_update 1)
    (    (if (exists (tackon FW_dest #fw_drawer))
            (set is_update 1)
            (makedir (tackon FW_dest #fw_drawer) (infos))
        )
        (set FW_dest (tackon FW_dest #fw_drawer))
    )
)

(set @default-dest FW_dest)
(set disk_space (getdiskspace FW_dest))

; If first time install ask if user wants a complete
; or minimal installation. The minimal installation will
; not install ClipArt, Extra Fonts, Macros or Templates.
(if (NOT is_update)
    (
        (set install_all
            (askbool
                (prompt    #min_or_comp_prompt)
                (help        #min_or_comp_help)
                (choices #option_complete #option_minimal)
                (default 1)
            )
        )

        (if install_all
            (set disk_space_needed 9794048)    ; 9.34 Megs
            (set disk_space_needed 2810183)    ; 2.68 Megs
        )
    )
)

(if (AND (< disk_space disk_space_needed) (NOT is_update))
    (
        (set answer1
            (askbool
                (prompt    #disk_space_prompt)
                (help        #disk_space_help)
            )
        )
        (if (NOT answer1)
            (abort #disk_space_abort
                    (getdevice @default-dest)
                    "\"."
            )
        )
    )
)

; Allow updating user to select what they want updated
(if is_update
    (set install_options
        (askoptions
            (prompt    #update_options_prompt)
            (help        @askoptions-help)
            (choices
                #update_program
                #update_macros
                #update_sysfiles
                #update_syslibs
                #update_sysfonts
                #update_spellhyph
                #update_thes
                #update_clipart
                #update_xfonts
                #update_templates
                )
            (default 543)    ; default to Program/Macros/Files/Libs/SysFonts/Templates
        )
    )

    ; First time install
    (if install_all
        (set install_options 1023) ; all options on
        (set install_options 125)    ; Macros/EPS/ExtraFonts/Templates off
    )
)

; Copy the extraction utility over and remember where it is
(copyfiles
    (source "Disk 1:lhex")
    (dest FW_dest)
)
(set DeArcher (tackon FW_dest "lhex"))
(set error 0)

; Installing Files on Disk 1?
(if (IN install_options 0 1 2 9)
    (
        ; Get Disk 1
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_1))
            (help        (#ask_disk1_help #name_disk_1))
            (dest        #install_disk_1)
        )

        ; If installing/updating the program
        (if (IN install_options 0)
            (
                ; Make installer cd into FW_dest when it executes the run statement
                (set @execute-dir FW_dest)

                ; copy the Final Writer program over. If the program
                ; icon doesn't exists copy it over too.
                ( if (exists (tackon FW_dest "FinalWriter.info"))
                    ; This DOES NOT copy the icon, in case the user
                    ; has modified the tool-types
                    (
                        (working (#install_program #name_disk_1))
                        (set error
                            (run
                                ("\"%s\" -f x \"Disk 1:FinalWriter.lha\" FinalWriter >NIL:" DeArcher)
                            )
                        )
                    )
                    ; This DOES copy the icon
                    (
                        (working (#install_program_icon #name_disk_1))
                        (set error
                            (run
                                ("\"%s\" -f x \"Disk 1:FinalWriter.lha\" >NIL:" DeArcher)
                            )
                        )
                    )
                )
            )
        )

        (if error
            (abort #install_program_err)
        )

        (complete 4)

        ; Installing FWMacros
        (if (IN install_options 1)
            (
                ; If FWMacros doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWMacros")))
                    (
                    (makedir (tackon FW_dest "FWMacros") (infos))
                    )
                )

                ; Make installer cd into FWMacros when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWMacros"))

                ; Extract the macro files
                (working (#install_macros #name_disk_1))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 1:FWMacros.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_macros_err)
                )
            )
        )

        (complete 7)

        ; Installing FWFiles
        (if (IN install_options 2)
            (
                ; If FWFiles doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFiles")))
                    (
                    (makedir (tackon FW_dest "FWFiles") (infos))
                    )
                )

                ; Make installer cd into FWFiles when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFiles"))

                ; Extract the files
                (working (#install_datafiles #name_disk_1))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 1:FWFiles.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_datafiles_err)
                )

                ; Previous versions of Final Writer have the hyphenation
                ; file, xxx.hyp, in FWFiles. With Final Writer Release 3
                ; the hyphenation file will reside in FWSpell instead.
                ; So, if we find the hyphenation file in FWFiles, then
                ; move it to FWSpell.
                (if (exists (tackon FW_dest #old_hyph_file))
                    (
                        (if (exists (tackon FW_dest "FWSpell"))
                            (
                                (copyfiles
                                    (source (tackon FW_dest #old_hyph_file))
                                    (dest (tackon FW_dest "FWSpell"))
                                )

                                (delete (tackon FW_dest #old_hyph_file))
                            )
                        )
                    )
                )
            )
        )

        (complete 11)

        ; Installing Templates
        (if (IN install_options 9)
            (
                ; If FWTemplates doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWTemplates")))
                    (
                    (makedir (tackon FW_dest "FWTemplates") (infos))
                    )
                )

                ; Make installer cd into FWTemplates when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWTemplates"))

                ; Extract the files
                (working (#install_templates #name_disk_1))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 1:FWTemplates.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_templates_err)
                )
            )
        )
    )
)

(complete 14)

; Installing files on Disk 2?
(if (IN install_options 3 4 5)
    (
        ; Get Disk 2
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_2))
            (help        (#ask_disk2_help #name_disk_2))
            (dest        #install_disk_2)
        )

        ; Installing FWLibs
        (if (IN install_options 3)
            (
                ; If FWLibs doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWLibs")))
                    (
                    (makedir (tackon FW_dest "FWLibs"))
                    )
                )

                ; Make installer cd into FWLibs when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWLibs"))

                (working (#install_libs #name_disk_2))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 2:FWLibs.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_libs_err)
                )

                (run ("Avail FLUSH"))
            )
        )

        (complete 19)

        ; Installing FWFonts
        (if (IN install_options 4)
            (
                ; If FWFonts doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFonts")))
                    (
                    (makedir (tackon FW_dest "FWFonts") (infos))
                    )
                )

                ; Make installer cd into FWFonts when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFonts"))

                (working (#install_sysfonts #name_disk_2))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 2:FWFonts.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_sysfonts_err)
                )
            )
        )

        (complete 24)

        ; Instaling FWSpell
        (if (IN install_options 5)
            (
                ; If FWSpell doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWSpell")))
                    (
                    (makedir (tackon FW_dest "FWSpell"))
                    )
                )

                ; Preserve the user dictionary.
                (if (exists (tackon FW_dest (cat "FWSpell/" #ud_file)))
                    (
                        (set restore_UD 1)
                        (copyfiles
                            (source (tackon FW_dest (cat "FWSpell/" #ud_file)))
                            (dest (tackon FW_dest "FWSpell"))
                            (newname #save_ud_file)
                        )
                    )
                    (set restore_UD 0)
                )

                ; Make installer cd into FWSpell when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWSpell"))

                (working (#install_spell #name_disk_2))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 2:FWSpell.lha\" >NIL:" DeArcher)
                    )
                )

                (if restore_UD
                    (
                        (copyfiles
                            (source (tackon FW_dest (cat "FWSpell/" #save_ud_file)))
                            (dest (tackon FW_dest "FWSpell"))
                            (newname #ud_file)
                        )
                        (delete (tackon FW_dest (cat "FWSpell/" #save_ud_file)))
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_spell_err)
                )

                ; Previous versions of Final Writer have the hyphenation
                ; file, xxx.hyp, in FWFiles. With Final Writer Release 3
                ; the hyphenation file will reside in FWSpell instead.
                ; So, if we find the hyphenation file in FWFiles, then
                ; move it to FWSpell.
                (if (exists (tackon FW_dest #old_hyph_file))
                    (
                        (if (exists (tackon FW_dest "FWSpell"))
                            (
                                (copyfiles
                                    (source (tackon FW_dest #old_hyph_file))
                                    (dest (tackon FW_dest "FWSpell"))
                                )

                                (delete (tackon FW_dest #old_hyph_file))
                            )
                        )
                    )
                )
            )
        )
    )
)

(complete 29)

(if (IN install_options 6 7)
    (
        ; Get Disk 3
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_3))
            (help        (#ask_disk3_help #name_disk_3))
            (dest        #install_disk_3)
        )

        ; Instaling FWThes
        (if (IN install_options 6)
            (
                ; If FWThes doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWThes")))
                    (
                    (makedir (tackon FW_dest "FWThes"))
                    )
                )

                ; Make installer cd into FWThes when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWThes"))

                (working (#install_thes #name_disk_3))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 3:FWThes.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_thes_err)
                )
            )
        )

        (complete 32)

        ; Installing EPS Clip Art <cc> <fed> <maps> <metro1>
        (if (IN install_options 7)
            (
                ; If FWClipArt doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWClipArt")))
                    (
                    (makedir (tackon FW_dest "FWClipArt"))
                    )
                )

                ; Make installer cd into FWClipArt when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWClipArt"))

                (working (#install_clipart #name_disk_3))

                (set error
                    (run
                        ("\"%s\" -f x \"Disk 3:cc.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_clipart_err)
                )

                (complete 35)

                (set error
                    (run
                        ("\"%s\" -f x \"Disk 3:fed.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_clipart_err)
                )

                (complete 37)

                (set error
                    (run
                        ("\"%s\" -f x \"Disk 3:maps.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_clipart_err)
                )

                (complete 40)

                (set error
                    (run
                        ("\"%s\" -f x \"Disk 3:metro1.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_clipart_err)
                )
            )
        )
    )
)

(complete 43)

(if (IN install_options 7)
    (
        ; Get Disk 4
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_4))
            (help        (#ask_disk4_help #name_disk_4))
            (dest        #install_disk_4)
        )

        ; Installing EPS Clip Art <dms> <totem>

        ; If FWClipArt doesn't exist, create it.
        (if (NOT (exists (tackon FW_dest "FWClipArt")))
            (
            (makedir (tackon FW_dest "FWClipArt"))
            )
        )

        ; Make installer cd into FWClipArt when it executes the run statement
        (set @execute-dir (tackon FW_dest "FWClipArt"))

        (working (#install_clipart #name_disk_4))
        (set error
            (run
                ("\"%s\" -f x \"Disk 4:dms.lha\" >NIL:" DeArcher)
            )
        )

        ; Abort if any errors
        (if error
            (abort #install_clipart_err)
        )

        (complete 50)

        (set error
            (run
                ("\"%s\" -f x \"Disk 4:totem.lha\" >NIL:" DeArcher)
            )
        )

        ; Abort if any errors
        (if error
            (abort #install_clipart_err)
        )
    )
)

(complete 57)

(if (IN install_options 7 8)
    (
        ; Get Disk 5
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_5))
            (help        (#ask_disk5_help #name_disk_5))
            (dest        #install_disk_5)
        )

        ; Instaling EPS Clip Art
        (if (IN install_options 7)
            (
                ; Make installer cd into FWClipArt/Metro when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWClipArt/Metro"))

                (working (#install_clipart #name_disk_5))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 5:Metro2.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_clipart_err)
                )
            )
        )

        (complete 62)

        ; Instaling Decorative fonts
        (if (IN install_options 8)
            (
                ; If FWFonts/SWOLFonts/Deco doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFonts/SWOLFonts/Deco")))
                    (
                    (makedir (tackon FW_dest "FWFonts/SWOLFonts/Deco") (infos))
                    )
                )

                ; Make installer cd into Deco when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFonts/SWOLFonts/Deco"))

                (working (#install_deco #name_disk_5))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 5:Deco.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_deco_err)
                )
            )
        )

        (complete 66)

        ; Instaling Serif1 fonts
        (if (IN install_options 8)
            (
                ; If FWFonts/SWOLFonts/Serif doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFonts/SWOLFonts/Serif")))
                    (
                    (makedir (tackon FW_dest "FWFonts/SWOLFonts/Serif") (infos))
                    )
                )

                ; Make installer cd into Serif when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFonts/SWOLFonts/Serif"))

                (working (#install_serif #name_disk_5))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 5:Serif1.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_serif_err)
                )
            )
        )
    )
)

(complete 71)

(if (IN install_options 8)
    (
        ; Get Disk 6
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_6))
            (help        (#ask_disk6_help #name_disk_6))
            (dest        #install_disk_6)
        )

        ; Instaling Serif2 fonts
        (if (IN install_options 8)
            (
                ; If FWFonts/SWOLFonts/Serif doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFonts/SWOLFonts/Serif")))
                    (
                    (makedir (tackon FW_dest "FWFonts/SWOLFonts/Serif") (infos))
                    )
                )

                ; Make installer cd into Serif when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFonts/SWOLFonts/Serif"))

                (working (#install_serif #name_disk_6))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 6:Serif2.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_serif_err)
                )
            )
        )
    )
)

(complete 86)

(if (IN install_options 8)
    (
        ; Get Disk 7
        (askdisk
            (prompt    (#ask_disk_prompt #name_disk_7))
            (help        (#ask_disk7_help #name_disk_7))
            (dest        #install_disk_7)
        )

        ; Instaling Sans serif fonts
        (if (IN install_options 8)
            (
                ; If FWFonts/SWOLFonts/Sans doesn't exist, create it.
                (if (NOT (exists (tackon FW_dest "FWFonts/SWOLFonts/Sans")))
                    (
                    (makedir (tackon FW_dest "FWFonts/SWOLFonts/Sans") (infos))
                    )
                )

                ; Make installer cd into Sans when it executes the run statement
                (set @execute-dir (tackon FW_dest "FWFonts/SWOLFonts/Sans"))

                (working (#install_sans #name_disk_7))
                (set error
                    (run
                        ("\"%s\" -f x \"Disk 7:Sans.lha\" >NIL:" DeArcher)
                    )
                )

                ; Abort if any errors
                (if error
                    (abort #install_sans_err)
                )
            )
        )
    )
)

; If FWDocs doesn't exist, create it.
(if (NOT (exists (tackon FW_dest "FWDocs")))
    (
    (makedir (tackon FW_dest "FWDocs") (infos))
    )
)

; If FWTextClips doesn't exist, create it.
(if (NOT (exists (tackon FW_dest "FWTextClips")))
    (
    (makedir (tackon FW_dest "FWTextClips") (infos))
    )
)

(delete DeArcher)

(complete 100)

(exit)