home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / SystemPatches / PGTRGB32.LHA / PatchGetRGB32.doc < prev    next >
Encoding:
Text File  |  1994-09-16  |  3.6 KB  |  132 lines
  1. ;
  2. ; PatchGetRGB32
  3. ;
  4. ; A program to fix a bug in graphics.library/GetRGB32():
  5. ; In V39 and V40 (Kickstart 3.0 and 3.1) GetRGB32() contains an
  6. ; unnecessary Check if the AGA Chipset is present and if not, it uses
  7. ; only 4 bits per gun instead of the 8 bits which exist in fact in the
  8. ; ColorTable to compute the 32bit results :-(
  9. ;
  10. ; This bug shows up when a graphics board with more than 4 bits per
  11. ; color gun is installed, a palette with color values that need more than 4
  12. ; bits per gun is build with the palette editor and then screens are
  13. ; switched: The lower bits of the palette are lost. This happened on my
  14. ; A2000 with Picasso gfx board and the palette of MagicWB2.0.
  15. ;
  16. ; PatchGetRGB32 looks if graphics.library V39+ and NO AGA are present and
  17. ; if the first few bytes of the GetRGB32() function are the known code
  18. ; with the unnecessary AGA-Test. If not, it quits with returncode 5,
  19. ; otherwise it uses exec.library/SetFunction() to install a short peace
  20. ; of code that is identical to the original version, but without the
  21. ; AGA-Check, and jumps into the original code after that.
  22. ;
  23. ; WARNING:  There is a (small) possibility that C= develops a V41 Kickstart
  24. ; which needs the AGA check in GetRGB32() and is identical in the first
  25. ; bytes to V39/V40... So: No warranty that this will work with future
  26. ; OS versions (if they ever are developed...).
  27. ;
  28. ; Start of program: "Run >NIL: PatchGetRGB32"
  29. ; in User-Startup or later. If started after the Workbech screen is
  30. ; already visible, use "Palette env:sys/palette.prefs use"
  31. ; to correct an already trimmed palette.
  32. ;
  33. ; End of program: not implemented :-) Program Wait()s forever.
  34. ;
  35. ; Author: Detlef Wuerkner, Roonstr. 12, 35390 Giessen, Germany.
  36. ; EMail:  TetiSoft@apg.lahn.de
  37. ;
  38. ; This is Public Domain.
  39.  
  40. SIGBREAKF_CTRL_C    = 1<<12
  41. _LVOOpenLibrary        = -552
  42. _LVOCloseLibrary    = -414
  43. _LVOForbid        = -132
  44. _LVOPermit        = -138
  45. _LVOSetFunction        = -420
  46. _LVOGetRGB32        = -900
  47. _LVOWait        = -318
  48.  
  49.     CODE
  50.  
  51.     move.l    (4).w,a6        ;SysBase
  52.     lea    GraphicsName(pc),a1
  53.     moveq.l    #39,d0
  54.     jsr    _LVOOpenLibrary(a6)
  55.     tst.l    d0
  56.     beq.s    error            ;GfxLib too old
  57.     move.l    d0,a1
  58.     btst    #3,236(a1)        ;ChipRevBits0 GFXB_AA_LISA
  59.     beq.s    NoAGA
  60.     jsr    _LVOCloseLibrary(a6)    ;AGA -> Patch not needed
  61. error
  62.     moveq.l    #5,d0
  63.     rts
  64. NoAGA
  65.     move.l    d0,a2            ;Save GfxBase
  66.     jsr    _LVOForbid(a6)        ;Ensure that no SetFunction()
  67.                     ;happens while we examine this
  68.     move.l    _LVOGetRGB32+2(a2),a0    ;Pointer to original GetRGB32()
  69.     lea    NewGetRGB32(pc),a1    ;Pointer to new GetRGB32()
  70.     cmp.l    (a0)+,(a1)+
  71.     bne.s    UnknownCode
  72.     cmp.l    (a0)+,(a1)+
  73.     bne.s    UnknownCode
  74.     cmp.w    (a0)+,(a1)+
  75.     bne.s    UnknownCode
  76.     cmp.l    #$082e0003,(a0)+
  77.     bne.s    UnknownCode
  78.     cmp.l    #$00ec6710,(a0)+
  79.     bne.s    UnknownCode
  80.     cmp.l    (a0)+,(a1)+
  81.     bne.s    UnknownCode
  82.     cmp.l    (a0)+,(a1)+
  83.     bne.s    UnknownCode
  84.     cmp.l    (a0)+,(a1)+
  85.     bne.s    UnknownCode
  86.     cmp.l    (a0)+,(a1)+
  87.     beq.s    DoPatch
  88. UnknownCode
  89.     jsr    _LVOPermit(a6)
  90.     move.l    a2,a1            ;GfxBase
  91.     jsr    _LVOCloseLibrary(a6)
  92.     moveq.l    #5,d0
  93.     rts
  94. DoPatch
  95.     move.l    a0,OldGetRGB32_Cont
  96.     lea    NewGetRGB32(pc),a0
  97.     move.l    a0,d0
  98.     move.l    a2,a1
  99.     move.w    #_LVOGetRGB32,a0
  100.     jsr    _LVOSetFunction(a6)
  101.     jsr    _LVOPermit(a6)
  102. WaitForEver
  103.     move.l    #SIGBREAKF_CTRL_C,d0
  104.     jsr    _LVOWait(a6)
  105.     bra.s    WaitForEver
  106.  
  107.  
  108. NewGetRGB32        ;a0 ColorMap d0 firstcolor d1 ncolors a1 table
  109.     movem.l    a2-a3/d2-d7,-(sp)
  110.     move.l    4(a0),a2    ;ColorMap.ColorTable
  111.     move.l    a2,a3
  112. ;    btst    #3,236(a6)    ;ChipRevBits0 GFXB_AA_LISA
  113. ;    beq.s    GotLowColorBits    ;DONT :-)
  114.     tst.b    1(a0)        ;ColorMap.Type == COLORMAP_TYPE_V1_2 ?
  115.     beq.s    GotLowColorBits
  116.     tst.l    12(a0)        ;ColorMap.LowColorBits
  117.     beq.s    GotLowColorBits
  118.     move.l    12(a0),a3    ;LowColorBits instead of ColorTable to a3
  119. GotLowColorBits
  120.     move.l    OldGetRGB32_Cont,-(sp)
  121.     rts            ;Jump to original
  122.  
  123. GraphicsName
  124.     dc.b    "graphics.library",0
  125.  
  126.     BSS
  127.  
  128. OldGetRGB32_Cont
  129.     ds.l    1
  130.  
  131.     END
  132.