Amiga ISO Collection/AmigaUtilCD1.iso/Database/fdata11.dms/in.adf/HDInstall

Text File | 1994-08-18 | 5.7 KB | 246 lines

;;
;;  $Filename: HDInstall $
;;  $Date: 1994/08/18 09:59:38 $
;;  $Revision: 1.3 $
;;

(set is_update 0)
(set @user-level 1)    ; force to use average mode
(complete 0)

(set FD_dest
    (askdir
        (prompt "In which disk or drawer should the "
                    "Final Data drawer be created in?")
        (help "The installation utility will create a drawer named "
            "\"FinalData\" in the selected drawer or directory.  All "
            "Final Data files and drawers will be placed inside "
            "the new directory.\n\n"
            "A tip for advanced users:\n"
            "The \"FinalData\" directory may be moved as long as "
            "the sub-directories FDFiles, FDFonts, and FDLibs "
            "are also moved to the same location.")
        (default @default-dest)
    )
)

; Check if this is an update
; the FDLibs directory is a tell-tale sign
; that FD is already installed here
(if (exists (tackon FD_dest "FDLibs"))
    (set is_update 1)
    (    (if (exists (tackon FD_dest "FinalData"))
            (set is_update 1)
            (makedir (tackon FD_dest "FinalData") (infos))
        )
        (set FD_dest (tackon FD_dest "FinalData"))
    )
)

(set @default-dest FD_dest)
(set disk_space (getdiskspace FD_dest))

(set disk_space_needed 500000)

(if (AND (< disk_space disk_space_needed) (NOT is_update))
    (
        (set answer1
            (askbool
                (prompt    "There may not be enough room available on "
                            "this drive to install \"Final Data\". "
                            "Do you wish to continue?")
                (help    "Final Data needs approximately .5 megabytes of "
                        "disk space for a complete installation or .5 megabytes "
                        "for a minimal installation. If Final Data is already "
                        "installed on this partition, you may wish to continue. "
                        "Otherwise, press ABORT or NO now and either free some "
                        "space on this partition or select a different partition "
                        "for the installation.")
            )
        )
        (if (NOT answer1)
            (abort "Final Data installation cancelled. Not enough disk "
                    "space on Volume \""
                    (getdevice @default-dest)
                    "\"."
            )
        )
    )
)

; Allow updating user to select what they want updated
(if is_update
    ; YES - already installed
    (set install_options
        (askoptions
            (prompt "What parts would you like to update?")
            (help @askoptions-help)
            (choices
                "Final Data Program"
                "ARexx Macros"
                "Sample Data Files"
                "System Files"
                "System Libraries"
                "System Fonts")
            (default 25)        ; default to 0001-1001 = (1)Program, (8)Sys Files and (16)Libraries
        )
    )

    ; NO - First time install
        (set install_options 63)    ; hex 3F - 0011-1111 - all six options on
)

(set error 0)

; Installing Files from FDProgram
(if (IN install_options 0 1 2 3 4 5)
    (
        ; -----------------
        ; Copy the More program to the hard drive
        ; so everyone is guaranteed to have it.
        ; -----------------
        (if (NOT is_update)
            (copyfiles
                (source "FDProgram:More")
                (dest FD_dest)
            )
        )
        ; -----------------
        ; If installing/updating the program
        ; -----------------
        (if (IN install_options 0)
            (
                ; ----- COPY the Final Data program over
                (working "Installing Final Data program from FDProgram disk.")
                (copyfiles
                    (source "FDProgram:FinalData")
                    (dest FD_dest)
                )
                ; ----- COPY the Final Data .info if the icon doesn't exists
                (if (NOT (exists (tackon FD_dest "FinalData.info")))
                    (copyfiles
                        (source "FDProgram:FinalData.info")
                        (dest FD_dest)
                    )
                )
            )
        )
        (complete 50)


        ; -----------------
        ; Installing FDMacros
        ; -----------------
        (if (IN install_options 1)
            (
                ; ----- CREATE FDMacros if it doesn't exist.
                (if (NOT (exists (tackon FD_dest "FDMacros")))
                    (
                    (makedir (tackon FD_dest "FDMacros") (infos))
                    )
                )
                (working "Installing ARexx Macros from FDProgram disk.")
                (copyfiles
                    (source "FDProgram:FDMacros")
                    (dest (tackon FD_dest "FDMacros"))
                    (all)
                )
            )
        )
        (complete 60)


        ; -----------------
        ; Installing FDData
        ; -----------------
        (if (IN install_options 2)
            (
                ; If FDData doesn't exist, create it.
                (if (NOT (exists (tackon FD_dest "FDData")))
                    (
                    (makedir (tackon FD_dest "FDData") (infos))
                    )
                )
                (working "Installing Sample Data from FDProgram disk.")
                (copyfiles
                    (source "FDProgram:FDData")
                    (dest (tackon FD_dest "FDData"))
                    (all)
                )
            )
        )
        (complete 70)

        ; -----------------
        ; Installing FDFiles (make dir, do not copy .prefs)
        ; -----------------
        (if (IN install_options 3)
            (
                ; If FDFiles doesn't exist, create it.
                (if (NOT (exists (tackon FD_dest "FDFiles")))
                    (
                    (working "Installing System Files from FDProgram disk.")
                    (makedir (tackon FD_dest "FDFiles") (infos))
                    )
                )
            )
        )
        (complete 80)

        ; -----------------
        ; Installing FDLibs
        ; -----------------
        (if (IN install_options 4)
            (
                ; If FDLibs doesn't exist, create it.
                (if (NOT (exists (tackon FD_dest "FDLibs")))
                    (
                    (makedir (tackon FD_dest "FDLibs") (infos))
                    )
                )
                (working "Installing System Libraries from FDProgram disk.")
                (if (< (/ (getversion) 65536) 37)
                     (copyfiles
                         (source "FDProgram:FDLibs/iffparse.library")
                         (dest (tackon FD_dest "FDLibs"))
                        (files)
                     )
                )
                (copyfiles
                     (source "FDProgram:FDLibs/fcswlib.library")
                     (dest (tackon FD_dest "FDLibs"))
                    (files)
                )
            )
        )
        (complete 90)


        ; -----------------
        ; Installing FDFonts
        ; -----------------
        (if (IN install_options 5)
            (
                ; If FDFonts doesn't exist, create it.
                (if (NOT (exists (tackon FD_dest "FDFonts")))
                    (
                    (makedir (tackon FD_dest "FDFonts") (infos))
                    )
                )
                (working "Installing System Fonts from FDProgram disk.")
                (copyfiles
                    (source "FDProgram:FDFonts")
                    (dest (tackon FD_dest "FDFonts"))
                    (all)
                )

                (run ("Avail FLUSH"))
            )
        )
    )
)

(complete 100)

(exit)