home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / Assembler / dse-src6.dms / in.adf / BOUNCHSRCS.LZH / BOBROUTINE.S < prev    next >
Encoding:
Text File  |  1991-01-26  |  9.6 KB  |  558 lines
  1. ; BOBROUTINE BY PSYCHO OF DOMINATORS
  2.  
  3. HOWMANY = 30
  4.  
  5. >EXTERN "DF1:OBJECTS/BOB1",BRUSH1
  6. >EXTERN "DF1:OBJECTS/BOBCOLS",COLLIST
  7. >EXTERN "DF1:OBJECTS/KORDS",KORDS
  8. ORG $38000
  9. LOAD $38000
  10. PICX=320 ; PIXELS
  11. PICY=160 ; PIXELS
  12. ANTAL_FARVER=32
  13. ANTAL_BPL=3
  14. ANTAL_BOBBPL=3
  15. HALFBRITE=0
  16.  
  17. BRUSHX=32 ; PIXELS
  18. BRUSHY=16 ; PIXELS
  19. BRUSHXOFFSET=128-108+1 ; ANTAL EXTRA PIXELS
  20. NUMBER_BRUSHES=HOWMANY-1
  21. DIFI =         20
  22. PICXWORD=PICX/16
  23. PICXBYTE=PICX/8
  24. BPLSIZE=PICXBYTE*PICY
  25. PICSIZE=BPLSIZE*ANTAL_BPL
  26.  
  27. BRUSHXWORD=BRUSHX/16
  28. BRUSHXBYTE=BRUSHX/8
  29. BRUSHSIZE=BRUSHXBYTE*BRUSHY
  30.  
  31.  
  32. START:
  33.     LEA    $DFF000,A5
  34.     JSR    INITIALIZE(PC)
  35.     JSR    SETCOL(PC)
  36.     JSR    SETUP_COPPERLIST1(PC)
  37.     JSR    SETUPSCREEN(PC)
  38.     JSR    CALC_CURSORPOS(PC)
  39.     JSR    MOVEXYPOS(PC)
  40.     JSR    SAVE_POSITIONS(PC)
  41.     JSR    MOVEBRUSH(PC)
  42.     MOVE.L    #0,STATUSPOS
  43. MAIN_LOOP:
  44.     JSR    MOVEXYPOS(PC)
  45.     JSR    MOVEBRUSH(PC)
  46.     BTST    #6,$BFE001
  47.     BNE.S    MAIN_LOOP
  48.     JSR    RESTORE
  49.     RTS
  50. MOVEXYPOS:
  51.        JSR        DOT(PC)
  52.        MOVE.L     #NUMBER_BRUSHES,D0
  53.        LEA    USEKORDS(PC),A4
  54.        LEA    XPOS1(PC),A0
  55. RED_LOOP:
  56.        MOVE.W  (A4)+,(A0)+
  57.        MOVE.W  (A4)+,(A0)+
  58.        DBRA       D0,RED_LOOP
  59.        RTS
  60.  
  61. CLOSELIB=-414
  62. EXECBASE=4
  63. FORBID=-132
  64. OPENLIB=-408
  65. PERMIT=-138
  66.  
  67. ;;; DOS.LIBRARY
  68.  
  69. CLOSE=-36
  70. OPEN=-30
  71. READ=-42
  72.  
  73. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  74. ;;;
  75. ;;; SUB-ROUTINES
  76. ;;;
  77. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  78.  
  79. PAUSE:
  80.     SUBI    #1,D0
  81.     BNE.S    PAUSE
  82.     RTS
  83.  
  84. BLTCPTH=$048
  85. BLTBPTH=$04C
  86. BLTAPTH=$050
  87. BLTDPTH=$054
  88. BLTCMOD=$060
  89. BLTBMOD=$062
  90. BLTAMOD=$064
  91. BLTDMOD=$066
  92. BLTCON0=$040
  93. BLTCON1=$042
  94. BLTSIZE=$058
  95. COP1LCH=$080
  96. COPJMP1=$088
  97. DMACON= $096
  98. DMACONR=$002
  99. VHPOSR= $006
  100.  
  101. SETUP_COPPERLIST1:
  102.  
  103.     MOVE.L    #BPL11,D0
  104.     LEA    HI1(PC),A2
  105.     MOVE.W    D0,6(A2)
  106.     LSR.L    #8,D0
  107.     LSR.L    #8,D0
  108.     MOVE.W    D0,2(A2)
  109.     MOVE.L    #BPL21,D0
  110.     MOVE.W    D0,14(A2)
  111.     LSR.L    #8,D0
  112.     LSR.L    #8,D0
  113.     MOVE.W    D0,10(A2)
  114.     MOVE.L    #BPL31,D0
  115.     MOVE.W    D0,22(A2)
  116.     LSR.L    #8,D0
  117.     LSR.L    #8,D0
  118.     MOVE.W    D0,18(A2)
  119.     RTS
  120.  
  121. SETUP_COPPERLIST2:
  122.     LEA    HI1(PC),A2
  123.     MOVE.L    #BPL12,D0
  124.     MOVE.W    D0,6(A2)
  125.     LSR.L    #8,D0
  126.     LSR.L    #8,D0
  127.     MOVE.W    D0,2(A2)
  128.     MOVE.L    #BPL22,D0
  129.     MOVE.W    D0,14(A2)
  130.     LSR.L    #8,D0
  131.     LSR.L    #8,D0
  132.     MOVE.W    D0,10(A2)
  133.     MOVE.L    #BPL32,D0
  134.     MOVE.W    D0,22(A2)
  135.     LSR.L    #8,D0
  136.     LSR.L    #8,D0
  137.     MOVE.W    D0,18(A2)
  138.     RTS
  139.  
  140. CALC_CURSORPOS:
  141.     MOVE.L    #0,A0
  142.     CLR.L    D2
  143.     MOVE.W    XPOS(PC),D2
  144.     LSR.L    #3,D2
  145.     MOVE.W    XPOS(PC),D3
  146.     ANDI.W    #$000F,D3
  147.     LSL.L    #8,D3
  148.     LSL.L    #4,D3
  149.     ADDA.W    D2,A0
  150.     MOVE.W    D3,SMOOTHXPOS
  151.     MOVE.W    YPOS(PC),D2
  152.     MULU    #40,D2
  153.     ADDA.L    D2,A0
  154.     MOVE.L    A0,CURSOR_POSITION
  155.     RTS
  156.  
  157.  
  158. RESTOREBEHIND_BRUSH1:
  159.     MOVE.B    #3,D0
  160.     MOVE.W    #BRUSHXWORD,D1
  161.     MOVE.W    #BRUSHY,D2
  162.     MOVE.W    #PICXBYTE-BRUSHXBYTE,D3
  163.     MOVE.W    #PICXBYTE-BRUSHXBYTE,D4
  164.     MOVE.L    #PICBUFFER1,A0
  165.     ADDI.L    CURSOR_POSITION,A0
  166.     MOVE.L    CURSOR_POSITION,A1
  167.     ADDI.L    BAKSCR,A1
  168.     JSR    SHOWSCREEN
  169.     RTS
  170. SHOW_BRUSH1:
  171.     MOVE.B    #3,D0
  172.     MOVE.W    #BRUSHXWORD,D1
  173.     MOVE.W    #BRUSHY,D2
  174.     CLR.L    D3
  175.     MOVE.W    #PICXBYTE-BRUSHXBYTE,D4
  176.     MOVE.W    SMOOTHXPOS(PC),D5
  177.     MOVE.L    #BRUSH1,A0
  178.     MOVE.L    BAKSCR(PC),A1
  179.     ADDI.L    CURSOR_POSITION(PC),A1
  180.     MOVE.L    #BRUSHMASK1,A2
  181.     JSR    SHOWBRUSH(PC)
  182.     RTS
  183. MOVEBRUSH:
  184. MOVEBRUSH_WAIT:
  185.     CMP.B    #$FF,$006(A5)
  186.     BNE.S    MOVEBRUSH_WAIT
  187.     CMP.L   #0,STATUSSCR
  188.     BEQ.S    SECOND_FRONT
  189.     CMP.L   #1,STATUSSCR
  190.     BEQ.S    FIRST_FRONT
  191.     
  192. CONT:    
  193.     MOVE.W    #$8400,DMACON(A5)
  194.     BSR.L    RESTORE_BRUSHES
  195.     BSR.L    SHOW_BRUSHES
  196.     BSR.L    SAVE_POSITIONS
  197.     MOVE.W    #$0400,DMACON(A5)
  198.     RTS
  199. FIRST_FRONT:
  200.     MOVE.L    #0,STATUSSCR
  201.     LEA    RESSCR(PC),A2
  202.     MOVE.L  #SCREENBUFFER1,(A2)
  203.     MOVE.L  #SCREENBUFFER2,4(A2)
  204.     MOVE.L    #OLDXPOS1,OLDXPOSPOINTER
  205.     JSR    SETUP_COPPERLIST1(PC)
  206.     BRA.S    CONT
  207. SECOND_FRONT:
  208.     MOVE.L    #1,STATUSSCR
  209.     LEA    RESSCR(PC),A2
  210.     MOVE.L  #SCREENBUFFER2,(A2)
  211.     MOVE.L  #SCREENBUFFER1,4(A2)
  212.     MOVE.L    #OLDXPOS2,OLDXPOSPOINTER
  213.     JSR    SETUP_COPPERLIST2(PC)
  214.     BRA.L    CONT
  215. SAVE_POSITIONS:
  216.     LEA    XPOS1,A0
  217.     MOVE.L    OLDXPOSPOINTER,A1
  218.     MOVE.L    #NUMBER_BRUSHES,D0
  219. SAVE_LOOP:
  220.     MOVE.W  (A0)+,(A1)+
  221.     MOVE.W  (A0)+,(A1)+
  222.     DBRA    D0,SAVE_LOOP
  223.     RTS
  224. RESTORE_BRUSHES:
  225.     LEA    XPOS,A0
  226.     MOVE.L    OLDXPOSPOINTER,A1
  227.     MOVE.L  #NUMBER_BRUSHES,D0
  228. RESTORE_LOOP:    
  229.     MOVE.W  (A1)+,(A0)
  230.     MOVE.W  (A1)+,2(A0)
  231.     MOVEM.L A0-A6/D0-D7,-(A7)
  232.     JSR    CALC_CURSORPOS
  233.     JSR    RESTOREBEHIND_BRUSH1
  234.     MOVEM.L (A7)+,A0-A6/D0-D7
  235.     DBRA    D0,RESTORE_LOOP
  236.     RTS
  237.  
  238.  
  239. SHOW_BRUSHES:
  240.     LEA    XPOS(PC),A0
  241.     LEA    XPOS1(PC),A1
  242.     MOVE.L    #NUMBER_BRUSHES,D0
  243. SHOW_LOOP:
  244.     MOVE.W    (A1)+,(A0)
  245.     MOVE.W  (A1)+,2(A0)
  246.     MOVEM.L A0-A6/D0-D7,-(A7)
  247.     JSR    CALC_CURSORPOS(PC)
  248.     JSR    SHOW_BRUSH1(PC)
  249.     MOVEM.L (A7)+,A0-A6/D0-D7
  250.     DBRA    D0,SHOW_LOOP
  251.     RTS
  252. SETUPSCREEN:
  253.     MOVE.W    #$8100,DMACON(A5)
  254.     MOVE.W    #$8040,DMACON(A5)
  255.     MOVE.W    #$0020,DMACON(A5)
  256.  
  257.     MOVE.W    #ANTAL_BPL,D0
  258.     MULU    #$1000,D0
  259.     ORI.W    #$0280,D0
  260.     MOVE.W    D0,BPLCON0+2
  261.     MOVE.W    #$0080,DMACON(A5)
  262.     MOVE.L    #COPPERLIST,COP1LCH(A5)
  263.     MOVE.W    COPJMP1(A5),D0
  264.     MOVE.W    #$8080,DMACON(A5)
  265.     RTS
  266.  
  267. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  268. ;;;
  269. ;;;    INITIALIZE
  270. ;;;    RESTORE
  271. ;;;
  272. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  273.  
  274. STARTLIST=38
  275.  
  276. INITIALIZE:
  277.     MOVE.W    #$7FFF,$DFF09A
  278.     MOVE.L    $4,A6
  279. RESTORE_COPPER:
  280.     LEA    GRAPHICS_LIBRARY(PC),A1
  281.     CLR.L    D0
  282.     JSR    OPENLIB(A6)
  283.     MOVE.L    D0,A1
  284.     MOVE.L    STARTLIST(A1),OLDCOPPER
  285.     JSR    CLOSELIB(A6)
  286.     RTS
  287.  
  288. RESTORE:
  289.     MOVE.W    #$4000,$DFF09A
  290.     MOVE.W    #$E02C,$DFF09A
  291.     MOVE.L    EXECBASE,A6
  292. RESTORE_SOUND:
  293.     MOVE.W    #$000F,$DFF096
  294.     MOVE.L    OLDCOPPER(PC),$DFF080
  295.     CLR.W    $DFF088
  296.     MOVE.W    #$83E0,$DFF096
  297.     RTS
  298.  
  299. GRAPHICS_LIBRARY:
  300.     DC.B    'graphics.library',0
  301.     EVEN
  302. OLDCOPPER:
  303.     DC.L    0
  304. EVEN
  305.  
  306. SHOWSCREEN:
  307.     MOVE.W    D1,D7
  308.     MULU    D2,D7
  309.     LSL.L    #1,D7
  310.     MOVE.W    D2,D6
  311.     LSL.L    #6,D6
  312.     ADDI.W    D1,D6
  313. SHOWSCREEN_WAIT:
  314.     BTST    #14,DMACONR(A5)
  315.     BNE    SHOWSCREEN_WAIT
  316.     MOVE.L    A0,BLTAPTH(A5)
  317.     MOVE.L    A1,BLTDPTH(A5)
  318.     MOVE.W    D3,BLTAMOD(A5)
  319.     MOVE.W    D4,BLTDMOD(A5)
  320.     MOVE.W    #$0000,BLTCON1(A5)
  321.     MOVE.W    #$09F0,BLTCON0(A5)
  322.     MOVE.W    D6,BLTSIZE(A5)
  323.     ADDI.L    #BPLSIZE,A0
  324.     ADDI.L    #BPLSIZE,A1    
  325.     SUBI.B    #1,D0
  326.     BNE    SHOWSCREEN_WAIT
  327.     RTS
  328.  
  329. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  330. ;;;
  331. ;;; SHOWBRUSH
  332. ;;;
  333. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  334. ;;;
  335. ;;; IN:
  336. ;;;    D0(B)    ANTAL BIT PLANER
  337. ;;;    D1(W)    X-SIZE (WORDS)
  338. ;;;    D2(W)    Y-SIZE (LINES)
  339. ;;;    D3(W)    SOURCE MODULO
  340. ;;;    D4(W)    DESTINATION MODULO
  341. ;;;    D5(W)    SMOOTH X-POSITION
  342. ;;;
  343. ;;;    A0(L)    SOURCE BUFFER
  344. ;;;    A1(L)    DESTINATION BUFFER
  345. ;;;    A2(L)    SOURCE MASK
  346. ;;;
  347. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  348. ;;;
  349. ;;; OUT:
  350. ;;;    D0(B)    0    
  351. ;;;    D1(W)    X-SIZE (WORDS)
  352. ;;;    D2(W)    Y-SIZE (LINES)
  353. ;;;    D3(W)    SOURCE MODULO
  354. ;;;    D4(W)    DESTINATION MODULO
  355. ;;;    D5(W)    BLTCON0
  356. ;;;    D6(W)    BLTSIZE
  357. ;;;    D7(L)    BIT-PLANE SIZE (BYTES)
  358. ;;;
  359. ;;;    A0(L)    END OF SOURCE BUFFER
  360. ;;;    A1(L)    END OF DESTINATION BUFFER
  361. ;;;    A2(L)    END OF SOURCE MASK
  362. ;;;    
  363. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  364.  
  365. SHOWBRUSH:
  366.     MOVE.W    D1,D7
  367.     MULU    D2,D7
  368.     LSL.L    #1,D7
  369.     MOVE.W    D2,D6
  370.     LSL.L    #6,D6
  371.     ADDI.W    D1,D6
  372. SHOWBRUSH_WAIT:
  373.     BTST    #14,DMACONR(A5)
  374.     BNE.S    SHOWBRUSH_WAIT
  375.     MOVE.L    A2,BLTAPTH(A5)
  376.     MOVE.L    A0,BLTBPTH(A5)
  377.     MOVE.L    A1,BLTCPTH(A5)
  378.     MOVE.L    A1,BLTDPTH(A5)
  379.     MOVE.W    D3,BLTAMOD(A5)
  380.     MOVE.W    D3,BLTBMOD(A5)
  381.     MOVE.W    D4,BLTCMOD(A5)
  382.     MOVE.W    D4,BLTDMOD(A5)
  383.     ANDI.W    #$F000,D5
  384.     MOVE.W    D5,BLTCON1(A5)
  385.     ORI.W    #$0FCA,D5
  386.     MOVE.W    D5,BLTCON0(A5)
  387.     MOVE.W    D6,BLTSIZE(A5)
  388.     MOVE.L    #$FFFFFFFF,$044(A5)
  389.     ADDI.L    D7,A0        ; HUSK
  390.     ADDI.L    #BPLSIZE,A1    ; HUSK
  391.     SUBI.B    #1,D0
  392.     BNE.S    SHOWBRUSH_WAIT
  393.     RTS
  394.  
  395. SETCOL:
  396. STORE:   LEA   COLLIST(PC),A0
  397.    LEA      COLOUR1+2(PC),A1
  398.    MOVE.W   #7,D0
  399. FILL2:   MOVE.W   (A0)+,(A1)
  400.    ADDA.L   #4,A1
  401.    DBF   D0,FILL2
  402.    RTS   
  403.  
  404.  
  405. DOT:
  406.     MOVEM.L    A0-A6/D0-D7,-(A7)
  407.     CLR.L   D0
  408.     CLR.L   D1
  409.     CLR.L   D2
  410.     CLR.L   D3
  411.     CLR.L   D4
  412.     CLR.L   D5
  413.     CLR.L   D6
  414.     LEA     USEKORDS(PC),A0
  415.     LEA     KORDPOS(PC),A2
  416.     MOVE.B  #HOWMANY,D6
  417.     MOVE.B  GETX(PC),D0
  418.     MOVE.B  GETX+1(PC),D1
  419.     MOVE.B  GETX+2(PC),D2
  420.     MOVE.B  GETX+3(PC),D3
  421. MAKELOOP1:
  422.     MOVE.L  (A2),A1
  423.     ADDA.L  D0,A1
  424.     MOVE.B  (A1),D4
  425.     LSR.B   #1,D4
  426.     MOVE.L  (A2),A1
  427.     ADDA.L  D1,A1
  428.     MOVE.B  (A1),D7
  429.     LSR.B   #1,D7
  430.     ADD.B   D7,D4
  431.     MOVE.W  D4,(A0)+
  432.     MOVE.L  (A2),A1
  433.     ADDA.L  D2,A1
  434.     MOVE.B  (A1),D5
  435.     LSR.B   #1,D5
  436.     MOVE.L  (A2),A1
  437.     ADD.L   D3,A1
  438.     MOVE.B  (A1),D7
  439.     LSR.B   #1,D7
  440.     ADD.B   D7,D5
  441.     LSR.B   #1,D5
  442.     ADDI.B  #$05,D5
  443.     MOVE.W  D5,(A0)+
  444.     LEA     SINUSPARMS(PC),A6
  445.     MOVE.L  (A6),A6
  446.     ADD.B   2(A6),D0
  447.     ADD.B   3(A6),D1
  448.     SUB.B   4(A6),D2
  449.     SUB.B   5(A6),D3
  450.     DBF     D6,MAKELOOP1
  451.     LEA     GETX(PC),A0
  452.     LEA     SPEED(PC),A1
  453.     MOVE.L  (A1),A1
  454.     MOVE.B  #$04,D0
  455. MAKELOOP2:
  456.     MOVE.B  (A0),D1
  457.     MOVE.B  (A1)+,D2
  458.     ADD.B   D2,D1
  459.     MOVE.B  D1,(A0)+
  460.     DBF     D0,MAKELOOP2
  461.     MOVEM.L    (A7)+,A0-A6/D0-D7
  462.     RTS
  463.  
  464. GETX:      DC.L    $00000000
  465. SPEEDPARMS:
  466. SPEED1:DC.B $03        ; SPEED X1
  467. SPEED2:DC.B $02        ; SPEED X2
  468. SPEED3:DC.B $01        ; SPEED Y1
  469. SPEED4:DC.B $03        ; SPEED Y2
  470. SINUSPARAMETERS:
  471. PARM1:    DC.W $00    ; UNUSED
  472. PARM2:    DC.B $6    ; WITH BETWEEN DOTS X1
  473. PARM3:    DC.B $7    ; WITH BETWEEN DOTS X2
  474. PARM4:    DC.B $8    ; WITH BETWEEN DOTS Y1
  475. PARM5:    DC.B $9    ; WITH BETWEEN DOTS Y2
  476. PARM6:    DC.B $00    ; UNUSED
  477. EVEN
  478. DUMMY:    DC.L $00000000
  479.  
  480. SPEED:        DC.L    SPEEDPARMS
  481. SINUSPARMS:    DC.L    SINUSPARAMETERS
  482. KORDPOS:    DC.L    KORDS
  483. USEKORDS:
  484. BLK.W          HOWMANY*8+4,$0004
  485.  
  486. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  487. ;;;
  488. ;;; CHIP ADDRESSES
  489. ;;;
  490. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  491.  
  492. STATUSSCR:    DC.L    0
  493. RESSCR:     DC.L    SCREENBUFFER1
  494. BAKSCR:     DC.L     SCREENBUFFER2
  495. CURSOR_POSITION:DC.L    PICXBYTE*16
  496. SHADOW_POSITION:DC.L    0
  497. STATUSPOS:    DC.L    0
  498. XPOS:        DC.W    1
  499. YPOS:        DC.W    1
  500. XPOS1:        BLK.W    200
  501. OLDXPOSPOINTER:    DC.L    0
  502. OLDXPOS1:    BLK.W   200
  503. OLDXPOS2:    BLK.W   200
  504. SMOOTHXPOS:    DC.W    0
  505. SMOOTHXPOS2:    DC.W    0
  506.  
  507.     
  508. COPPERLIST:
  509.     DC.W    $1001,$FFFE
  510.     DC.W    $0100,$0200
  511.     DC.W    $2001,$FFFE
  512.     DC.W    $008E,$1C61
  513.     DC.W    $0090,$10F1
  514.     DC.W     $0092,$0038
  515.     DC.W    $0094,$00D0
  516.     DC.W    $0108,$0000
  517. BPLCON0:DC.W    $0100,$3200
  518. HI1:    DC.W    $00E0,0
  519. LO1:    DC.W    $00E2,0
  520. HI2:    DC.W    $00E4,0
  521. LO2:    DC.W    $00E6,0
  522. HI3:    DC.W    $00E8,0
  523. LO3:    DC.W    $00EA,0
  524. COLOUR1:
  525.     DC.W    $0180,$0333
  526.     DC.W    $0182,$0111
  527.     DC.W    $0184,$0222
  528.     DC.W    $0186,$0333
  529.     DC.W     $0188,$0444
  530.     DC.W    $018A,$0555
  531.     DC.W    $018C,$0666
  532.     DC.W    $018E,$0777
  533.     DC.W    $BC01,$FFFE
  534.     DC.W    $0100,$0200
  535.     DC.W    $FFFF,$FFFE    ;END COPPER LIST
  536.  
  537. BRUSH1:        BLK.B    BRUSHSIZE*ANTAL_BOBBPL,$FF
  538. BRUSHMASK1:    BLK.B    BRUSHSIZE,$FF
  539.  
  540. COLLIST:     BLK.B 64
  541.  
  542. PICBUFFER1:    BLK.B    BPLSIZE,0
  543. PICBUFFER2:    BLK.B    BPLSIZE,0
  544. PICBUFFER3:    BLK.B    BPLSIZE,0
  545.  
  546. SCREENBUFFER1:
  547. BPL11:    BLK.B    BPLSIZE,0
  548. BPL21:    BLK.B    BPLSIZE,0
  549. BPL31:    BLK.B    BPLSIZE,0
  550. SCREENBUFFER2:
  551. BPL12:    BLK.B    BPLSIZE,0
  552. BPL22:    BLK.B    BPLSIZE,0
  553. BPL32:    BLK.B    BPLSIZE,0
  554.  
  555. KORDS:  BLK.B   4000,0
  556.  
  557. END:
  558.