home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Misc / GXY-INF.LHA / infos / compare.s < prev    next >
Encoding:
Text File  |  1996-03-09  |  10.8 KB  |  461 lines
  1. *******************************************************************************
  2. * COMPARE   vergleicht die game disk mit der getrainten disk und speichert    *
  3. * alle unterschiedlichen blöcke in file: datenfile des akktuellen Dirs ab !   *
  4. * Format :                                            *
  5. *  offset: 0   .w  :     anzahl der zu schreibenden blöcke !              *
  6. *          2-  .w  :     offsets des blockes auf der disk !                   *
  7. *       512     :     erster block  512 byte lang dan der nächste          *
  8. *                                V 1.00          [GRAiN/DTC 07/19/92]         *
  9. *******************************************************************************
  10.  
  11.                 include "dh0:code/include/exec/exec_lib.i"
  12. last    =    2*20        * letzter Block (11*79*2)
  13.  
  14.  
  15.  
  16. _LVOOutput     equ    -60        ;DOS: Output-Handle holen
  17. _LVOWrite     equ    -48        ;     Ausgabe
  18.  
  19. x:        move.l    a0,clineadd    * cli-command  addr
  20.         move.l    d0,clinelen    * cli-command  lenght
  21.         move.b    #0,-1(a0,d0)
  22.  
  23.         move.l    #databuffer+2,datavector
  24.         move.l    #blockbuffer,curbufvector
  25.  
  26.  
  27.  
  28. _main        move.l    #dosname,a1        ;Name der DOS-Lib 
  29.         moveq    #0,d0            ;Version egal
  30.         move.l  _SysBase,a6        ;Basis Exec
  31.            jsr     _LVOOpenLibrary(a6)    ;DOS-Lib oeffnen
  32.         tst.l    d0            ;Fehler?
  33.         beq    fini            ;wenn Fehler, Ende
  34.         move.l    d0,DOSBase        ;Zeiger merken
  35.  
  36.         move.l    #curoff,tsource
  37.         move.l    #5,tlaenge
  38.         bsr    print
  39.  
  40.         move.l    #text1,tsource
  41.         move.l    #(text1e-text1),tlaenge
  42.         bsr    print
  43.  
  44.         
  45.         cmp.l    #1,clinelen
  46.         bne    nohelptext
  47.         move.l    #help,tsource
  48.         move.l    #helpe-help,tlaenge
  49.         bsr    print
  50.         bra    ente
  51.  
  52.  
  53. nohelptext:
  54.                 move.l    #0,a1
  55.                 CALLEXEC FindTask               * Task suchen
  56.                 move.l  d0,ReplyPort+16            * MsgPort
  57.                 lea     ReplyPort,a1            * initialisieren und
  58.                 CALLEXEC AddPort                * einfügen
  59.  
  60.  
  61.                 lea     DiskIO0,a1              * IOTrackDisk laden
  62.                 move.l  #0,d0            * Laufwerk  dfx (0)
  63.                 moveq   #0,d1                   * keine Spezial-Flags
  64.                 lea     DevName,a0              * Name des Devices
  65.                 CALLEXEC OpenDevice             * Device öffnen
  66.         tst.l   d0                      * hat's geklappt?
  67.                 beq    drive1device       
  68.  
  69.         move.l    #noDrive0,tsource
  70.         move.l    #(noDrive0e-nodrive0),tlaenge
  71.         bsr    print
  72.         bra    Abort          
  73.  
  74. drive1device:
  75.         bsr    enter
  76.  
  77.                 lea     DiskIO1,a1               * IOTrackDisk laden
  78.                 move.l  #1,d0                    * Laufwerk  dfx (0)
  79.                 moveq   #0,d1                   * keine Spezial-Flags
  80.                 lea     DevName,a0              * Name des Devices
  81.                 CALLEXEC OpenDevice             * Device öffnen
  82.         tst.l   d0                      * hat's geklappt?
  83.                 beq    starttest       
  84.  
  85.         move.l    #noDrive1,tsource
  86.         move.l    #(noDrive1e-nodrive1),tlaenge
  87.         bsr    print
  88.         bra    Abort          
  89.  
  90.  
  91. ******************************************************************************
  92. starttest:    bsr    enter
  93. loadnext:
  94.         bsr    loadblock
  95.  
  96.         move.l    #line,tsource
  97.         move.l    #2,tlaenge
  98.         bsr    print
  99.         bsr    trackprint
  100.         bsr    compare        
  101.         bsr    freeprint
  102.     
  103.         add    #1,curtrack
  104.         cmp    #160,curtrack
  105.         bne    loadnext
  106.         
  107.  
  108.         move    savecounter,databuffer
  109.  
  110.         move.l    #savtxt,tsource
  111.         move.l    #savtxte-savtxt,tlaenge
  112.         bsr    print
  113.  
  114.  
  115.         move.l    dosbase,a6
  116.         move.l    #1006,d2    * Mode :  NEWFILE
  117.         move.l    clineadd,d1
  118.         jsr    -30(a6)        * open
  119.         move.l    d0,datei
  120.         beq    endoftest
  121.         
  122.  
  123.         move.l    #databuffer,d2
  124.         move.l    #000,d3
  125.         move    savecounter,d3
  126.         asl.l    #8,d3
  127.         asl.l    #1,d3
  128.         add.l    #512,d3
  129. *        move.l    #90112,d3
  130.         move.l    datei,d1
  131.         jsr    -48(a6)        * write
  132.         tst    d0
  133.         bmi    withclose
  134.  
  135.         
  136.         move.l    #endtxt,tsource
  137.         move.l    #endtxte-endtxt,tlaenge
  138.         bsr    print
  139.  
  140.         
  141.  
  142.  
  143. ****************************************************************************** 
  144. withclose:
  145.  
  146.         move.l    datei,d1
  147.         jsr    -36(a6)        * close
  148.         
  149.  
  150. endoftest:    
  151.         jsr    -132(a6)
  152.         move.l    d0,$60004
  153.  
  154. ende:
  155.         lea     DiskIO0,a1
  156.                 CALLEXEC CloseDevice            * Device schließen
  157.  
  158.         lea     DiskIO1,a1
  159.                 CALLEXEC CloseDevice            * Device schließen
  160.  
  161.  
  162. Abort:        lea     ReplyPort,a1
  163.         CALLEXEC RemPort                * Port entfernen
  164.  
  165. ente:
  166.  
  167.         move.l    #curon,tsource
  168.         move.l    #5,tlaenge
  169.         bsr    print
  170.  
  171.         move.l    DOSBase,a1        ;Basis der Lib
  172.         move.l  _SysBase,a6        ;Basis Exec
  173.             jsr     _LVOCloseLibrary(a6)    ;Funktion "Schliessen"
  174.  
  175.  
  176.  
  177. fini:
  178.         move.l    clineadd,$60000
  179.         move.l    #00000,d0
  180.         rts                ;Return zum CLI
  181.  
  182.  
  183.  
  184.  
  185. ******************* S U B R O U T I N E S *******************************
  186. compare:
  187.         lea    buffer0,a0
  188.         lea    buffer1,a1
  189.         move.l    a0,curgameblock
  190.         move.l    a1,curtrainblock
  191.  
  192.         move    #11-1,d6
  193. cmp_3:        move    #512/4-1,d7
  194.         move.l    curtrainblock,a1
  195.         move.l    curgameblock,a0
  196.         
  197. cmp_1:        
  198.         cmpm.l    (a0)+,(a1)+
  199.         bne    saveblock
  200.         dbf    d7,cmp_1
  201.         move.l    #equal,tsource
  202.         move.l    #6,tlaenge
  203.         bsr    print
  204.         bra    cmp_e
  205. saveblock:
  206.         move.l    datavector,a2
  207.         move    curblock,(a2)+
  208.         move.l    a2,datavector    
  209.         move.l    curtrainblock,a2
  210.         move.l    curbufvector,a3
  211.         move    #512/4-1,d7
  212. cmp_2:        move.l    (a2)+,(a3)+            
  213.         dbf    d7,cmp_2
  214.         add    #1,savecounter
  215.         add.l    #512,curbufvector
  216.         cmp    #255,savecounter
  217.         bhi    endofsave
  218.         move.l    #nequal,tsource
  219.         move.l    #6,tlaenge
  220.         bsr    print
  221.         bra    cmp_e
  222. cmp_e:        
  223.         add    #1,curblock
  224.         add.l    #512,curtrainblock
  225.         add.l    #512,curgameblock
  226.         dbf    d6,cmp_3
  227.         rts
  228.  
  229. endofsave:    move.l    #toomany,tsource
  230.         move.l    #toomanye-toomany,tlaenge
  231.         bsr    print
  232.         move.l    (sp)+,a0
  233.         bra    endoftest
  234.  
  235.         
  236.  
  237. LoadBlock:    
  238.  
  239.  
  240.                 lea     DiskIO0,a1                                         
  241.                 move.l  #ReplyPort,14(a1)        * Nachrichten-Port laden
  242.         move.w  #2,28(a1)        * Kommando: lesen         
  243.                 move.l  #512*11,36(a1)        * Länge: 512 Bytes * track
  244.                 move.l  #buffer0,40(a1)        * Adresse
  245.         moveq    #0,d0
  246.                 move    curblock,d0
  247.                 asl.l    #8,d0
  248.                 asl.l    #1,d0            
  249.                 move.l    d0,44(a1)        * Byte-Offset startblock    
  250.         movem.l d1-d3/a1-a3,-(SP)               
  251.                 CALLEXEC DoIO            * und 'reinladen!         
  252.         movem.l (SP)+,d1-d3/a1-a3    
  253.         move    d0,error
  254.         beq    loaddf1
  255.  
  256.         move.l    #noDisk0,tsource
  257.         move.l    #(noDisk0e-nodisk0),tlaenge
  258.         bsr    print
  259.         move.l    (sp)+,a0
  260.         bra    ende
  261.  
  262. loaddf1:
  263.                 lea     DiskIO1,a1                                         
  264.                 move.l  #ReplyPort,14(a1)        * Nachrichten-Port laden
  265.         move.w  #2,28(a1)        * Kommando: lesen         
  266.                 move.l  #512*11,36(a1)        * Länge: 512 Bytes * track
  267.                 move.l  #buffer1,40(a1)        * Adresse
  268.         moveq    #0,d0
  269.                 move    curblock,d0
  270.                 asl.l    #8,d0
  271.                 asl.l    #1,d0            
  272.                 move.l    d0,44(a1)        * Byte-Offset startblock    
  273.         movem.l d1-d3/a1-a3,-(SP)               
  274.                 CALLEXEC DoIO            * und 'reinladen!         
  275.         movem.l (SP)+,d1-d3/a1-a3    
  276.         move    d0,error
  277.  
  278.         beq    return    
  279. errors:
  280.         move.l    #noDisk1,tsource
  281.         move.l    #(noDisk1e-nodisk1),tlaenge
  282.         bsr    print
  283.         move.l    (sp)+,a0
  284.         bra    ende
  285. return:
  286.         rts                
  287.  
  288.             
  289. trackprint:
  290.         moveq    #0,d0
  291.         move    curblock,d0
  292.         beq    trpri_0
  293. trpri_0:    divu    #11,d0
  294.         lea     printbuffer,a0
  295.         move.b    #"0",(a0)
  296.         cmp    #100,d0
  297.         bmi    trpri_1
  298.         move.b    #"1",(a0)
  299.         sub    #100,d0
  300. trpri_1:    
  301.         lea    1(a0),a0
  302.         move.l    d0,d1
  303.         divu    #10,d0                
  304.         move.b    d0,(a0)
  305.         add.b    #$30,(a0)+
  306.         mulu    #10,d0
  307.         sub    d0,d1
  308.         move.b    d1,(a0)
  309.         add.b    #$30,(a0)+
  310.         move.b    #":",(a0)+
  311.         move.b    #" ",(a0)+
  312.         move.l    #printbuffer,tsource
  313.         move.l    #5,tlaenge
  314.         bsr    print
  315.         rts
  316. freeprint:
  317.         moveq    #0,d0
  318.         move    savecounter,d0
  319.         lea     printbuffer,a0
  320.         move.b    #" ",(a0)+
  321.         move.b    #$1b,(a0)+
  322.         move.l    #"[31m",(a0)+
  323.         
  324.         move.l    d0,d1
  325.         divu    #100,d0
  326.         move.b    d0,(a0)
  327.         add.b    #$30,(a0)+
  328.         mulu    #100,d0
  329.         sub    d0,d1
  330.  
  331.         move.l    d1,d0
  332.         divu    #10,d0                
  333.         move.b    d0,(a0)
  334.         add.b    #$30,(a0)+
  335.         mulu    #10,d0
  336.         sub    d0,d1
  337.  
  338.         move.b    d1,(a0)
  339.         add.b    #$30,(a0)+
  340.         move.b    #10,(a0)+
  341.         move.l    #printbuffer,tsource
  342.         move.l    #10,tlaenge
  343.         bsr    print
  344.         rts
  345.  
  346. enter:        move.l    #enterc,tsource
  347.         move.l    #1,tlaenge
  348.         bsr    print
  349.         rts
  350.  
  351. Print:            move.l    DOSBase,a6        ;DOS-Funktion rufen    
  352.         jsr    _LVOOutput(a6)        ;Hole Output-Handle
  353.         move.l    d0,d1            ;und in d1 merken
  354.  
  355.         move.l    tsource,d2        ;Address Text
  356.         move.l    tlaenge,d3            ;Laenge Text
  357.             move.l  DOSBase,a6             ;Basis DOS
  358.         jsr    _LVOWrite(a6)        ;Funktion "Schreiben"
  359.         rts
  360.  
  361.  
  362.  
  363.  
  364. *********************** Datenbereich **********************************
  365. savecounter:    dc.w    0        * anzahl der gesavten blöcke    
  366. datavector:    dc.l    0        * auf akkt DATENstand 
  367. curbufvector:    dc.l    0        * auf akkt BUFFERstand
  368. curgameblock:    dc.l    0        * zwischenspeicher  
  369. curtrainblock:    dc.l    0        * zwischenspeicher  
  370. curtrack:    dc.w    0        * akueller track
  371. curblock:    dc.w    0        * akueller block     
  372. lasblock:    dc.w    1749        * letzer track
  373.  
  374. clineadd:    dc.l    0        * cli-command
  375. clinelen:    dc.l    0        * cli-command
  376.  
  377. error:        dc.w    0        * ErrorStatus
  378. drive:        dc.l    0        * DFx (?)
  379. *********************** Datenbereich **********************************
  380.  
  381. tsource:    dc.l    0
  382. tlaenge:    dc.l    0
  383. DiskIO0:         ds.b     80                         * IOStdReq-Record drive 0
  384. DiskIO1:         ds.b     80                         * IOStdReq-Record drive 1
  385. ReplyPort:      ds.b     34                         * MsgPort-Record
  386. DevName:        dc.b     "trackdisk.device",0
  387.          even
  388.  
  389. Memory:         dc.l    0
  390.  
  391. DOSBase:     dc.l    0
  392. dosname:    dc.b    'dos.library',0
  393.          even
  394. filename:    dc.b    "df0:daten",0
  395.         even
  396. datei:        dc.l    0            * datei - identification
  397.  
  398.  
  399. text1:        dc.b       $1B,$5B,$31,$6D,"Compare da Disks "
  400.         dc.b    $1B,$5B,$3b,$6D,"V0.90 by Grain/Dytec",10
  401.         dc.b     "insert game disk in df0: and train disk in df1:",10
  402. text1e:        even
  403. help:        dc.b    "it compares two disks (game and train disk) and"
  404.         dc.b     " save the",10
  405.         dc.b    "different blocks from the traindisk (the installed "
  406.         dc.b    "trainer)",10,"to make an Install.exe !!",10
  407.         dc.b    10,"Usage: Compare (Datenfilename)",10,10
  408. helpe:        even
  409.  
  410.  
  411. noDisk0:    dc.b    10,"No Disk in Drive df0:",10
  412. noDisk0e:    even
  413. noDisk1:    dc.b    10,"No Disk in Drive df1:",10
  414. noDisk1e:    even
  415. noDrive0    dc.b    "Drive df0: not ready",10
  416. noDrive0e:    even
  417. noDrive1    dc.b    "Drive df1: not ready",10
  418. noDrive1e:    even
  419. toomany:    dc.b    10,10,"Too many different blocks! (over 300!)",10
  420. toomanye:    even
  421. savtxt:        dc.b    10,"Now saving DatenFile",10
  422. savtxte:    even
  423. endtxt:        dc.b    "All work done!",10
  424. endtxte:    even
  425. curoff:        dc.b    $1b,"[0 p"
  426.         even
  427. curon:        dc.b    $1b,"[1 p"
  428.         even
  429. nul:        dc.b    "0"
  430.         even
  431. one:        dc.b    "1"
  432.         even
  433. next:        dc.b    " "
  434.         even
  435. enterc:        dc.b    10
  436.         even
  437. equal:        dc.b    $1b,"[32m."
  438.         even
  439. nequal:        dc.b    $1b,"[31m."
  440.         even
  441. line:        dc.b    $1b,"M"        * return + Crs 1 zeile hoch
  442.         even
  443.                 section sectors,bss_p
  444. printbuffer:    ds.b    100
  445. buffer0:    ds.b    512*11            * Trackbuffer drive 0
  446.         even
  447. buffer1:    ds.b    512*11            * Trackbuffer drive 1
  448.         even
  449. databuffer:    ds.b    512            * für blockwerte und so 
  450. blockbuffer:    ds.b    512*255            * 255 blöcke 
  451.  
  452.  
  453.  
  454.            **************************************************
  455.            * ON THE LONG TRIP  THIS TEXTFILE TRAVELD TO THE *
  456.            * DOORS OF BEVERLY HILLS HOUSE ON THE 20-Jul-92  * 
  457.            *          TIME UPLOADED IS 01:07:34             *
  458.            *   CALL NOW ++49 (0)30 662 55 02 = DO IT NOW!   *
  459.            **************************************************
  460.  
  461.