home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / C / LFC-SW2.LHA / StormWizard / Include / basic / blitzbasic / WizardTest.asc < prev    next >
Encoding:
Text File  |  1996-06-02  |  2.6 KB  |  92 lines
  1. ;Benoetigt amigalibs.res sowie const.res
  2. ;(im Options-Requester eintragen!)
  3.  
  4. #TOOLMANAGER=1
  5. #TOOLMANAGER_GADGETS=32
  6.  
  7. ;INCLUDE "StormWizard:Examples/ToolManager.bb2"
  8.  
  9. ;Falls "ToolManager.asc" nicht vorhanden sein sollte,
  10. ;muss Stormwizard zunaechst auf die Erzeugung von
  11. ;BlitzBasic-Headerfiles eingestellt werden. Dies
  12. ;wird ueber die ToolTypes von Stormwizard geregelt.
  13.  
  14. ;Dann sollte die Beispieldatei "ToolManager.wizard"
  15. ;(oder eine beliebige andere Datei) eingeladen werden
  16. ;und wieder gespeichert werden. Dabei werden automatisch
  17. ;die Header-Files mit den Konstanten erzeugt.
  18.  
  19. ;Das erzeugte ".asc"-File muss mit dem BB-Editor eingeladen
  20. ;werden und als ".bb2"-File wieder abgespeichert werden.
  21. ;Dadurch wird das Programm tokenisiert. Jetzt kann es mit
  22. ;INCLUDE eingebunden werden.
  23.  
  24. ;Anmerkung: Fuer kleinere Files mit nur ein paar Konstanten
  25. ;kann das HeaderFile auch direkt in den Sourcecode mitauf-
  26. ;genommen werden (Menu:Project/Include File...)
  27.  
  28. DEFTYPE.l                               ;Long-Vars fuer Pointer
  29. DEFTYPE.IntuiMessage *msg               ;Intuition-Message
  30.  
  31. Dim Tags.TagItem (8)                    ;Array fuer Tags
  32. Dim Gads.l       (#TOOLMANAGER_GADGETS) ;Array fuer Gadgets
  33.  
  34. ;-------------------------------------------------------------------------
  35.  
  36. Surface=WZ_OpenSurfaceA_ (0,?SurfaceData, 0)
  37. If Surface
  38.  
  39.   WbToScreen 0
  40.   WinHandle=WZ_AllocWindowHandleA_ (ActiveScreen,0,Surface,0)
  41.   If WinHandle
  42.  
  43.     Tags(0)\ti_Tag=#WWH_GadgetArray,     &Gads(0)
  44.     Tags(1)\ti_Tag=#WWH_GadgetArraySize, #TOOLMANAGER_GADGETS*4
  45.     Tags(2)\ti_Tag=#TAG_END,             0
  46.     NewWindow=WZ_CreateWindowObjA_ (WinHandle,#TOOLMANAGER,&Tags(0))
  47.     If NewWindow
  48.  
  49.       Tags(0)\ti_Tag=#WA_AutoAdjust, True
  50.       Tags(1)\ti_Tag=#TAG_DONE,      0
  51.       MyWindow=WZ_OpenWindowA_ (WinHandle,NewWindow,&Tags(0))
  52.       If MyWindow
  53.  
  54.         Port.l=Peek.l(MyWindow+86)  ;Window\UserPort
  55.         Repeat
  56.           WaitPort_ Port
  57.           Repeat
  58.             *msg=GetMsg_ (Port)
  59.             If *msg
  60.               If *msg\Class = $200 Then exit=True
  61.               ReplyMsg_ *msg
  62.             EndIf
  63.           Until *msg=0
  64.         Until exit
  65.         WZ_CloseWindow_ WinHandle
  66.  
  67.       Else
  68.         NPrint "Fehler bei WZ_CreateWindowObj!"
  69.       EndIf
  70.  
  71.     Else
  72.       NPrint "Fehler bei WZ_CreateWindowObj!"
  73.     EndIf
  74.     WZ_FreeWindowHandle_ WinHandle
  75.  
  76.   Else
  77.     NPrint "Fehler bei WZ_AllocWindowHandle!"
  78.   EndIf
  79.   WZ_CloseSurface_ Surface
  80.  
  81. Else
  82.   NPrint "Fehler bei WZ_OpenSurface!"
  83. EndIf
  84.  
  85. End
  86.  
  87. ;-------------------------------------------------------------------------
  88.  
  89. SurfaceData: IncBin "StormWizard:Examples/ToolManager.Wizard"
  90. SurfaceDataEnd:
  91.  
  92.