home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / Assembler / dse-src1.dms / in.adf / Devpac / 300bobs.asm next >
Encoding:
Assembly Source File  |  1991-12-12  |  6.7 KB  |  264 lines
  1. *        
  2. *  1.    move.w    #149,antal        ;# of bobs-1/2
  3. *  2.   move.l    #32,choice          ;even 0-36 (curve)
  4. *  
  5. *  1.   149 betyder 300 eftersom (149+1)*2=300
  6. *       helften av bobarna er en mirror kopia.
  7. *
  8. *  2.   32 betyder bana 32, helt enkelt hur
  9. *       proggy ska 'hoppa' i sinus & coslistan
  10. * 
  11. *  PS.  det er fullt med fula tricks i denna kod
  12. *  men vitsen med den er att ni ska fo principen
  13. *  klar over hur det funkar.... DS.
  14. *
  15.  
  16.     opt     c-
  17.         section mycode,code_c
  18.          incdir asmdisk1:binary/    
  19.  
  20.     move.l    #main,$80    ;Exeption!
  21.     trap    #0        ;first trix!
  22.     moveq    #0,d0
  23.     rts
  24.     
  25. main    bsr    preset
  26.     bsr    dubbuf
  27.     bsr    blitset
  28.         bsr     initcop                        
  29.     bsr    curve
  30.  
  31. mouse    btst    #6,$bfe001
  32.         bne     mouse
  33.         
  34.         bsr     stopcop
  35.         rte
  36.  
  37. preset    move.w    #149,antal        ;# of bobs-1/2
  38.     move.l    #32,choice          ;even 0-36 (curve)
  39.     move.w    #$0fca,d3        ;Minterm (Cookie-cut)
  40.     move.l  #mask,d4        ;Source A Pointer (mask)
  41.     move.l  #shape,d5        ;Source B Pointer (Shape)
  42.     move.w    #$0782,d6        ;BlitSize (16*30)
  43.     move.l  #$ffffffff,$dff044  ;BlitWord-Mask F & L (Source)
  44.     move.w    #28,$dff060        ;Source C Modulo
  45.     move.w    #1,$dff062        ;Source B Modulo
  46.     move.w    #1,$dff064        ;Source A Modulo
  47.     move.w    #28,$dff066        ;Destination D Modulo
  48.     move.l  #$dff000,a6        ;Offset to Hardware.
  49.     rts
  50.  
  51. blitset move.l  prebuf,$dff048      ;Source C Pointer (Backgrnd)
  52.     move.l  #shape,$dff04c      ;Source B Pointer (Bob)
  53.     move.l  #mask,$dff050       ;Source A pointer (Mask)
  54.     rts
  55.  
  56. initcop 
  57.         move.w  $dff002,olddma     
  58.         bset    #15,olddma          ;Nasty!
  59.         move.l  #mycopper,$dff080
  60.         clr.w   $dff088
  61.         move.w  #%0111111111111111,$dff09a ;off all IRQ
  62.         move.w  #%1100000000010000,$dff09a ;Use Master & Copper IRQ
  63.         move.w  #%0000000000010000,$dff09c ;off Copper IRQ
  64.         move.w  #%0111111111111111,$dff096 ;off all DMA
  65.         move.w  #%1000001111000000,$dff096 ;on blten,copen,bplen,dmaen
  66.         move.w  #%1000010000000000,$dff096 ;Blitter Nasty on!
  67.         move.l  $6c,oldirq
  68.         move.l  #newirq,$6c
  69.         move.l  #0,$dff144             ;Kill all Sprites
  70.         rts 
  71.  
  72. stopcop move.l  oldirq,$6c
  73.         move.w  #%1110000001111111,$dff09a
  74.         move.l  4,a6
  75.         move.l  156(a6),a5             ;156 -> graphics.lib.
  76.         move.l  38(a5),$dff080             ;Reactivate WB-Copper
  77.         clr.w   $dff088
  78.         move.w  #%0111111111111111,$dff096 ;off all DMA
  79.         move.w  olddma,$dff096           ;on normal DMA
  80.         rts
  81.  
  82. newirq  bsr    dubbuf               ;Shift bitmap
  83.     bsr    clsbuf               ;Clear previous
  84.     bsr    barrel               ;Fix bliter shifts
  85.     bsr    putbobs               ;put bob on bitmap
  86.     move.w  #16,$dff09c           ;off copper IRQ
  87.         rte                   ;Exit
  88.  
  89. dubbuf    lea    bufptrs(pc),a0
  90.     adda.w    offset,a0
  91.     move.l  (a0),prebuf
  92.     move.l  (a0),d0
  93.     move.w  d0,pln1l
  94.     swap    d0
  95.     move.w    d0,pln1h
  96.     swap    d0
  97.     addi.w    #32,d0
  98.     move.w    d0,pln3l
  99.     swap    d0
  100.     move.w  d0,pln3h
  101.     swap    d0
  102.     addi.w  #$2fa0,d0
  103.     move.w  d0,pln2l
  104.     swap    d0
  105.     move.w  d0,pln2h
  106.     swap    d0
  107.     addi.w  #32,d0
  108.     move.w  d0,pln4l
  109.     swap    d0
  110.     move.w  d0,pln4h
  111.     eori.w    #4,offset    ;Shifts between bitmaps
  112.     rts
  113.  
  114. clsbuf  btst    #14,$dff002
  115.     bne    clsbuf
  116.     clr.l   $dff064                 ;No shift A & D
  117.     move.l  #$01000000,$dff040         ;D on!
  118.     move.l  prebuf,$dff054             ;Dest. D ptr.
  119.     move.w  #$3020,$dff058             ;BlitSize
  120.     rts
  121.  
  122. barrel    lea    cdptrs(pc),a0        ;Close your eyes now if
  123.     lea    shifts(pc),a2            ;you do NOT like TRIX!!
  124.     lea    cosinus(pc),a4   ;x
  125.     lea    sinus(pc),a5     ;y
  126.  
  127. lsbptr1    addi.w    #2,tabendl     ;This is very nasty!!!
  128. msbptr1    addi.w    #0,tabendh     ; but i don't care...
  129.     cmpi.w    #720,tabendl     
  130.     bmi.s   hiptr    
  131.     clr.w    tabendl
  132. hiptr    cmpi.w    #720,tabendh    
  133.     bmi.s    loptr
  134.     clr.w    tabendh
  135. loptr    adda.w    tabendl,a4
  136.     adda.w  tabendh,a5
  137.  
  138.     move.w    antal,d7
  139.     ext.l   d7
  140. getnxt    move.w    (a5),d0
  141. lsbptr2    adda.w    #2,a5
  142.     lsl.w    #6,d0
  143.     move.w    (a4),d2
  144. msbptr2    adda.w  #0,a4
  145.     move.w  d2,d1
  146.     andi.w  #$000f,d1
  147.     ror.w    #4,d1
  148.     lsr.w    #3,d2
  149.     add.w    d0,d2
  150.     add.w    prebuf+2,d2
  151.     move.w    d2,(a0)+
  152.     move.w    d1,(a2)+
  153.     dbf    d7,getnxt
  154.         rts
  155.  
  156. putbobs lea    shifts(pc),a2
  157.     lea    cdptrs(pc),a0
  158. wblit    btst    #14,$dff002
  159.     bne    wblit
  160.     move.w    #1,$dff064               ;Source A Modulo
  161.     move.w    #28,$dff066           ;Dest.  D Modulo
  162.     move.w    antal,d7
  163.     ext.l    d7                   ;Make Long
  164. nxtbob    move.w    (a2)+,d1
  165.     move.w    d1,$42(a6)           ;BLTCON1
  166.     or.w    d3,d1                   ;Minterm
  167.     move.w    d1,$40(a6)               ;BLTCON0
  168.     move.w    (a0),$4a(a6)           ;Source C (LOW)
  169.     move.w    (a0)+,$56(a6)               ;Dest.  D (LOW)
  170.     move.w    d4,$52(a6)               ;Source A (LOW)
  171.     move.w    d5,$4e(a6)           ;Source B (LOW)
  172.     move.w    d6,$58(a6)               ;BLTSIZE (16*30)
  173.     dbf    d7,nxtbob
  174.     rts
  175.  
  176. curve    movem.l    a0-a4/d0-d4,-(a7)
  177.     move.w    #0,tabendl
  178.     move.w    #180,tabendh
  179.     lea    order1(pc),a0
  180.     lea    order2(pc),a1
  181.     lea    order3(pc),a2
  182.     lea    order4(pc),a3
  183.     clr.l    d0
  184.     move.l    choice,d0
  185.     move.w    0(a0,d0.l),msbptr2+2       ;Ops! illegal again!
  186.     move.w    0(a1,d0.l),lsbptr2+2
  187.     move.w    0(a2,d0.l),lsbptr1+2
  188.     move.w    0(a3,d0.l),msbptr1+2
  189.     movem.l (a7)+,a0-a4/d0-d4
  190.     rts
  191.  
  192.  
  193. prebuf  dc.l    $70000               ;Bitmap at ABS. addr.
  194. bufptrs dc.l    $70000,$75000              ;makes the code shorter.
  195. offset  dc.w    4
  196. choice    dc.l    0
  197.  
  198. order1    dc.w 2,8,18,8,30,8, 2,4,12,6, 4,12,4,2,10,92,22,118,10
  199. order2    dc.w 2,8,22,8,14,4,34,2,46,8,12,12,2,4, 4, 2,12,  2, 8
  200. order3  dc.w 2,4, 2,0, 2,4, 2,6, 2,2, 2, 2,2,8, 2, 2, 2,  2, 2
  201. order4  dc.w 0,2, 2,4, 2,6, 2,0, 0,2, 8, 0,8,2, 2, 4, 2,  2, 2
  202.  
  203.     dc.w    0,0,0,0,0,0,0,0
  204.  
  205.  
  206. mycopper
  207.     dc.w    $0182,$0093    ;also the colors are set up
  208.     dc.w    $0184,$0093    ;in a specific order.
  209.     dc.w    $0186,$0093    ;So when two bobs 'cross' each
  210.     dc.w    $0188,$0063    ;other they wont't produce
  211.     dc.w    $018a,$0043    ;another color...
  212.     dc.w    $018c,$0063
  213.     dc.w    $018e,$0043
  214.     dc.w    $0190,$0063
  215.     dc.w    $0192,$0093
  216.     dc.w    $0194,$0043
  217.     dc.w    $0196,$0093    
  218.     dc.w    $0198,$0063
  219.     dc.w    $019a,$0043
  220.     dc.w    $019c,$0063
  221.     dc.w    $019e,$0043
  222.         dc.w    $0100,$4200
  223.     dc.w    $0102,$0000
  224.         dc.w    $008e,$4ca1
  225.         dc.w    $0090,$12a1
  226.         dc.w    $0092,$0048
  227.         dc.w    $0094,$00c0
  228.         dc.w    $0108,32      ;32 bytes off screen   (This is the trick...)   
  229.         dc.w    $010a,-96     ;32*3=96               (to get so many bobs!)
  230.         dc.w    $0180
  231.         dc.w    0,$00e0       ;4 bitplanes but we do NOT
  232. pln1h    dc.w    0,$00e2          ;get 16 colors on bobs....
  233. pln1l    dc.w    0,$00e4
  234. pln2h    dc.w    0,$00e6
  235. pln2l    dc.w    0,$00e8
  236. pln3h    dc.w    0,$00ea
  237. pln3l   dc.w    0,$00ec
  238. pln4h    dc.w    0,$00ee
  239. pln4l    dc.w    0
  240.         dc.w    $009c,$8010
  241.     dc.w    $ffdf,$fffe,$1001,$fffe         ;a good one!
  242.     dc.w    $0100,$0200            ;Garbage off! he he..
  243.         dc.w    $ffff,$fffe
  244.  
  245. olddma  dc.l    0
  246. oldirq  dc.l    0
  247. tabendl dc.w    0
  248. tabendh dc.w    0
  249. antal    dc.w    0
  250.     even
  251. cdptrs  dcb.w    510,0
  252. shifts  dcb.w   510,0
  253.     even
  254.     dcb.w   100,0
  255. cosinus incbin  'cosinus'    
  256.     dcb.w    50,0
  257. sinus    incbin  'sinus'
  258.     dcb.w      50,0
  259. shape    incbin    'shape'        ;more tricks here!
  260. mask    incbin  'shadow'
  261.  
  262.   
  263.  
  264.