home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / GFX / ADPro251-3.DMS / ADPro251-3.adf / ADProScripts.lha / RemapANIM.adpro < prev    next >
Encoding:
Text File  |  1994-01-31  |  5.0 KB  |  244 lines
  1. /*
  2. ** RemapANIM.adpro
  3. **
  4. ** $VER: RemapANIM.adpro 1.3.1 (17.1.94)
  5. **
  6. ** This AREXX program will take an existing ANIM file and remaps its
  7. ** frames to either the first frame's palette or an external palette file.
  8. **
  9. ** This script requires ADPro v2.5.0 (or higher).
  10. **
  11. ** Copyright © 1993-1994 ASDG, Incorporated
  12. ** All Rights Reserved
  13. */
  14.  
  15.  
  16. ADDRESS "ADPro"
  17. OPTIONS RESULTS
  18.  
  19. NL = '0A'X
  20. SQ = '27'X
  21. DQ = '22'X
  22. TRUE = 1
  23. FALSE = 0
  24. TempDefaults = "T:TempADProDefaults"
  25.  
  26.  
  27. /*
  28. ** Save the current environment.
  29. */
  30.  
  31. SAVE_DEFAULTS TempDefaults
  32.  
  33.  
  34. PSTATUS "UNLOCKED"
  35.  
  36.  
  37. /*
  38. ** Select the file to remap.
  39. */
  40.  
  41. CALL "FREDSCRIPTS:FREDFunctions/GetAFile" '"Enter ANIM To Remap"' '"ADPRO:"' '""""' TRUE
  42. IF (RESULT = DQ||DQ) THEN DO
  43.     ADPRO_TO_FRONT
  44.     OKAY1 "Error, no source ANIM specified."
  45.     CALL ErrorOut 10
  46. END
  47. SrcANIMFName = RESULT
  48.  
  49. CALL "FREDSCRIPTS:FREDFunctions/GetAFile" '"Enter name of ANIM file to create."' '"ADPRO:"' '""""' TRUE
  50. IF (RESULT = DQ||DQ) THEN DO
  51.     ADPRO_TO_FRONT
  52.     OKAY1 "Error, no dest ANIM specified."
  53.     CALL ErrorOut 10
  54. END
  55. DestANIMFName = RESULT
  56.  
  57. IF (EXISTS( DestANIMFName )) THEN DO
  58.     ADPRO_TO_FRONT
  59.  
  60.     OKAYN '"RemapANIM"' '"Truncate destination ANIM?"' '"Start New File|Append To File|Cancel"'
  61.     IF (RC = 0) THEN DO
  62.         CALL ErrorOut 10
  63.     END
  64.     ELSE IF (RC = 1) THEN DO
  65.         IMAGE_TYPE
  66.         ImageType = ADPRO_RESULT
  67.         IF (WORD( ImageType, 1 ) = "NONE") THEN DO
  68.             LOADER "BACKDROP" "XXX" "WIDTH" 10 "HEIGHT" 10 "COLOR"
  69.             IF (RC ~= 0) THEN DO
  70.                 ADPRO_TO_FRONT
  71.                 OKAY1 "Unable to create temp image." || NL ||,
  72.                     "Argument Information:" || NL||,
  73.                     "Width = " || 10 || NL ||,
  74.                     "Height = " || 10 || NL ||,
  75.                     "Type = " || "COLOR"
  76.                 CALL ErrorOut 10
  77.             END
  78.         END
  79.  
  80.         IF (WORD( ImageType, 1 ) ~= "BITPLANE") THEN DO
  81.             EXECUTE
  82.             IF (RC ~= 0) THEN DO
  83.                 ADPRO_TO_FRONT
  84.                 OKAY1 "Unable to create temp rendered data."
  85.                 CALL ErrorOut 10
  86.             END
  87.         END
  88.  
  89.         SAVER "ANIM" DestANIMFName "IMAGE" "QUIT"
  90.         IF (RC ~= 0) THEN DO
  91.             ADPRO_TO_FRONT
  92.             OKAY1 "Could not close current ANIM file." || NL ||,
  93.                 "Argument Information:" || NL ||,
  94.                 "Filename = " || DestANIMFName || NL ||,
  95.                 "Type = " || "IMAGE" || NL ||,
  96.                 "Flags = " || "QUIT"
  97.             CALL ErrorOut 10
  98.         END
  99.  
  100.         ADDRESS COMMAND "Delete >NIL:" DestANIMFName
  101.     END
  102. END
  103.  
  104. LOADER "ANIM" SrcANIMFName "COUNT"
  105. IF (RC ~= 0) THEN DO
  106.     ADPRO_TO_FRONT
  107.     OKAY1 "Can't find ANIM file."
  108.     CALL ErrorOut 10
  109. END
  110. NumFrames = ADPRO_RESULT
  111.  
  112.  
  113. /*
  114. ** Ask which frames to process.
  115. */
  116.  
  117. CALL "FREDSCRIPTS:FREDFunctions/GetANumber" '"Starting frame"' 1 1 NumFrames TRUE
  118. StartFrame = RESULT
  119. IF (StartFrame = (1-1)) THEN
  120.     CALL ErrorOut 10
  121.  
  122. CALL "FREDSCRIPTS:FREDFunctions/GetANumber" '"Ending frame"' NumFrames StartFrame NumFrames TRUE
  123. EndFrame = RESULT
  124. IF (EndFrame = (StartFrame-1)) THEN
  125.     CALL ErrorOut 10
  126.  
  127.  
  128. ADPRO_TO_FRONT
  129.  
  130. OKAYN '"RemapANIM"' '"Select palette to use"' '"ANIM''s First Frame|External Palette|Cancel"'
  131. IF (RC = 0) THEN DO
  132.     CALL ErrorOut 10
  133. END
  134. ELSE IF (RC = 1) THEN DO
  135.     LOADER "ANIM" SrcANIMFName "FRAME" 1
  136.     IF (RC ~= 0) THEN DO
  137.         ADPRO_TO_FRONT
  138.         OKAY1 "Cannot find source ANIM."
  139.         CALL ErrorOut 10
  140.     END
  141. END
  142. ELSE IF (RC = 2) THEN DO
  143.     CALL "FREDSCRIPTS:FREDFunctions/GetAFile" '"Select palette file"' '""""' '""""' TRUE
  144.     IF (RESULT = DQ||DQ) THEN DO
  145.         ADPRO_TO_FRONT
  146.         OKAY1 "Error, no palette file selected."
  147.         CALL ErrorOut 10
  148.     END
  149.     ELSE
  150.         PaletteFile = RESULT
  151.  
  152.     PLOAD PaletteFile
  153.     IF (RC ~= 0) THEN DO
  154.         ADPRO_TO_FRONT
  155.         OKAY1 "Error loading palette file:" || NL ||,
  156.             PaletteFile
  157.         CALL ErrorOut 10
  158.     END
  159. END
  160.  
  161. PSTATUS "LOCKED"
  162.  
  163. SCREEN_TYPE
  164. oldSType = ADPRO_RESULT
  165. SCREEN_TYPE ADPRO_RESULT
  166.  
  167. CurrFrameNum = StartFrame
  168. continue = FALSE
  169. DO WHILE (continue = FALSE)
  170.     LOADER "ANIM" SrcANIMFName "FRAME" CurrFrameNum
  171.     IF (RC ~= 0) THEN DO
  172.         ADPRO_TO_FRONT
  173.         OKAY1 "Error during load" || NL ||,
  174.             "of frame " || CurrFrameNum || "."
  175.         CALL ErrorOut 10
  176.     END
  177.  
  178.     EXECUTE
  179.     IF (RC ~= 0) THEN DO
  180.         ADPRO_TO_FRONT
  181.         OKAY1 "Error creating rendered data."
  182.         CALL ErrorOut 10
  183.     END
  184.  
  185.     SAVER "ANIM" DestANIMFName "APPEND" "IMAGE"
  186.     IF (RC ~= 0) THEN DO
  187.         ADPRO_TO_FRONT
  188.         OKAY1 "Error during load" || NL ||,
  189.             "of frame " || CurrFrameNum || "."
  190.         CALL ErrorOut 10
  191.     END
  192.  
  193.     CurrFrameNum = CurrFrameNum + 1
  194.     IF (CurrFrameNum > EndFrame) THEN
  195.         continue = TRUE
  196. END
  197.  
  198. SAVER "ANIM" DestANIMFName "QUIT" "IMAGE"
  199. IF (RC ~= 0) THEN DO
  200.     ADPRO_TO_FRONT
  201.     OKAY1 "Error closing dest ANIM."
  202.     CALL ErrorOut 10
  203. END
  204.  
  205. CALL ErrorOut 0
  206.  
  207.  
  208. ErrorOut:
  209.     PARSE ARG ExitCode
  210.  
  211.     IF (EXISTS( SrcANIMFName )) & (ErrorCode ~= 0) THEN DO
  212.         LOADER "ANIM" SrcANIMFName "QUIT"
  213.         IF (RC ~= 0) THEN DO
  214.             ADPRO_TO_FRONT
  215.             OKAY1 "Error closing source ANIM:" || NL ||,
  216.                 SrcANIMFName || NL || NL ||,
  217.                 "You need to close it" || NL ||,
  218.                 "manually."
  219.         END
  220.     END
  221.  
  222.     IF (EXISTS( DestANIMFName )) & (ErrorCode ~= 0) THEN DO
  223.         SAVER "ANIM" DestANIMFName "IMAGE" "QUIT"
  224.         IF (RC ~= 0) THEN DO
  225.             ADPRO_TO_FRONT
  226.             OKAY1 "Error closing dest ANIM:" || NL ||,
  227.                 DestANIMFName || NL || NL ||,
  228.                 "You need to close it" || NL ||,
  229.                 "manually."
  230.         END
  231.     END
  232.  
  233.     IF (EXISTS( TempDefaults )) THEN DO
  234.         LOAD_DEFAULTS TempDefaults
  235.         IF (RC ~= 0) THEN DO
  236.             ADPRO_TO_FRONT
  237.             OKAY1 "Error restoring settings."
  238.         END
  239.  
  240.         ADDRESS COMMAND "Delete >NIL:" TempDefaults
  241.     END
  242.  
  243.     EXIT ExitCode
  244.