Amiga ISO Collection/AmigaUtilCD1.iso/Database/adm30.lha/ADM/TerminTool/TerminTool.lha/prefs/ADMscPrefs

Text File | 1996-03-28 | 5.0 KB | 161 lines

.K Version
.Bra {
.Ket }
.Def Version= "$VER: ADMscPrefs V 0.8 (16.12.95) © Bernd Stange"

;--------------------------------------------------------------------------

if not exists c:Askreq
set dummy `requestchoice "Fehler:" "Bitte zuerst das Zusatzprogramm Askreq in das C:-Verzeichnis kopieren !" "OK"`
quit
endif

resident >NIL: C:Type PURE
If exists "ENV:ADMscPrefs"
setenv PfadVariable "ENV"
else
setenv PfadVariable "s"
endif
if not exists $pfadvariable:ADMscPrefs
setenv PfadVariable "env"
Setenv PfadADM "nicht gesetzt"
Setenv PfadADMDaten "nicht gesetzt"
Setenv PfadADMGebliste "nicht gesetzt"
Setenv VLog "nicht gesetzt"
Setenv Vorwarnung "nicht gesetzt"
Setenv Checkaktuell "nicht gesetzt"
else

if exists $PfadVariable:ADMscPrefs/PfadADM
Setenv PfadADM `type $PfadVariable:ADMscPrefs/PfadADM `
else
Setenv PfadADM "nicht gesetzt"
endif
if exists $PfadVariable:ADMscPrefs/PfadADMDaten
Setenv PfadADMDaten `type $PfadVariable:ADMscPrefs/PfadADMDaten `
else
Setenv PfadADMDaten "nicht gesetzt"
endif
if exists $PfadVariable:ADMscPrefs/PfadADMGebliste
Setenv PfadADMGebliste `type $PfadVariable:ADMscPrefs/PfadADMGebliste `
else
Setenv PfadADMGebliste "nicht gesetzt"
endif
if exists $PfadVariable:ADMscPrefs/VLog
Setenv VLog `type $PfadVariable:ADMscPrefs/VLog `
else
Setenv VLog "nicht gesetzt"
endif
if exists $PfadVariable:ADMscPrefs/Vorwarnung
Setenv Vorwarnung `type $PfadVariable:ADMscPrefs/Vorwarnung `
else
Setenv Vorwarnung "nicht gesetzt"
Endif
if exists $PfadVariable:ADMscPrefs/Checkaktuell
Setenv Checkaktuell `type $PfadVariable:ADMscPrefs/Checkaktuell `
else
Setenv Checkaktuell "nicht gesetzt"
Endif


ENDIF

Lab Start

set result `requestchoice "{Version} Aktuelle Einstellungen:" "1__ADM ====> $PfadADM*n2__ADMDaten ====> $PfadADMDaten*n3__Geb-Datei ====> $PfadADMGebliste*n4__VLog ====> $VLog*N5__Vorwarnung ====> $Vorwarnung*N6__Checkaktuell ====> $Checkaktuell" "1|2|3|4|5|6|Speichern|Abbruch"`

If "$result" eq "1"
set dummy `RequestChoice "Hinweis" "Einfach nur den Adressmaster anwählen !" "OK"`
Setenv PfadADM `requestfile TITLE="Bitte AddressMaster anwählen !"`
skip start back
endif

If "$result" eq "2"
set dummy `RequestChoice "Hinweis" "Einfach nur die ADM-Datensatzdatei von ADM anwählen !" "OK"`
Setenv PfadADMDaten `requestfile TITLE="Bitte ADMDaten anwählen !" FILE=Daten.ADM`
skip start back
endif

If "$result" eq "3"
set dummy `RequestChoice "Hinweis" "Das wird die Datei,*nin der alle Geburtstage*nim benötigten Format gespeichert werden !" "OK"`
Setenv PfadADMGebliste `requestfile TITLE="Bitte Pfad der Datei bestimmen !" FILE=Geburtstage.ASC`
skip start back
endif

