home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Misc / Mathscript_cr.lzx / MathScript / Install < prev    next >
Encoding:
Text File  |  1997-01-18  |  12.4 KB  |  311 lines
  1. ; MathScript installation script
  2. ; (C) Copyright 1996 by Simon Ihmig
  3.  
  4. (if (= @language "deutsch")
  5.     (set #def_lang 1)
  6.     (set #def_lang 0)
  7. )
  8.  
  9. (set #lang
  10.     (askchoice
  11.         (prompt "Select your preferred language!\nWählen Sie Ihre bevorzugte Sprache aus!")
  12.         (help   (cat "The language specified will be used for this installation script, the documentation and the program.\n\nDie angegebene Sprache wird für die Installation, die Dokumentation und das Programm benutzt.\n\n" @askchoice-help))
  13.         (choices "english" "deutsch")
  14.         (default #def_lang)
  15.     )
  16. )
  17.  
  18. (if (= #lang 0)
  19.     (
  20.         (set #MSG_NOMUI            "It seems that there is not MUI installed on your system.\nMathScript needs at least MUI3.1!")
  21.         (set #MSG_INSTALLTYPE      "What do you want to do?")
  22.         (set #MSG_INSTALLTYPE_HELP (cat "Full Installation:\nA new installation will be done.\n\nUpdate:\nThe existing MathScript installation will be updated.\n\nDeinstallation:\nThe existing MathScript installation will be removed.\n\nInstall Keyfile:\nOnly your keyfile will be copied.\n\n" @askchoice-help))
  23.         (set #MSG_INSTALL_CHOICE1  "Full Installation")
  24.         (set #MSG_INSTALL_CHOICE2  "Update")
  25.         (set #MSG_INSTALL_CHOICE3  "Deinstallation")
  26.         (set #MSG_INSTALL_CHOICE4  "Install Keyfile")
  27.         (set #MSG_DIR              "Where shall the directory 'MathScript' be created?")
  28.         (set #MSG_DIR_HELP         (cat "All files needed by MathScript will be installed here.\n\n" @askdir-help))
  29.         (set #MSG_ICONS            "Which set of icons do you prefer?")
  30.         (set #MSG_ICONS_HELP       (cat "Standard:\nThe standard icons.\n\nMagicWB:\nMagicWB icons. You should only use these, if you have MagicWB installed.\n\n" @askchoice-help))
  31.         (set #MSG_FONTDIR          "Where do you want to install the supplied PostScript fonts?")
  32.         (set #MSG_FONTDIR_HELP     (cat "There are some PostScript fonts you need for MathScript.\nChoose where you want to install them!\n\n" @askdir-help))
  33.         (set #MSG_STARTUP          "Some additions to your User-Startup are needed!")
  34.         (set #MSG_STARTUP_HELP     (cat "MathScript needs an assign MathScript: pointing to its home directory.\nA PSFonts: assign should be made for the directory you installed the PostScript fonts in.\n\n" @startup-help))
  35.         (set #MSG_POSTLIB          "Copying post.library to Libs:")
  36.         (set #MSG_POSTLIB_HELP     (cat "post.library is needed for MathScript. It should be copied to Libs:\n\n" @copylib-help))
  37.         (set #MSG_REMSTARTUP       "Removing User-Startup entries")
  38.         (set #MSG_APPS             "Which applications do you want to use with MathScript?")
  39.         (set #MSG_APPS_HELP        (cat "Select all applications which you want to import formulas generated by MathScript.\n\n" @askoptions-help))
  40.         (set #MSG_INIT             "May the file '%s' of %s be replaced?")
  41.         (set #MSG_INIT_HELP        "This file is used for imported EPS files. In order to show and print MathScript formulas corecctly, it has to be modified slightly. If you replace it now, you do not have to care about this later on.")
  42.         (set #MSG_INIT_DIR         "In which directory is %s located?")
  43.         (set #MSG_INIT_DIR_HELP    (cat "Select the directory, where the program is installed!\n\n" @askdir-help))
  44.         (set #MSG_INIT_NODIR       "The directory does not seem to be correct.\nThe file %s/%s does not exist there!")
  45.     )
  46.     (
  47.         (set #MSG_NOMUI            "MUI scheint nicht auf Ihrem System installiert zu sein!\nMathScript benötigt mindestens MUI3.1!")
  48.         (set #MSG_INSTALLTYPE      "Was wollen Sie tun?")
  49.         (set #MSG_INSTALLTYPE_HELP (cat "Komplette Installation:\nEine neue Installation wird erstellt.\n\nUpdate:\nDie existierende Installation wird erneuert.\n\nDeinstallation:\nDie existierende Installation wird entfernt.\n\nKeyfile kopieren:\nNur Ihr Keyfile wird kopiert.\n\n" @askchoice-help))
  50.         (set #MSG_INSTALL_CHOICE1  "Komplette Installation")
  51.         (set #MSG_INSTALL_CHOICE2  "Update")
  52.         (set #MSG_INSTALL_CHOICE3  "Deinstallation")
  53.         (set #MSG_INSTALL_CHOICE4  "Keyfile kopieren")
  54.         (set #MSG_DIR              "Wo soll das Verzeichnis 'MathScript' erzeugt werden?")
  55.         (set #MSG_DIR_HELP         (cat "In diesem Verzeichnis werden alle von MathScript benötigten Dateien abgelegt.\n\n" @askdir-help))
  56.         (set #MSG_ICONS            "Welche Icons bevorzugen Sie?")
  57.         (set #MSG_ICONS_HELP       (cat "Standard:\nDie normalen Icons.\n\nMagicWB:\nIcons im MagicWB-Stil. Diese sollten Sie nur verwenden, wenn Sie auch MagicWB installiert haben.\n\n" @askchoice-help))
  58.         (set #MSG_FONTDIR          "Wo sollen die beigefügten PostScript-Schriften installiert werden?")
  59.         (set #MSG_FONTDIR_HELP     (cat "Einige PostScript-Schriften liegen bei, die MathScript benötigt.\nWo sollen diese installiert werden?\n\n" @askdir-help))
  60.         (set #MSG_STARTUP          "Einige Änderungen an Ihrer User-Startup müssen vorgenommen werden!")
  61.         (set #MSG_STARTUP_HELP     (cat "MathScript benötigt ein Assign MathScript:.\nEin Assign PSFonts: sollte auf das Verzeichnis zeigen, in dem die PostScript-Schriften installiert wurden.\n\n" @startup-help))
  62.         (set #MSG_POSTLIB          "Kopiere post.library nach Libs:")
  63.         (set #MSG_POSTLIB_HELP     (cat "MathScript benötigt post.library. Die Library sollte nach Libs: kopiert werden.\n\n" @copylib-help))
  64.         (set #MSG_REMSTARTUP       "Entferne User-Startup Einträge")
  65.         (set #MSG_APPS             "Welche Programme wollen Sie mit MathScript benutzen?")
  66.         (set #MSG_APPS_HELP        (cat "Wählen Sie alle Programme aus, mit denen Sie mathematische Formeln von MathScript einbinden wollen.\n\n" @askoptions-help))
  67.         (set #MSG_INIT             "Darf die Datei '%s' von %s ersetzt werden?")
  68.         (set #MSG_INIT_HELP        "Diese Datei wird für importierte EPS-Dateien verwendet. Damit MathScript-Formeln richtig angezeigt und gedruckt werden können, müssen einige Mängel beseitigt werden. Wenn Sie die Datei jetzt ersetzen lassen, müssen Sie sich später nicht mehr darum kümmern.")
  69.         (set #MSG_INIT_DIR         "In welchem Verzeichnis befindet sich %s?")
  70.         (set #MSG_INIT_DIR_HELP    (cat "Wählen Sie das Verzeichnis aus, in dem das Programm installiert wurde!\n\n" @askdir-help))
  71.         (set #MSG_INIT_NODIR       "Das Verzeichnis scheint nicht korrekt zu sein.\nDie Datei %s/%s existiert dort nicht!")
  72.  
  73.     )
  74. )
  75.  
  76. ; *************************
  77. ; ***** P_ReplaceInit *****
  78. ; *************************
  79.  
  80. (procedure P_ReplaceInit ;#app_name #app_init #app_subdir
  81.  
  82. (if (askbool (prompt (#MSG_INIT #app_init #app_name)) (help #MSG_INIT_HELP) (default 1))
  83.     (
  84.         (set #leave 0)
  85.  
  86.         (until (= #leave 1)
  87.             (
  88.                 (set #dir (askdir (prompt (#MSG_INIT_DIR #app_name)) (help #MSG_INIT_DIR_HELP) (default @default-dest)))
  89.  
  90.                 (if (exists (tackon #dir (tackon #app_subdir #app_init)) (noreq))
  91.                     (set #leave 1)
  92.                     (message (#MSG_INIT_NODIR #app_subdir #app_init))
  93.                 )
  94.  
  95.             )
  96.         )
  97.  
  98.         (copyfiles (source "init.ps") (dest (tackon #dir #app_subdir) (newname #app_init)))
  99.     )
  100. )
  101. )
  102.  
  103.  
  104. ; *********************
  105. ; ***** P_Install *****
  106. ; *********************
  107. (procedure P_Install
  108.  
  109. (if (= #dest "")
  110.     (
  111.         (set #dir (askdir (prompt #MSG_DIR) (help #MSG_DIR_HELP) (default @default-dest)))
  112.         (set #dest (tackon #dir "MathScript"))
  113.         (makedir #dest (infos))
  114.     )
  115. )
  116.  
  117. (set #font_dest (askdir (prompt #MSG_FONTDIR) (help #MSG_FONTDIR_HELP) (default #dest)))
  118.  
  119. (set #icons (askchoice (prompt #MSG_ICONS) (help #MSG_ICONS_HELP) (choices "Standard" "MagicWB")))
  120.  
  121. (set #apps (askoptions (prompt #MSG_APPS) (help #MSG_APPS_HELP) (choices "FinalWriter V5" "WordWorth V5")))
  122.  
  123.  
  124. (if (IN #apps 0)
  125.     (
  126.     (set #app_name "FinalWriter")
  127.     (set #app_subdir "FWFiles")
  128.     (set #app_init "init.ps")
  129.  
  130.     (P_ReplaceInit)
  131.     )
  132. )
  133.  
  134. (if (IN #apps 1)
  135.     (
  136.     (set #app_name "WordWorth")
  137.     (set #app_subdir "WwFiles")
  138.     (set #app_init "eps_init.ps")
  139.  
  140.     (P_ReplaceInit)
  141.     )
  142. )
  143.  
  144. (copylib (confirm) (optional "force" "askuser") (source "Libs/post.library") (dest "LIBS:") (prompt #MSG_POSTLIB) (help #MSG_POSTLIB_HELP))
  145.  
  146. (makedir (tackon #dest "Files") (infos))
  147. (makedir (tackon #dest "Catalogs") (infos))
  148. (makedir (tackon #dest "Docs") (infos))
  149. (makedir (tackon #dest "Libs") (infos))
  150. (makedir (tackon #dest "Rexx") (infos))
  151. (makedir (tackon #dest "Fonts") (infos))
  152. (makedir (tackon #dest "Icons") (infos))
  153. (makedir (tackon #dest "Formulas") (infos))
  154.  
  155. (copyfiles (source "MathScript") (dest #dest))
  156. (copyfiles (source "Registration") (dest #dest))
  157. (copyfiles (source "MathScript.prefs") (dest #dest))
  158.  
  159. (copyfiles (source "Files") (dest (tackon #dest "Files")) (all))
  160. (copyfiles (source "Libs/fontengine.library") (dest (tackon #dest "Libs")))
  161. (copyfiles (source "Rexx") (dest (tackon #dest "Rexx")) (all))
  162. (copyfiles (source "Fonts") (dest (tackon #dest "Fonts")) (all))
  163.  
  164. (if (= #lang 1)
  165.     (copyfiles (source "Docs/deutsch") (dest (tackon #dest "Docs")) (all))
  166.     (copyfiles (source "Docs/english") (dest (tackon #dest "Docs")) (all))
  167. )
  168. (copyfiles (source "Docs") (dest (tackon #dest "Docs")) (files) (pattern "#?"))
  169.  
  170. (if (= #lang 1)
  171.     (copyfiles (source "Catalogs/deutsch") (dest (tackon #dest "Catalogs/deutsch")) (all))
  172. )
  173.  
  174. (copyfiles (source "Catalogs") (dest (tackon #dest "Catalogs")) (files) (pattern "#?"))
  175.  
  176. (if (= #icons 1)
  177.     (set #icon_dir "Icons/MagicWB")
  178.     (set #icon_dir "Icons/Standard")
  179. )
  180.  
  181. (copyfiles (source #icon_dir) (dest #dest) (files) (pattern "#?"))
  182.  
  183. (copyfiles (source (tackon #icon_dir "Icons")) (dest (tackon #dest "Icons")) (all))
  184.  
  185. (foreach (tackon #dest "Files") "~(#?.info)"
  186.     (copyfiles (source (tackon #icon_dir "Files/File.info")) (dest (tackon #dest "Files")) (newname (cat @each-name ".info")))
  187. )
  188.  
  189. (foreach (tackon #dest "Rexx") "~(#?.info)"
  190.     (copyfiles (source (tackon #icon_dir "Rexx/Rexx.info")) (dest (tackon #dest "Rexx")) (newname (cat @each-name ".info")))
  191. )
  192.  
  193. (foreach (tackon #dest "Docs") "#?.guide"
  194.     (copyfiles (source (tackon #icon_dir "Docs/Guide.info")) (dest (tackon #dest "Docs")) (newname (cat @each-name ".info")))
  195. )
  196.  
  197. (if (= #key 1)
  198.     (copyfiles (source "MathScript.key") (dest #dest))
  199. )
  200.  
  201.  
  202. (copyfiles (source "PSFonts") (dest #font_dest) (all))
  203.  
  204.  
  205. (makeassign "MathScript" #dest)
  206. (makeassign "PSFonts" #font_dest)
  207.  
  208. (startup "MathScript" (prompt #MSG_STARTUP) (help #MSG_STARTUP_HELP) (command (cat "assign MathScript: " #dest "\n" "assign PSFonts: " #font_dest " add")))
  209. )
  210.  
  211. ; ********************
  212. ; ***** P_Update *****
  213. ; ********************
  214. (procedure P_Update
  215.  
  216. (if (NOT (exists "MathScript:libs/fontengine.library" (noreq)))
  217.     (P_RemoveOld)
  218. )
  219.  
  220. (set #dest "MathScript:")
  221.  
  222. (P_Install)
  223. )
  224.  
  225. ; ***********************
  226. ; ***** P_Deinstall *****
  227. ; ***********************
  228. (procedure P_Deinstall
  229.  
  230. (set #dest (expandpath "MathScript:"))
  231.  
  232. (makeassign "MathScript")
  233.  
  234. (run (cat "delete \"" #dest "\" all"))
  235.  
  236. (startup "MathScript" (prompt #MSG_REMSTARTUP) (help @startup-help) (command ""))
  237. )
  238.  
  239. ; *********************
  240. ; ***** P_CopyKey *****
  241. ; *********************
  242. (procedure P_CopyKey
  243.  
  244. (set #dest "MathScript:")
  245.  
  246. (if (= #key 1)
  247.     (copyfiles (source "MathScript.key") (dest #dest))
  248. )
  249. )
  250.  
  251. ; ***********************
  252. ; ***** P_RemoveOld *****
  253. ; ***********************
  254. (procedure P_RemoveOld
  255.  
  256. (run "delete MathScript:Catalogs all")
  257. (run "delete MathScript:Docs all")
  258. (run "delete MathScript:Fonts all")
  259. (run "delete MathScript:Icons all")
  260.  
  261. (delete "MathScript:Rexx/CloseMathScript.ms")
  262. (delete "MathScript:Rexx/InsertFormula.ms")
  263. (delete "MathScript:Rexx/OpenMathScript.ms")
  264.  
  265. (delete "MathScript:Metrics")
  266. (delete "MathScript:PSFont")
  267. (delete "MathScript:init.ps")
  268. )
  269.  
  270.  
  271.  
  272. (if (NOT (exists "Libs:muimaster.library"))
  273.   (message #MSG_NOMUI)
  274. )
  275.  
  276. (if (exists "MathScript:MathScript" (noreq))
  277.     (set #exists 1)
  278.     (set #exists 0)
  279. )
  280.  
  281. (if (exists "MathScript.key" (noreq))
  282.     (set #key 1)
  283.     (set #key 0)
  284. )
  285.  
  286. (if (= #exists 1)
  287.     (
  288.         (if (= #key 1)
  289.             (set #install (askchoice (prompt #MSG_INSTALLTYPE) (help #MSG_INSTALLTYPE_HELP) (choices #MSG_INSTALL_CHOICE1 #MSG_INSTALL_CHOICE2 #MSG_INSTALL_CHOICE3 #MSG_INSTALL_CHOICE4) (default 1)))
  290.             (set #install (askchoice (prompt #MSG_INSTALLTYPE) (help #MSG_INSTALLTYPE_HELP) (choices #MSG_INSTALL_CHOICE1 #MSG_INSTALL_CHOICE2 #MSG_INSTALL_CHOICE3) (default 1)))
  291.         )
  292.     )
  293.     (
  294.         (set #install 0)
  295.     )
  296. )
  297.  
  298. (set #dest "")
  299.  
  300. (select #install
  301.     (P_Install)
  302.     (P_Update)
  303.     (P_Deinstall)
  304.     (P_CopyKey)
  305. )
  306.  
  307. (set @default-dest #dest)
  308.  
  309. (exit)
  310.  
  311.