Amiga ISO Collection/AmigaUtilCD1.iso/Disk&HD/DCN-DP12.LHA/DiskProtection/Install

Text File | 1996-05-01 | 8.5 KB | 256 lines

; Install script for DiskProtection V1.2

(set @default-dest "")

;=============================================================================
; make sure we are running under a 2.04+ ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort "You must be using Kickstart 2.04+ to run DiskProtection.")
))

;=============================================================================

(message (cat "\n\nDiskProtection installation script.\n\n"
              "This script installs DiskProtection on your Amiga. "
              "Read the documentation for "
              "more information on the distribution "
              "and commercial usage of DiskProtection.\n\n"
              "DiskProtection © 1994-1995 Patrick Ohly.\n"
              "All rights reserved."))

; check files ================================================================

(if (> 2 @user-level)
    (
       (set choice 1)
    )
    (
       (set choice (askbool (prompt (cat "Should the data integrity of " @app-name
                                         " be checked before attempting to install?\n\n"
                                         "(This is recommended.)")
                            )
                            (help @askbool-help)
                            (default 1)
                   )
       )
    )
)
(if (= choice 1)
    (
       (working (cat "Checking the integrity of " @app-name "."
                     "\n\nThis may take a few moments, depending on the"
                     " speed of your system."
                )
       )
       (if (> (run "md5sum/md5sum -c Checksums" (safe)) 0)
           (
              (abort (cat "WARING: This version of " @app-name " is"
                          " incorrect, damaged, or has been tampered with. Please check the"
                          " archive and the archive source carefully. If you"
                          " suspect the archive has been modified please contact"
                          " Patrick Ohly <[e-mail]> immediately!"))
           )
       )
    )
)

; copy files =================================================================

(set install_mode (askchoice
                      (prompt "Where do you want to install the different files of DiskProtection?")
                      (choices "In their corresponding system directory." "In one single directory.")
                      (help @askchoice-help)
                  )
)
(set mode_system_dirs 0)
(set mode_single_dir 1)

(set start_it (askbool
                      (prompt "Do you want to activate DiskProtection at startup?" )
                      (help @askbool-help)
              )
)

(set @default-dest
     (if (= install_mode mode_single_dir)
         (askdir (prompt "Please select a place for DiskProtection. All files and directories are copied there.")
                 (default "Work:DiskProtection")
                 (help @askdir-help)
         )
         ("")
     )
)

(if (= install_mode mode_single_dir)
    (set install_dir @default-dest)
)

(if (= install_mode mode_system_dirs)
    (
       (set install_dir
            (if (> @user-level 1)
                (askdir (prompt "Please select a place for the preferences program \"DiskProtection\".")
                        (default "SYS:Prefs")
                        (help @askdir-help)
                )
                ("SYS:Prefs")
            )
       )
       (set dp_dir install_dir)
    )
)
(copylib (prompt "Copying the preferences program \"DiskProtection\"...")
         (source "DiskProtection")
         (dest install_dir)
         (confirm "average")
         (infos)
         (help @copylib-help)
)

(set temp_dir
    (if (= start_it 1)
        ("SYS:WBStartup")
        (if (= install_mode mode_system_dirs)
            (if (> @user-level 1)
                (askdir (prompt "Please select a place for the initialization program \"DPInit\".")
                        (default "SYS:Tools")
                        (help @askdir-help)
                )
                ("SYS:Tools")
            )
            (install_dir)
        )
    )
)
(copylib (prompt "Copying the initialization program \"DPInit\"...")
         (source "DPInit")
         (dest temp_dir)
         (confirm "average")
         (infos)
         (help @copylib-help)
)

(set temp_dir
     (if (> @user-level 1)
         (askdir (prompt "Please select a place for the exec device \"diskprot.device\".")
                 (default "DEVS:")
                 (help @askdir-help)
         )
         ("DEVS:")
     )
)
(copyfiles (prompt "Copying the exec device \"diskprot.device\"...")
          (source "devs/diskprot.device")
          (dest temp_dir)
          (confirm "average")
          (help @copylib-help)
)

(if (= install_mode mode_system_dirs)
    (set install_dir
         (if (> @user-level 1)
             (askdir (prompt "Please select a place for the catalogs.")
                     (default "LOCALE:Catalogs")
                     (help @askdir-help)
             )
             ("LOCALE:Catalogs")
         )
    )
)
(copyfiles (prompt "Copying the catalogs for DiskProtection...")
           (source "catalogs")
           (all)
           (dest (if (= install_mode mode_single_dir) (tackon install_dir "Catalogs") (install_dir)))
           (confirm "average")
           (help @copyfiles-help)
)

(if (= install_mode mode_system_dirs)
    (set install_dir
         (if (> @user-level 1)
             (askdir (prompt "Please select a place for the amigaguide online help for DiskProtection.")
                     (default "HELP:")
                     (help @askdir-help)
             )
             ("HELP:")
         )
    )
)
(copyfiles (prompt "Copying the amigaguide online help for DiskProtection...")
           (source "help")
           (all)
           (dest (if (= install_mode mode_single_dir) (tackon install_dir "Help") (install_dir)))
           (infos)
           (confirm "average")
           (help @copyfiles-help)
)

(if (= install_mode mode_system_dirs)
    (set install_dir
         (if (> @user-level 1)
             (askdir (prompt (cat "Please select a place for the documentation of DiskProtection."
                              "It is available in ASCII-format (.dok/.doc) and TEX-format (.DVI)."
                             )
                     )
                     (default "HELP:")
                     (help @askdir-help)
             )
             ("HELP:")
         )
    )
)
(copyfiles (prompt "Copying the documentation for DiskProtection...")
           (source "Docs")
           (dest (if (= install_mode mode_single_dir) (tackon install_dir "Docs") (install_dir)))
           (all)
           (infos)
           (confirm "average")
           (help @copyfiles-help)
)

; check for triton library ===================================================
(copylib (prompt (cat "DiskProtection requires Triton V1.3. "
                      "Read the file 'Triton/ReadMe' for "
                      "more information on Triton.\n\n"
                      "Do you want to install at least the "
                      "triton.library for OS2.04?"
                 )
         )
         (help @copylib-help)
         (source "Triton/triton.library")
         (dest "LIBS:")
         (confirm "average")
)

; check for ENV:EDITOR =======================================================
(if (<> (exists "ENVARC:EDITOR") 1)
    (textfile (prompt "Creating enviroment variable 'EDITOR'...")
              (dest "ENVARC:EDITOR")
              (append (askstring (prompt "Which text editor do you want to use as system default?")
                                 (default "ed")
                                 (help @askstring-help)
                      )
              )
              (confirm "expert")
              (help @textfile-help)
    )
)

; create assigns + path in user-startup ======================================
(if (= install_mode mode_single_dir)
    (startup "DiskProtection" (prompt (cat "Adding \"assign DiskProtection: " install_dir "\"\n"
                                           "\"assign DEVS: DiskProtection:Devs ADD\" and\n"
                                           "\"path DiskProtection:\"\n"
                                           "to  user-startup..."
                                      )
                              )
                              (command (cat "assign DiskProtection: " install_dir "\n"
                                            "assign DEVS: DiskProtection:Devs ADD\n"
                                            "path DiskProtection:\n")
                              )
                              (help @startup-help)
    )
)