Amiga ISO Collection/AmigaUtilCD2.iso/Sound/Player/PowerPlayer.lha/PowerPlayer/Install-PowerPlayer

Text File | 1994-06-19 | 14.9 KB | 608 lines

; ************************************************
; *
; * $VER: Install-PowerPlayer v4.0 (19.09.93)
; *
; * This is the installation-script for PowerPlayer
; *
; * Copyright © 1993 Stephan Fuhrmann
; *
; ************************************************

(welcome "Welcome to the PowerPlayer installation!")

(set OSVersion (/ (getversion) 65536))

(message "PowerPlayer is SHAREWARE !\n\n"
            "This means that you *MUST* pay the shareware-fee\n"
            "after testing\n\nPowerPlayer\n\nor delete it.\n"
            "\nChoose 'Proceed' if you agree!"
)

(copylib
    (prompt "Copying lh.library to LIBS:.")
    (help
        "The lh.library is needed to crunch/decrunch modules with PMC. "
        "PowerPlayer will automatically decrunch these modules if the "
        "lh.library is installed. This library is optional but installing it is recommended, though.\n\n"
        @copylib-help
    )
    (source "libs/lh.Library")
    (dest "LIBS:")
    (confirm)
)

(copylib
    (prompt "Copying powerpacker.library to LIBS:.")
    (help
        "The powerpacker.library is needed to decrunch modules crunched with PowerPacker. "
        "PowerPlayer will automatically decrunch these modules if the "
        "powerpacker.library is installed. PowerPlayer needs this library to work.\n\n"
        @copylib-help
    )
    (source "libs/powerpacker.Library")
    (dest "LIBS:")
    (confirm)
)

(if (>= OSVersion 36)
    (set reqmsg ("You're using OS 2.0 or higher."))
    (set reqmsg ("You're using OS 1.3 or lower."))
)

(if (>= OSVersion 36) (set defchoice 0) (set defchoice 1))

(set reqlib
    (askchoice
        (prompt "Copying ReqTools.Library to LIBS:\n" reqmsg)
        (choices "Install special OS 2.0 version"
                    "Install OS 1.3-compatible version")
        (default defchoice)
        (help
            "If you are running your system with OS 2.0 and higher only, then "
            "there is no need to install the OS 1.3-compatible version of the "
            "ReqTools.Library - the OS 2.0 version is shorter and offers special "
            "features that the OS 1.3-compatible version doesn't have.\n\n"
            "If you're using OS 1.3 or lower, then you must install the OS 1.3-compatible "
            "version of the ReqTools.Library.\n\n"
            @askchoice-help
        )
    )
)

(if (= reqlib 0)    (set rlpath "libs/OS2.0/reqtools.library")
                        (set rlpath "libs/OS1.3/reqtools.library")
)

(copylib
    (prompt "Copying reqtools.library to LIBS:.")
    (help
        "The ReqTools.Library is needed to display the requesters in PowerPlayer. "
        "PowerPlayer needs this library to work.\n\n"
        @copylib-help
    )
    (source rlpath)
    (dest "LIBS:")
    (confirm)
)

(set setemup
    (askbool
        (prompt "Do you want to setup the tooltypes for PowerPlayer ?")
        (help
            "A tooltype is a special kind of preset in an icon. These presets "
            "can be modified by you now, the installer script offers to you this "
            "simple graphical way of installing the tooltypes only once. "
            "\n\n(Otherwise the standard presets are used)\n\n"
            @askbool-help
        )
    )
)

