Amiga ISO Collection/AmigaUtilCD1.iso/Database/FLD-TBRE.LHA/TBASE/TeleBASE.install

Text File | 1994-02-16 | 4.3 KB | 232 lines

(set #screenselectcopyhelp (cat
    "This is the directory you want TeleBASE program "
    "to be installed. If you want TeleBASE always to start "
    "in boot up process then you should install it to "
    "WBStartup-directory.") )


(set #tooltypeshelp (cat
    "These are the commodity tooltypes for "
    "TeleBASE. You should run the TBPrefs "
  "program to complete the installation\n") )

(set #TBPrefscopyhelp (cat
    "This is the directory you want The TeleBASE "
     "Preferences setting program to be installed. "
     "For maximum consistency with system preferences "
     "programs you should install it to Prefs-directory.") )

(set #doccopyhelp (cat
    "Select documentation files for TeleBASE and "
    "TBPrefs programs you want to be installed." )
)

(set ver (/ (getversion "workbench.library") 65536) )

(complete 0)

(set #destination
        (askdir
            (prompt "Where would you like to install TeleBASE program?")
            (help #TeleBASEcopyhelp )
            (default "SYS:WBStartup/")
        )
)

(set @default-dest #destination)

(message "Copy TeleBASE to " #destination " directory?\n")

(copyfiles (source "TeleBASE")
           (dest #destination)
           (infos)
)

(complete 30)

(set #tooltypeopts
        (askoptions
            (prompt "Which tooltypes you want to set for TeleBASE\n")
            (help #tooltypeshelp)
            (choices "CX_POPUP" "CX_PRI" "CX_POPKEY" )
            (default 0)
        )
)

(if (IN #tooltypeopts 0)
        (tooltype
            (dest
                    (tackon
                        #destination "TeleBASE")
                    )
            (settooltype "CX_POPUP" "YES")
            (noposition) )
        (tooltype
            (dest
                    (tackon
                        #destination "TeleBASE")
                    )
            (settooltype "CX_POPUP" "NO")
            (noposition) ) )

(if (IN #tooltypeopts 1)
        (tooltype
            (dest
                    (tackon
                        #destination "TeleBASE")
                    )
            (settooltype "CX_PRI"
                    (cat
                            (asknumber
                                    (prompt "TeleBASE commodity priority?")
                                    (help "")
                                    (range -127 127)
                                    (default 0)
                            )
                    )
            )
            (noposition)
        )
)

(if (IN #tooltypeopts 2)
        (tooltype
            (dest (tackon #destination "TeleBASE") )
            (settooltype "CX_POPKEY"
                    (askstring
                        (prompt "TeleBASE popkey string?")
                        (help
                                (cat
                                    "You can also set popkey string with\n"
                                    "TBPrefs program.")
                                )
                        (default "rcommand F10")
                    )
            )
            (noposition)
        )
)

(complete 50)

(set #prefs
        (askdir
            (prompt "Where should I install the TBPrefs program?")
            (help #TBPrefscopyhelp)
            (default "SYS:Prefs/")
        )
)

(message "Copy TBPrefs to " #prefs " directory?\n")

(copyfiles (source "TBPrefs")
           (dest #prefs)
           (infos)
)

(tooltype (dest (tackon #prefs "TBPrefs"))
  (settooltype "TeleBASE" (tackon #destination "TeleBASE"))
  (noposition)
)

(set #prefsinrightplace (IN (exists "SYS:Prefs/TBPrefs" (noreq)) 0))

(complete 73)

(if (= 0 #prefsinrightplace)
        (tooltype (dest (tackon #destination "TeleBASE"))
                  (settooltype "PREFSPROGRAM" (tackon #prefs "TBPrefs"))
                  (noposition)
        )
)

(complete 85)

(set #docfiles
        (askoptions
            (prompt "Which document files you want to install?\n")
            (help #doccopyhelp)
            (choices "TeleBASE.doc   - ASCII file."
               "TBPrefs.doc    - ASCII file."
                     )
            (default 3)
        )
)

(if (= 0 #docfiles)
        (message "No document files installed!\n")
        (
            (set #docdir
                    (askdir
                        (prompt "Where should I install the document files?")
                        (help "" )
                        (default "WORK:")
                    )
            )

            (complete 93)

            (if (IN #docfiles 0)
                (
                    (copyfiles
                            (source "docs/TeleBASE.doc")
                               (dest #docdir)
                               (infos)

                    )

                    (set #docfilename
                            (tackon #docdir "TeleBASE.doc")
                    )

                    (if (> ver 38)
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "MultiView")
                                (noposition)
                            )
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "More")
                                (noposition)
                            )
                    )
                )
            )

            (complete 96)

            (if (IN #docfiles 1)
                (
                    (copyfiles
                            (source "docs/TBPrefs.doc")
                               (dest #docdir)
                               (infos)

                    )

                    (set #docfilename
                            (tackon #docdir "TBPrefs.doc")
                    )

          (if (> ver 38)
                            (tooltype
                                (dest #docfilename)
                                (setdefaulttool "MultiView")
                          (noposition)
                        )
                    (tooltype
                                (dest #docfilename)
                                (setdefaulttool "More")
                                (noposition)
                        )
                    )
                )
            )

            (complete 98)
        )
)

(complete 100)