Amiga ISO Collection/AmigaUtilCD1.iso/Emulatoren/DC-PCT40.DMS/in.adf/Install-PCTask

Text File | 1997-01-06 | 4.2 KB | 244 lines

; PC-Task v4.0 Install Script (1.0)
; 12/12/96    Copyright 1994-1997 Quasar Distribution
; Translated by:

(set @default-dest "SYS:")

; English language

(set #pctask-location
(cat "Select location to put PC-Task 4 directory:"
))

(set #copying-files
(cat "Copying files..."
))

(set #help-askbool
(cat "Please select Yes to install the file(s) "
     "or select No so they are not installed. "
))

(set #data-set
(cat "Which programs do you wish to install?"
))


(set #notknown-set
(cat "CPU not known.  Please chose program to install."
))

(set #install-asl
(cat "You have Kickstart 2.0+\nasl.library can be used\n"
     "This allows you to select your screen modes from "
     "a list of available modes on your machine. "
))

(set #install-hardfiledevice
(cat "Do you wish to install the hardfile.device?\n"
     "This is needed if you wish to access a PC drive "
     "(which you have created for PC-Task) from AmigaDOS "
))

(set #copy-hardfile
(cat "Copying hardfile.device"
))

(set #install-msdosutils
(cat "Do you wish to install the MSDOSUtils directory?\n"
     "This directory contains some useful utilities "
     "which will come in handy when using PC-Task. "
))

(set #copy-msdosutils
(cat "Copying MSDOSUtils directory"
))

;--------------------------------------------------

(set dest2    (askdir    (prompt #pctask-location)
            (default @default-dest)
            (help @askdir-help)
            )
)

(set dest1 (tackon dest2 "PC-Task4"))
(makedir dest1 (infos))

; copy the PC-Task program
(set machine (database "cpu"))

(if (OR (= machine "68000") (= machine "68010"))
(
    (abort "You cannot run PC-Task 4 on your processor!")
)
)

(if (OR (= machine "68020") (= machine "68030") (= machine "68040"))
(
    (set types_to_install
        (askoptions
            (prompt #data-set)
            (help #whichone-help)
            (choices "PC-Task_Dynamic" "PC-Task_Interpretive")
        )
    )

    (if (IN types_to_install 0)
        (
        (copyfiles
            (prompt #copying-files)
            (source "PCT4_Disk:")
            (dest dest1)
            (choices "PC-Task_Dynamic")
            (infos)
            (help @copyfiles-help)
        )
        (tooltype
            (help @tooltype-help)
            (dest (tackon dest1 "PC-Task_Dynamic"))
            (noposition)
            (swapcolors)
        )
        )
    )

    (if (IN types_to_install 1)
    (
        (askdisk
            (prompt #copying-files)
            (dest "PCT4_Disk")
            (help @askdisk-help)
        )
        (copyfiles
            (prompt #copying-files)
            (source "PCT4_Disk:")
            (dest dest1)
            (choices "PC-Task_Interpretive")
            (infos)
            (help @copyfiles-help)
        )
        (tooltype
            (help @tooltype-help)
            (dest (tackon dest1 "PC-Task_Interpretive"))
            (noposition)
            (swapcolors)
        )
        )
    )
)
)


(copyfiles
    (source "PCT4_Disk:")
    (dest dest1)
    (choices "README_FIRST!")
    (infos)
    (help @copyfiles-help)
)

(tooltype
    (help @tooltype-help)
    (dest (tackon dest1 "README_FIRST!"))
    (noposition)
    (setdefaulttool "more")
)

(copyfiles
    (source "PCT4_Disk:")
    (dest dest1)
    (choices "PCTCrossMount")
    (infos)
    (help @copyfiles-help)
)

(tooltype
    (help @tooltype-help)
    (dest (tackon dest1 "PCTCrossMount"))
    (noposition)
)

(copyfiles
    (source "PCT4_Disk:")
    (dest dest1)
    (choices "PCTCrossMount.doc")
    (infos)
    (help @copyfiles-help)
)

(tooltype
    (help @tooltype-help)
    (dest (tackon dest1 "PCTCrossMount.doc"))
    (noposition)
    (setdefaulttool "more")
)

(set vernum (getversion))
(set ver (/ vernum 65536))

(if (AND (>= ver 37) (<= ver 38))
    (
        (copylib
            (prompt #install-asl)
            (source "PCT4_Disk:libs/asl.library")
            (dest "libs:")
            (optional nofail askuser force)
            (confirm)
            (help @copylib-help)
        )
    )
)



(set hardy     (askbool
            (prompt #install-hardfiledevice)
            (help #help-askbool)
        )
)

(if (= hardy 1)
    (copylib
        (prompt #copy-hardfile)
        (source "PCT4_Disk:devs/hardfile.device")
        (dest "devs:")
        (optional nofail askuser force)
        (confirm)
        (help @copyfiles-help)
    )
)


(set hardy     (askbool
            (prompt #install-msdosutils)
            (help #help-askbool)
        )
)

(if (= hardy 1)
    (
        (set dest2 (tackon dest1 "MSDOSUtils"))
        (copyfiles
            (infos)
            (prompt #copy-msdosutils)
            (source "PCT4_Disk:MSDOSUtils")
            (dest dest2)
            (all)
            (help @copyfiles-help)
        )
        (tooltype
            (help @tooltype-help)
            (dest dest2)
            (noposition)
        )
        (tooltype
            (help @tooltype-help)
            (dest (tackon dest2 "ProduceUtilDisk.doc"))
            (setdefaulttool "more")
        )
    )
)

(set @default-dest dest1)