(if setemup
    (
        (
            ;set up the qualifier for the shortcuts

            (set myqualifier "")

            (set qval
                (askoptions
                    (prompt    "Please choose the keyboard qualifiers for\n"
                                "PowerPlayer's hotkeys!")
                    (choices
                        "Left Shift"
                        "Right Shift"
                        "Capslock"
                        "Control"
                        "Left Alt"
                        "Right Alt"
                        "Left Amiga"
                        "Right Amiga"
                    )
                    (default 25)
                    (help
                        "A hotkey is a keyboard shortcut that allows to you to "
                        "give commands to an application from every screen/window.\n\n"
                        @askoptions-help
                    )
                )
            )
            (if (IN qval 0) (set myqualifier ("LSHIFT!")))
            (if (IN qval 1) (set myqualifier ("%s%s" myqualifier "RSHIFT!")))
            (if (IN qval 2) (set myqualifier ("%s%s" myqualifier "CAPSLOCK!")))
            (if (IN qval 3) (set myqualifier ("%s%s" myqualifier "CONTROL!")))
            (if (IN qval 4) (set myqualifier ("%s%s" myqualifier "LALT!")))
            (if (IN qval 5) (set myqualifier ("%s%s" myqualifier "RALT!")))
            (if (IN qval 6) (set myqualifier ("%s%s" myqualifier "LAMIGA!")))
            (if (IN qval 7) (set myqualifier ("%s%s" myqualifier "RAMIGA!")))

            (if (myqualifier)
                (set myqualifier (substr myqualifier 0 (- (strlen myqualifier) 1))))

        )

        (
            ;set up the directory for the file requester
            (set mydirectory
                (askdir
                    (prompt "Select the directory where you store your modules.")
                    (help
                        "Usually users store their modules in one directory. "
                        "If you want the filerequester of PowerPlayer to start in "
                        "the directory where you store your modules, then choose your "
                        "modules directory in the file requester!\n\n"
                        @askfile-help
                    )
                    (default "")
                    (disk)
                )
            )
        )

        (
            ;set up the pattern for the file requester
            (set mypattern
                (askstring
                    (prompt    "Please enter the default matching pattern\n"
                                "for the file-requesters.\n\n"
                                "Recommended: '#?'\n"
                                "Other examples: 'MOD.#?'\n"
                    )
                    (help
                        "A matching pattern is a kind of name mask applied to every "
                        "name in a filerequester. If the name fits to the mask the "
                        "name is displayed, otherwise not. Please consult your "
                        "computers manual for more information on pattern matching.\n\n"
                        @askstring-help
                    )
                    (default "#?")
                )
            )
        )
        (
            ;ask for the LED-mode
            (set filtermode
                (askchoice
                    (prompt "Which mode do you wish for the\nlow-pass audio filter ?\n")
                    (choices "Force filter off (best quality)"
                                "Force filter on (high frequencies filtered)"
                                "Don't change the mode of the filter"
                    )
                    (default 2)
                    (help
                        "The low-pass audio filter is a special device in your AMIGA "
                        "that prevents very high frequencies (=noise frequencies) from "
                        "passing to your audio output. On normal AMIGAs there are "
                        "no noise frequencies produced and the filter prevents the "
                        "high frequencies of the samples from passing - the sound "
                        "starts to be dull.\n\n"
                        @askchoice-help
                    )
                )
            )
            (if (= filtermode 0) (set myled "0"))
            (if (= filtermode 1) (set myled "1"))
            (if (= filtermode 2) (set myled "M"))

        )

        (
            ;ask for the ASL-requesters
            (if
                (askbool
                    (prompt    "Do you want to use the system's ASL-filerequester\n"
                                "rather than the filerequester of the\n ReqTools.Library ?"
                    )
                    (default 0)
                    (help
                        "This is a question of taste. The ASL-filerequester is the "
                        "system's standard for OS 2.0 and higher, if you have habituated "
                        "to it you should select 'Yes'.\n\n"
                        "The ReqTools.Library's filerequester is more powerful than the "
                        "ASL-filerequester and it is used by many other programs, too. "
                        "In the current version it is faster than the ASL-filerequester "
                        "and is easier to work with.\n\n"
                        @askbool-help
                    )
                )
                (set myasl "TRUE")
                (set myasl "FALSE")
            )
        )

        (
            ;ask for the timer
            (if
                (askbool
                    (prompt    "Do you want PowerPlayer to have a timer-display ?\n"
                                "\nThis will consume some CPU-cycles once a second.\n"
                                "(But you propably won't be able to spot the difference)"
                    )
                    (default 1)
                    (help
                        "Select 'Yes', there's no real reason to turn it off!\n\n"
                        @askbool-help
                    )
                )
                (set mytimer "FALSE")
                (set mytimer "TRUE")
            )
        )

        (
            ;ask for the task pri
            (set mytoolpri
                (cat
                    (asknumber
                        (prompt    "Which task priority do you want for PowerPlayer ?\n\n"
                                    "Valid range: -3..0..3\n\n"
                                    "Default is 0."
                        )
                        (default 0)
                        (help
                            "If you give a high task priority to PowerPlayer it will be "
                            "faster on busy systems. With a low priority (lower than 0) "
                            "PowerPlayer will only get CPU time if the other tasks are "
                            "waiting for something (keypress, disk-access).\n\n"
                            @asknumber-help
                        )
                    )
                )
            )
        )
    )
)