If "$result" eq "4"
set dummy `RequestChoice "Frage:" "Das Programm Voice-Log zum Anwählen*Neiner Telefonnummer verwenden ?" "Ja|Nein"`
if $dummy eq "0"
setenv VLog Nein
skip start back
else
set dummy `RequestChoice "Hinweis" "Einfach nur das Programm Voice-Log anwählen !*NVoice-Log muß natürlich richtig konfiguriert sein." "OK"`
Setenv VLog `requestfile TITLE="Bitte Voice-Log anwählen"`
skip start back
endif
endif

If "$result" eq "5"
set dummy `RequestChoice "Hinweis" "Hier bitte eingegeben,*Nwieviele Tage vor einem Termin oder Geburtstag*Nerinnert werden soll !" "OK"`
setenv Vorwarnung `askreq H "Eingabe" M "Bitte die Vorwarntage eingeben" I`
skip start back
endif

If "$result" eq "6"
set dummy `RequestChoice "Hinweis" "Hier bitte wählen,*Nob die Geb.-Liste immer auf Aktualität geprüft werden soll.*NWenn ja, dann wird sie auf Wunsch sofort erneuert.*NDazu dann bitte gleich den Pfad des ARexxScripts 'ADMGeblist.adm' wählen!" "Ja|Nein|Abbruch"`
if "$dummy" eq "1"
setenv Checkaktuell `requestfile FILE = ADMGebList.adm PATTERN = "#?.adm" TITLE="Bitte das Rexxcript ADMGebList.adm wählen !" POSITIVE = "Erneuere Liste"`
Endif
if "$dummy" eq "2"
setenv Checkaktuell "NEIN"
endif
skip start back
endif

If "$result" eq "7"
set dummy `RequestChoice "Frage:" "Die Einstellungen von ADMscPrefs*Nin S: oder in ENVARC: abspeichern ?" "S:|ENVARC:|Abbruch"`
if $dummy eq 1
if exists envarc:ADMscPrefs
delete >NIL: envarc:ADMscPrefs all
delete >NIL: env:ADMscPrefs all
endif
setenv PFADvariable S
endif
if $dummy eq 2
if exists s:ADMscPrefs
delete >NIL: s:ADMscPrefs all
endif
setenv Pfadvariable ENVARC
endif
if $dummy eq 0
skip Ende
endif
set dummy `RequestChoice "Hinweis:" "Speichere die Einstellungen unter *N*N$PFADvariable:ADMscPrefs ab !" "OK|Abbruch"`
if $dummy eq 0
skip ende
endif
makedir >NIL: $PfadVariable:ADMscPrefs
echo "$PfadADM" >$PfadVariable:ADMscPrefs/PfadADM
echo "$PfadADMDaten" >$PfadVariable:ADMscPrefs/PfadADMDaten
echo "$PfadADMGebliste" >$PfadVariable:ADMscPrefs/PfadADMGebliste
echo "$VLog" >$PfadVariable:ADMscPrefs/VLog
echo "$Vorwarnung" >$PfadVariable:ADMscPrefs/Vorwarnung
echo "$Checkaktuell" >$PfadVariable:ADMscPrefs/Checkaktuell
If $PfadVariable:ADMscPrefs eq "ENVarc:ADMscPrefs"
copy >NIL: "ENVarc:ADMscPrefs" "ENV:ADMscPrefs" all
endif
skip ende
endif

If "$result" eq "0"
lab ende
unsetenv >NIL: PFADADM
unsetenv >NIL: PFADADMDaten
unsetenv >NIL: PFADADMGebliste
unsetenv >NIL: VLog
unsetenv >NIL: Vorwarnung
unsetenv >NIL: PfadVariable
unsetenv >NIL: Checkaktuell
resident >NIL: Type remove
quit
endif