home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / Source / pheno.lha / pha / IFFFix.s < prev    next >
Encoding:
Text File  |  1987-12-17  |  4.2 KB  |  220 lines
  1.  
  2.             ;--- IFF-Picture Decruncher & Fixer ---
  3.  
  4. org    $20000
  5. load    $20000
  6.  
  7. >EXTERN        'TimGlasLogo',IFFBild
  8.  
  9. S:        movem.l    d0-d7/a0-a6,-(a7)
  10.         bsr    Decrunch
  11.         bsr    SaveAll
  12.         bsr    StartCopper
  13.         bsr    WaitLoop
  14.         bsr    RestoreCopper
  15.         movem.l    (a7)+,d0-d7/a0-a6
  16.         rts
  17.  
  18. SaveAll:    lea    OldCop(pc),a2
  19.         moveq    #$f,d2
  20.         moveq    #0,d0
  21.         move.l    4.W,a6
  22.         lea    GfxName(pc),a1
  23.         jsr    -408(a6)
  24.         move.l    d0,a0
  25.         move.l    $26(a0),(a2)+
  26.         lea    $dff000,a6
  27.         move.w    $2(a6),d0
  28.         move.w    $1c(a6),d1
  29.         bset    d2,d0
  30.         bset    d2,d1
  31.         movem.w    d0-d1,(a2)
  32.         rts
  33.  
  34. StartCopper:    lea    CopperList(pc),a0
  35.         move.l    a0,$80(a6)
  36.         tst.w    $88(a6)
  37.         move.w    #$7fff,d0
  38.         move.w    d0,$96(a6)
  39.         move.w    d0,$9a(a6)
  40.         move.w    #$87c0,$96(a6)
  41.         move.w    #$c000,$9a(a6)
  42.         rts
  43.  
  44. RestoreCopper:    lea    OldCop(pc),a0
  45.         move.l    (a0)+,$80(a6)
  46.         tst.w    $88(a6)
  47.         move.w    (a0)+,$96(a6)
  48.         move.w    (a0)+,$9a(a6)
  49.         rts
  50.  
  51. WaitLoop:    cmp.b    #-1,$6(a6)
  52.         bne.S    WaitLoop
  53.         btst    #6,$bfe001
  54.         bne.S    WaitLoop
  55.         rts
  56.  
  57. OldCop:        dc.l    0,0
  58. GfxName:    dc.b    'graphics.library',0
  59.         even
  60.  
  61. ;----------------------------------------------------------------------
  62.  
  63.             ;--- The Decrunch ---
  64.  
  65. Decrunch:    bsr    Base
  66.         bsr    GetColors
  67.         bsr    Graphics
  68.         rts
  69.  
  70. GetColors:    move.l    #'CMAP',d0
  71.         move.l    IFFPointer(pc),a0
  72.         bsr    FindString
  73.         lea    Colors+2(pc),a1
  74.         move.w    Cols(pc),d7
  75.         subq.w    #1,d7
  76. ColorLoop:    moveq    #0,d0
  77.         move.b    (a0)+,d0
  78.         move.b    (a0)+,d1
  79.         move.b    (a0)+,d2
  80.         lsl.w    #4,d0
  81.         lsr.b    #4,d2
  82.         or.b    d1,d0
  83.         or.b    d2,d0
  84.         move.w    d0,(a1)
  85.         addq.l    #4,a1
  86.         dbf    d7,ColorLoop
  87.         rts
  88.  
  89. ; --- When decrunching: ------------------------------------------------
  90. ; - 1:st byte:    < 128 then the number stands for the number of following
  91. ;        bytes that should be copied into the plane.
  92. ;        = 128 clear the next byte of the plane
  93. ;        > 128 then NEG the byte. The number you have now is the
  94. ;        number of times the next byte in the IFF-file should be
  95. ;        copied into the plane.
  96. ;------------------------------------------------------------------------
  97.  
  98. Graphics:    move.l    #'BODY',d0
  99.         move.l    IFFPointer(pc),a0
  100.         bsr    FindString
  101.         lea    LinePointers(pc),a1
  102.         move.l    ShowAdr(pc),d0
  103.         move.l    #256*40,d1
  104.         moveq    #4,d7
  105. ALoop:        move.l    d0,(a1)+
  106.         add.l    d1,d0
  107.         dbf    d7,ALoop
  108.  
  109.         moveq    #0,d3
  110.         move.b    BPlan(pc),d3
  111.         subq.b    #1,d3
  112.         move.w    #128,d4
  113.         lea    LinePointers(pc),a3
  114.         move.w    #256-1,d7
  115.  
  116. LLoop1:        move.l    a3,a1
  117.         move.w    d3,d6
  118. LLoop2:        move.l    (a1),a2
  119.         moveq    #40-1,d5
  120. LLoop3:        moveq    #0,d0
  121.         move.b    (a0)+,d0
  122.         bpl.S    Move1
  123.         cmp.b    d4,d0
  124.         bne.S    Move2
  125.  
  126. Move3:        clr.b    (a2)+
  127. EndIt2:        tst.b    d5
  128.         bpl.S    LLoop3
  129.         move.l    a2,(a1)+
  130.         dbf    d6,LLoop2
  131.         dbf    d7,LLoop1
  132.         rts
  133.  
  134. Move2:        neg.b    d0
  135.         sub.b    d0,d5
  136.         move.b    (a0)+,d1
  137. FL1:        move.b    d1,(a2)+
  138.         dbf    d0,FL1
  139.         subq.b    #1,d5
  140.         bra.S    EndIt2
  141.  
  142. Move1:        sub.b    d0,d5
  143.         subq.b    #1,d5
  144. FL2:        move.b    (a0)+,(a2)+
  145.         dbf    d0,FL2
  146.         bra.S    EndIt2
  147.  
  148. ;------------------------------------------------------------
  149.  
  150. FindString:    cmp.l    (a0),d0
  151.         beq.S    StringFound
  152.         addq.l    #2,a0
  153.         bra.S    FindString
  154. StringFound:    addq.l    #8,a0
  155.         rts
  156.  
  157. Base:        lea    IFFPointer(pc),a0
  158.         move.l    IFFBild(pc),(a0)
  159.         move.l    (a0),a1
  160.         moveq    #0,d0
  161.         move.b    28(a1),d0        ;Antal Bitplan
  162.         lea    AntBpl+2(pc),a2
  163.         lsl.b    #4,d0
  164.         move.b    d0,(a2)
  165.         lsr.b    #4,d0
  166.         move.b    d0,16(a0)
  167.         subq.w    #1,d0
  168.         add.w    d0,d0
  169.         move.w    NoCols(pc,d0.W),d0
  170.         move.w    d0,14(a0)
  171.         lea    BMap(pc),a3
  172.         move.l    ShowAdr(pc),d0
  173.         moveq    #0,d1
  174.         move.w    #256*40,d1
  175.         moveq    #0,d7
  176.         move.b    16(a0),d7
  177.         subq.w    #1,d7
  178. BMapLoop:    swap    d0
  179.         move.w    d0,2(a3)
  180.         swap    d0
  181.         move.w    d0,6(a3)
  182.         addq.l    #8,a3
  183.         add.l    d1,d0
  184.         dbf    d7,BMapLoop
  185.         rts
  186.  
  187. IFFBild:    dc.l    $40000
  188. ShowAdr:    dc.l    $50000
  189. IFFPointer:    dc.l    0
  190. NoCols:        dc.w    2,4,8,16,32
  191. Cols:        dc.w    0
  192. BPlan:        dc.b    0
  193.         even
  194.  
  195. LinePointers:    blk.l    5,0
  196.  
  197. ;----------------------------------------------------------------------
  198.  
  199. CopperList:    dc.l    $008e2881,$009028dd,$00920038,$009400d0
  200.         dc.l    $01020000,$01040000,$01080000,$010a0000
  201.  
  202. BMap:        dc.l    $00e00000,$00e20000,$00e40000,$00e60000
  203.         dc.l    $00e80000,$00ea0000,$00ec0000,$00ee0000
  204.         dc.l    $00f00000,$00f20000
  205.  
  206. Colors:        dc.l    $01800000,$01820000,$01840000,$01860000
  207.         dc.l    $01880000,$018a0000,$018c0000,$018e0000
  208.         dc.l    $01900000,$01920000,$01940000,$01960000
  209.         dc.l    $01980000,$019a0000,$019c0000,$019e0000
  210.         dc.l    $01a00000,$01a20000,$01a40000,$01a60000
  211.         dc.l    $01a80000,$01aa0000,$01ac0000,$01ae0000
  212.         dc.l    $01b00000,$01b20000,$01b40000,$01b60000
  213.         dc.l    $01b80000,$01ba0000,$01bc0000,$01be0000
  214.  
  215. AntBpl:        dc.l    $01000000
  216.  
  217.         dc.l    -2
  218. ss:
  219.  
  220.