(
    ;get destination dir for PowerPlayer-executable
    (set mydest
        (askdir
            (prompt "Select the directory where you\n want to put the PowerPlayer executable.")
            (help
                "The directory where you store the executable "
                "should be easily accessible via WorkBench or CLI/Shell.\n\n"
                @askfile-help
            )
            (default "Work:")
            (disk)
        )
    )

    (if (= @user-level 0)
        (
            (set mydest (tackon mydest "PowerPlayer"))
            (makedir
                mydest
                (prompt "Making PowerPlayer-Directory")
                (help @makedir-help)
                (infos)
            )
        )
    )

    (set @default-dest mydest)

    (set ppdest (tackon mydest "PowerPlayer"))

    (
        ; check the version of the destination-PowerPlayer (if exists)
        (set vernum (getversion "PowerPlayer"))
        (set ver (/ vernum 65536))
        (set rev (- vernum (* ver 65536)))

        (if (= 1 (exists ppdest))
            (
                (set dvernum (getversion ppdest))
                (set dver (/ dvernum 65536))
                (set drev (- dvernum (* ver 65536)))


                (if (<= vernum dvernum)
                    (
                        (if (= 0
                            (askbool
                                (prompt    "ATTENTION: You have already installed\n\n"
                                            ("PowerPlayer v%ld.%ld\n\nand are going to install\n\n" dver drev)
                                            ("PowerPlayer v%ld.%ld.\n\n" ver rev)
                                            "Do you want to continue installing an older version ?"
                                )
                                (default 0)
                                (help
                                    "Installing an older version is unwise because there "
                                    "may be bugs or important features missing in the "
                                    "older version. If you proceed the newer version will "
                                    "be lost!\n\n"
                                    @askbool-help
                                )
                                (choices "Continue" "Abort")

                            ))
                            (abort "Okay, I didn't overwrite the executable.")
                        )
                    )
                )
            )
        )
    )

    (set copyinfo 1)

    (if (= 1 (exists (ppdest (tackon mydest "PowerPlayer"))))
        (if (askbool
                (prompt    "ATTENTION: You are going to\n"
                "overwrite the PowerPlayer.info file which\n"
                "contains your previous setup.\n\n"
                "Do you want to overwrite old settings?")
                (default 0)
                (help
                    "To get the full gain of new features, you should overwrite\n"
                    "the old PowerPlayer.info-file with a more up-to-date\n"
                    "info-file. On the other hand, you may want to continue\n"
                    "using your old presets\n"
                    @askbool-help
                )
                (choices "Yes" "No")
            )
            (set copyinfo 1)
            (set copyinfo 0))
        )

    (if (= copyinfo 1)
        (copyfiles
            (prompt ("Copying PowerPlayer executable to %s." mydest))
            (help @copyfiles-help)
            (source "PowerPlayer")
            (dest mydest)
            (infos)
        )

        (copyfiles
            (prompt ("Copying PowerPlayer executable to %s." mydest))
            (help @copyfiles-help)
            (source "PowerPlayer")
            (dest mydest)
        )
    )

    ;install all this tooltype stuff
    (if setemup
        (
            (tooltype
            (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "QUALIFIER" myqualifier)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "DIRECTORY" mydirectory)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "PATTERN" mypattern)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "LED" myled)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "ASL" myasl)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "NOTIMER" mytimer)
            )

            (tooltype
                (prompt ("Modifying tooltypes for PowerPlayer in %s." mydest))
                (help @tooltype-help)
                (dest ppdest)
                (settooltype "TOOLPRI" mytoolpri)
            )
        )
    )
)

