Amiga ISO Collection/AmigaUtilCD2.iso/Paint/alpha1.dms/in.adf/Install-Alpha

Text File | 1994-10-22 | 10.8 KB | 344 lines

; Alpha Paint Installer Utility
;
; For Alpha Paint from InnoVision Technology
;
; (Last updated: Vincent Law 10/5/94)

(set @user-level 2)

(
   ; Which OS are we under?
   (set osver (/ (getversion) 65536))

   ; Ask where to install it...
   (makedir "RAM:ENV")
   (makeassign "ENV" "RAM:ENV")
   (run "Alpha1:CHECK_CPU")
   (if (= (exists "RAM:ENV/MATH") 0)
      (message
         "WARNING: To run Alpha Paint, Math coprocessor\n"
         "         68882 or above is required!         \n"
         (help "\n\n   Click PROCEED to continue.\n   Click CANCEL to abort.\n")
      )
   )
   (run "Alpha1:inquire")
   (set default_dir (getenv "TOASTER_DIR"))
   (if (<> @ioerr 0)
      (abort "ERROR: Please install Video Toaster Software\n"
             "       before installing Alpha Paint!       \n")
   )

   (set Error_code 127)

   (while (<> Error_code 0)
      (
         (set default_dest_dir
            (askdir
               (prompt "Video Toaster installation has been found on \n"
                       default_dir "\n"
                       "Click PROCEED to install Alpha Paint onto\n"
                       default_dir "/AlphaPaint\n")
               (help "   This is the default directory where\n"
                     "   Alpha Paint will be installed. \n")
               (default default_dir)
            )
         )
         (set @default-dest default_dest_dir)
         (message
            "Alpha Paint will be installed onto\n"
            (tackon @default-dest "AlphaPaint") "\n"
            (help "\n\n   Click PROCEED to continue.\n   Click CANCEL to abort.\n")
         )
         (set Error_code 0)
      )
   )

   (if (= (exists (tackon @default-dest "AlphaPaint")) 0)
      (makedir (tackon @default-dest "AlphaPaint"))
   )

   (if (= (exists (tackon @default-dest "AlphaPaint/ALPHAPIX")) 0)
      (makedir (tackon @default-dest "AlphaPaint/ALPHAPIX"))
   )

   (if (= (exists (tackon @default-dest "AlphaPaint/ALPHA_SETUP")) 0)
      (makedir (tackon @default-dest "AlphaPaint/ALPHA_SETUP"))
   )

   (if (= (exists (tackon @default-dest "AlphaPaint/Brushes")) 0)
      (makedir (tackon @default-dest "AlphaPaint/Brushes"))
   )

   (if (= (exists (tackon @default-dest "AlphaPaint/Data")) 0)
      (makedir (tackon @default-dest "AlphaPaint/Data"))
   )

   (set iff_dir
      (askdir
         (prompt "Enter the name of your preferred directory\n"
                 "for loading 24-bit IFF picture files:     \n")
         (help "   This is the default directory where   \n"
               "   IFF pictures will be loaded and saved.\n")
         (default (tackon @default-dest "AlphaPaint"))
      )
   )

   (set framestore_dir
      (askdir
         (prompt "Enter the name of default FRAMESTORE directory:\n")
         (help "This is the directory where the framestore files will be saved.\n")
         (default (getenv "FS_DIR"))
      )
   )

   (set jpeg_dir
      (askdir
         (prompt "Enter the name of default JPEG directory:\n")
         (help "This is the directory where the JPEG files will be used.\n")
         (default (tackon @default-dest "AlphaPaint"))
      )
   )

   (set default_fonts_dir (tackon @default-dest "ToasterFonts"))

   (set toasterfonts_dir
      (askdir
         (prompt "Enter the name of default TOASTER FONTS directory:\n")
         (help "This is the directory where the toaster fonts will be\n"
               "looked for during the execution of Alpha Paint.      \n")
         (default default_fonts_dir)
      )
   )

   (set chromafonts_dir
      (askdir
         (prompt "Enter the name of default CHROMA FONTS directory:\n")
         (help "This is the directory where the chroma fonts will be\n"
               "looked for during the execution of Alpha Paint.     \n")
         (default default_fonts_dir)
      )
   )

   (set psfonts_dir
      (askdir
         (prompt "Enter the name of default POSTSCRIPT FONTS directory:\n")
         (help "This is the directory where the postscript fonts will\n"
               "be looked for during the execution of Alpha Paint.   \n")
         (default default_fonts_dir)
      )
   )

   ;----------------------------------------------------------
   ; Prompt for Disk 1.

   (if (= (exists "Alpha1:") 2)
      (askdisk
         (prompt "Please insert Alpha Paint Program Disk 1:")
         (help "")
         (dest "Alpha1")
      )
   )

   (if (= (exists "Alpha1:Alpha.setup") 1)
      (copyfiles
         (prompt "Creating Alpha Paint Startup file")
         (help @copyfiles-help)
         (source "Alpha1:Alpha.setup")
         (dest (tackon @default-dest "AlphaPaint/Data"))
      )
   )

   (if (= (exists "Alpha1:make_alpha_startup_file") 1)
      (run "Alpha1:make_alpha_startup_file " @default-dest " " iff_dir " " framestore_dir " " jpeg_dir " " toasterfonts_dir " " chromafonts_dir " " psfonts_dir)
   )

   (onerror
      (message
         "Alpha Paint installation is not complete.\n"
         "Do you want to quit?\n"
      )
   )

   (if (= (exists "Alpha1:make_alpha_call_script") 1)
      (run "Alpha1:make_alpha_call_script " @default-dest " 0")
   )

   (onerror
      (message
         "Alpha Paint installation is not complete.\n"
         "Do you want to quit?\n"
      )
   )

   (if (= (exists "Alpha1:AMenu") 2)
      (
         (makedir "fonts:AMenu")
         (copyfiles
            (prompt "")
            (help @copyfiles-help)
            (source "Alpha1:AMenu")
            (dest "fonts:AMenu")
            (all)
         )
      )
   )

   (if (= (exists "Alpha1:AMenu.font") 1)
      (copyfiles
         (prompt "")
         (help @copyfiles-help)
         (source "Alpha1:AMenu.font")
         (dest "fonts:")
      )
   )

   (working "Installing Alpha Paint Utility Files...")

   (if (= (exists "Alpha1:LHEX") 1)
      (
         (if (= (exists "C:LHEX") 0)
            (copyfiles
               (prompt "")
               (help @copyfiles-help)
               (source "Alpha1:LHEX")
               (dest "C:")
            )
         )
         (set LHEX_string ("LHEX -qfw=%s x Alpha1:Alpha.lha" (tackon @default-dest "AlphaPaint")))
         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha1:Icons.lha" @default-dest))
         (run LHEX_string)
;         (set LHEX_string ("LHEX -qfw=%s x Alpha1:AlphaLaunch.lha" (tackon @default-dest "AlphaPaint")))
;         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha1:Data.lha" (tackon @default-dest "AlphaPaint/Data")))
         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha1:Tutorial1.lha" (tackon @default-dest "AlphaPaint/ALPHAPIX")))
         (run LHEX_string)
;         (if (= (exists "Alpha1:COPY_ALPHA_PS_LIBRARY") 1)
;            (run "Alpha1:COPY_ALPHA_PS_LIBRARY")
;         )
         (if (= (exists "LIBS:post.library") 1)
            (
               (set psver (/ (getversion "LIBS:post.library") 65536))
               (set psver_ext (- (getversion "LIBS:post.library") 65536))
               (if (OR (< psver 1) (AND (= psver 1) (< psver_ext 7)))
                  (
                     (set install_ps_library_flag
                        (askbool
                           (prompt "The currently installed PostScript Library is\n"
                                   "version " psver "." psver_ext "                                  \n\n"
                                   "Do you want to overwrite it with version 1.7?\n")
                           (choices "Yes" "No")
                           (help "Click YES to install PostScript version 1.7 library.\n"
                                 "Click NO to keep your own PostScript library.       \n")
                           (default 1)
                        )
                     )
                     (if (= install_ps_library_flag 1)
                        (
                           (working "Installing PostScript Library....")
                           (run "LHEX -qfw=LIBS: x Alpha1:LIBS.lha")
                        )
                     )
                  )
               )
            )
            (
               (working "Installing PostScript Library....")
               (run "LHEX -qfw=LIBS: x Alpha1:LIBS.lha")
            )
         )
      )
   )

   (tooltype
      (prompt "Creating Alpha Paint icon....")
      (help "Setting default tool for Alpha Paint icons...")
      (dest (tackon @default-dest "Alpha"))
      (setdefaulttool (tackon @default-dest "AlphaPaint/Alpha"))
      (setstack 30000)
      (noposition)
   )

;   (tooltype
;      (prompt "")
;      (help "Setting default tool for Alpha Paint icons...")
;      (dest (tackon @default-dest "Alpha-S"))
;      (setdefaulttool (tackon @default-dest "AlphaPaint/Alpha"))
;      (setstack 30000)
;      (noposition)
;   )

   (if (= (exists "Alpha1:InstallManager") 1)
      (
         (copyfiles
            (prompt "")
            (help @copyfiles-help)
            (source "Alpha1:InstallManager")
            (dest (tackon @default-dest "AlphaPaint"))
         )
         (if (= (exists "Alpha1:Data/aaaa.0") 1)
            (
               (set install_command ("Alpha1:InstallManager 0 %s" (tackon @default-dest "AlphaPaint")))
               (run install_command)
;               (set aaaa (getenv "AAAA"))
;               (if (<> aaaa "0")
;                  (abort "ERROR: Cannot validate Alpha Paint installation!\n")
;               )
            )
         )
      )
   )

   ;----------------------------------------------------------
   ; Prompt for Disk 2.

   (askdisk
      (prompt "Please insert Alpha Paint Program Disk 2:")
      (help "")
      (dest "Alpha2")
   )

   (working "Installing Tutorial files....")

   (if (= (exists "C:LHEX") 1)
      (
         (set LHEX_string ("LHEX -qfw=%s x Alpha2:JPEG1.lha" (tackon @default-dest "AlphaPaint/Data")))
         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha2:Tutorial2.lha" (tackon @default-dest "AlphaPaint/ALPHAPIX")))
         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha2:Tutorial_IFF1.lha" (tackon @default-dest "AlphaPaint/ALPHAPIX")))
         (run LHEX_string)
      )
   )

   ;----------------------------------------------------------
   ; Prompt for Disk 3.

   (askdisk
      (prompt "Please insert Alpha Paint Program Disk 3:")
      (help "")
      (dest "Alpha3")
   )

   (working "Installing Tutorial files....")

   (if (= (exists "C:LHEX") 1)
      (
         (set LHEX_string ("LHEX -qfw=%s x Alpha3:JPEG2.lha" (tackon @default-dest "AlphaPaint/Data")))
         (run LHEX_string)
         (set LHEX_string ("LHEX -qfw=%s x Alpha3:Tutorial_IFF2.lha" (tackon @default-dest "AlphaPaint/ALPHAPIX")))
         (run LHEX_string)
      )
   )

   (set @default-dest (tackon @default-dest "AlphaPaint"))

   (message
      "Remember to remove the last Alpha Paint disk\n"
      "from the floppy drive after the installation\n"
      "and store it in a safe place.               \n"
      (help "\n\n   Click PROCEED to continue.\n   Click CANCEL to abort.\n")
   )
)