home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Misc / MegaJitterV1,3.LHA / rexx / god next >
Encoding:
Text File  |  1994-05-17  |  5.5 KB  |  199 lines
  1. /****************************************************************************
  2. * MegaJitter GOD                                            (C) LVA May 1994
  3. * --------------                                            ----------------
  4. * 
  5. * This AREXX program generates RANDOM ecosystems for MegaJitter and subse-
  6. * quently tests their stability.
  7. * Settings which produce long-lived ecosystems are printed on the screen.
  8. * 
  9. * Criteria for a healthy ecosystem are:
  10. *  - at least one run of 50'000 time steps.
  11. *  - not more than 3 total extinctions
  12. * 
  13. * I think God must have had a similar program to determine the incredibly
  14. * fine-tuned Universal constants for our own Universe....
  15. * Doing it by hand is real tedious monkey work !
  16. * 
  17. ****************************************************************************/
  18.  
  19. OPTIONS FAILAT 1000000    /* don't want REXX to complain about legal return values! */
  20.  
  21. SIGNAL ON BREAK_C
  22. SIGNAL ON HALT
  23.  
  24. /* WATCH OUT : we're going to use two command hosts.
  25.        PRIMARY        : MegaJitter itself
  26.     SECONDARY    : AmigaDOS
  27.  
  28.    By simply saying "ADRRESS" on its own, we toggle between the two */
  29.  
  30. ADDRESS COMMAND                /* Secondary host first ... */
  31. 'RESIDENT C:WAIT'            /* cache wait command since we need it often */
  32.  
  33. ADDRESS "REXX-MJ"            /* MegaJitter has to be running already... */
  34.  
  35. SAY "MegaJitter GOD: The Automated Universe Creator (just sit back and watch)"
  36. SAY
  37.  
  38. RANDU(time('S'))            /* Randomize random number sequence (sigh) */
  39.  
  40. DO FOREVER                    /* Use CTRL-C to break out guys.. */
  41.  
  42.     CALL gen_random_parms    /* roll some dice.. make a new Universe */
  43.     CALL config_MJ
  44.  
  45.     'MJ_RESET'                /* Use new constants */
  46.  
  47.     CALL TIME('R')            /* reset elapsed time clock */
  48.  
  49.     max_time = 0            /* reset oldest ecosystem age */
  50.  
  51.     i = 0                    /* circular buffer index */
  52.     bugs.0 = 0
  53.     bugs.1 = 0                /* bugs[5] */
  54.     bugs.2 = 0
  55.     bugs.3 = 0
  56.     bugs.4 = 0
  57.  
  58.     DO WHILE TIME('E') < 15*60
  59.  
  60.  
  61.     /**** SAMPLE RUNNING ECOSYSTEM EVERY 5 SECS ***/
  62.  
  63.         ADDRESS                /* toggle hosts */
  64.         'Wait 5 secs'        /* we're not Busy waiting !! */
  65.         ADDRESS                /* toggle hosts */
  66.  
  67.     /**** TRACK MAXIMUM ECOSYSTEM AGE ***/
  68.  
  69.         'MJ_TIMESTEPS?'
  70.         IF RC > max_time THEN max_time = RC
  71.  
  72.     /**** IF ECOSYSTEM DIES OUT TOO OFTEN, TRY ANOTHER ... ***/
  73.  
  74.         'MJ_RUNS?'            /* Ask MJ how many extinctions have occured */
  75.         IF RC > 3 THEN DO
  76.             SAY "Ecosystem failed because too many extinctions in just " TIME('E') "SECONDS"
  77.             LEAVE            /* Try another set of constants then ... */
  78.         END
  79.  
  80.     /**** TRACK CURRENT POPULATION. IF CONSTANTLY EXPLODING, TRY ANOTHER... ***/
  81.  
  82.         'MJ_BUGS?'            /* howmany bugs do we have now ? */
  83.         bugs.i = RC
  84.  
  85.         i = ((i+1) // 4)
  86.  
  87.         total = 0
  88.         DO n = 0 to 3
  89.             total = total + bugs.n
  90.         END
  91.         total = total / 4
  92.  
  93.         IF total > 280 THEN DO
  94.             SAY "Ecosystem failed because population too numerous."
  95.             max_time = 0
  96.             LEAVE
  97.         END
  98.  
  99.     END
  100.  
  101.     'MJ_RUNS?'
  102.     IF RC < 3 & max_time > 50000 THEN DO
  103.         SAY "Ecosystem succeeded ! (Max Age achieved =" max_time ")"
  104.         CALL dump_constants
  105.     END
  106. END
  107.  
  108.  
  109.  
  110. EXIT                        /* END OF THE PROGRAM */
  111.  
  112. /* ------------------------------------------------------------------------ */
  113. /* Generate legal, random parameter settings to configure a new ecosystem.    */
  114. /* ------------------------------------------------------------------------ */
  115. gen_random_parms:
  116.  
  117.     init_bugs       = rand(10,50)            /* never more than MAX_BUGS **!! */
  118.     init_food       = rand(50,4000)
  119.     init_energy     = rand(50,3000)
  120.     init_variance   = rand(80,240)
  121.     mutate_range    = rand(20,100)
  122.     food_rate       = rand(1,20)        
  123.     food_energy     = rand(100,2000)
  124.     oasis_size      = 0
  125.     x_pattern       = 1
  126.     y_pattern       = 1            
  127.  
  128.     return
  129.  
  130. /* ------------------------------------------------------------------------ */
  131. /* Send new parameter settings to MegaJitter using the assignment syntax.   */
  132. /* ------------------------------------------------------------------------ */
  133. config_MJ:
  134.  
  135.     'INIT_BUGS'        init_bugs
  136.     'INIT_FOOD'        init_food
  137.     'INIT_ENERGY'    init_energy
  138.     'INIT_VARIANCE'    init_variance
  139.     'MUTATE_RANGE'    mutate_range    
  140.     'FOOD_RATE'        food_rate
  141.     'FOOD_ENERGY'    food_energy
  142.     'OASIS_SIZE'    oasis_size
  143.     'X_PATTERN'        x_pattern
  144.     'Y_PATTERN'        y_pattern
  145.  
  146.     'MJ_VISION'            /*   <<<<<<    */
  147.     'MJ_NOSEX'
  148.  
  149.     SAY
  150.     SAY "Trying out a NEW random Ecosystem on"
  151.     ADDRESS COMMAND 'DATE'
  152.  
  153.     return
  154.  
  155. /* ------------------------------------------------------------------------ */
  156. /* The current settings produced a long-lived ecosystem: dump settings.     */
  157. /* ------------------------------------------------------------------------ */
  158. dump_constants:
  159.  
  160.     SAY "Ecosystem had the following parameters:"
  161.     SAY
  162.     
  163.     SAY 'INIT_BUGS    =' init_bugs
  164.     SAY 'INIT_FOOD    =' init_food
  165.     SAY 'INIT_ENERGY    =' food_energy
  166.     SAY 'INIT_VARIANCE    =' init_variance
  167.     SAY 'MUTATE_RANGE    =' mutate_range    
  168.     SAY 'FOOD_RATE    =' food_rate
  169.     SAY 'FOOD_ENERGY    =' food_energy
  170.     SAY 'OASIS_SIZE    =' oasis_size
  171.     SAY 'X_PATTERN    =' x_pattern
  172.     SAY 'Y_PATTERN    =' y_pattern
  173.  
  174.     SAY
  175.     return
  176.  
  177. /* ------------------------------------------------------------------------ */
  178. /* A better RANDOM(low, high) without the 1.999 limitation !                */
  179. /* ------------------------------------------------------------------------ */
  180. RAND:
  181.     arg low,high
  182.  
  183.     range = high - low
  184.  
  185.     return (low + (randu()*range)%1)
  186.  
  187. /* ------------------------------------------------------------------------ */
  188. /*                        SPECIAL REXX INTERRUPT HANDLERS                        */
  189. /* ------------------------------------------------------------------------ */
  190.  
  191. BREAK_C:
  192.     SAY "^C *** PROGRAM ABORTED ***"
  193.     EXIT
  194. /* ------------------------------------------------------------------------ */
  195. HALT:
  196.     SAY "*** PROGRAM ABORTED *** (External HALT issued)"
  197.     EXIT
  198. /* ------------------------------------------------------------------------ */
  199.