(
    ;Copy PMC
    (set pmcdest
        (askdir
            (prompt "Select the directory where you\n want to put PMC.")
            (help
                "This directory is usually your 'c:'-directory or the same "
                "directory where PowerPlayer resides in, too.\n\n"
                @askfile-help
            )
            (default mydest)
            (disk)
        )
    )

    (copyfiles
        (prompt ("Copying PMC executable to %s." pmcdest))
        (help @copyfiles-help)
        (source "PMC")
        (dest pmcdest)
    )

)

(
    ;Copy Docs

    (if
        (set qval
            (askoptions
                (prompt    "Please choose which docs you want to have\n"
                            "installed!\n"
                            "(Or choose none to have no docs installed!)")
                (choices
                    "English Docs"
                    "German Docs"
                    "French Docs"
                )

                (default 7)
                (help
                    "Not installing the docs is unwise because you could have "
                    "questions while using PowerPlayer - then you would have to "
                    "search the installer disk of PowerPlayer. Choosing the "
                    "documentation in your favourite language is sufficient.\n\n"
                    @askoptions-help
                )
            )
        )

        (
            (set docsdest
                (askdir
                    (prompt "Select the directory where you\n want to put the docs.")
                    (help
                        "You may store the docs "
                        "where you usually store docs or in the directory where "
                        "PowerPlayer resides in.\n\n"
                        @askfile-help
                    )
                    (default mydest)
                )
            )

            (if (IN qval 0)
                (copyfiles
                    (prompt ("Copying english docs to %s." docsdest))
                    (help @copyfiles-help)
                    (source "Docs/PowerPlayer.English")
                    (dest docsdest)
                    (infos)
                )
            )

            (if (IN qval 1)
                (copyfiles
                    (prompt ("Copying german docs to %s." docsdest))
                    (help @copyfiles-help)
                    (source "Docs/PowerPlayer.Deutsch")
                    (dest docsdest)
                    (infos)
                )
            )
            (if (IN qval 2)
                (copyfiles
                    (prompt ("Copying french docs to %s." docsdest))
                    (help @copyfiles-help)
                    (source "Docs/PowerPlayer.Français")
                    (dest docsdest)
                    (infos)
                )
            )
        )
    )
)

(
    ;install LOCALEs

    (set catdir "LOCALE:catalogs")

    (if (= 2 (exists "LOCALE:" (noreq)))
        (if
            (set qval
                (askoptions
                    (prompt    "Please choose which catalogs you want to have\n"
                                "installed!\n"
                                "(Or choose none to have no catalogs installed!)")
                    (choices
                        "Deutsch (german)"
                        "Français (french)"
                        "Norsk (norwegian)"
                        "Português (portuguese)"
                    )

                    (default 15)
                    (help
                        "It is sufficient to install the catalog(s) of the language(s) "
                        "that you specified as 'preferred' in the locale-preferences "
                        "editor. \n\n"
                        @askoptions-help
                    )
                )
            )

            (
                (if (IN qval 0)
                    (copyfiles
                        (prompt ("Copying german catalog to %s." (tackon catdir "deutsch")))
                        (help @copyfiles-help)
                        (source "Catalogs/deutsch/PowerPlayer.catalog")
                        (dest (tackon catdir "deutsch"))
                        (infos)
                    )
                )
                (if (IN qval 1)
                    (copyfiles
                        (prompt ("Copying french catalog to %s." (tackon catdir "français")))
                        (help @copyfiles-help)
                        (source "Catalogs/français/PowerPlayer.catalog")
                        (dest (tackon catdir "français"))
                        (infos)
                    )
                )
                (if (IN qval 2)
                    (copyfiles
                        (prompt ("Copying norwegian catalog to %s." (tackon catdir "norsk")))
                        (help @copyfiles-help)
                        (source "Catalogs/norsk/PowerPlayer.catalog")
                        (dest (tackon catdir "norsk"))
                        (infos)
                    )
                )
                (if (IN qval 3)
                    (copyfiles
                        (prompt ("Copying portuguese catalog to %s." (tackon catdir "português")))
                        (help @copyfiles-help)
                        (source "Catalogs/português/PowerPlayer.catalog")
                        (dest (tackon catdir "português"))
                        (infos)
                    )
                )
            )
        )
    )
)