home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / Cruncher / MiniXpkGuide.lha / MiniXpkGuide.S < prev    next >
Encoding:
Text File  |  1995-05-28  |  6.8 KB  |  281 lines
  1. *****************************************
  2. *        MiniXpkGuide        *
  3. * Small AmigaGuide-viewer with XPK sup.    *
  4. *    V1.0 7.3.95 by Martin Gierich    *
  5. *    Last change:28.05.95        *
  6. *****************************************
  7.                               
  8. ;Can be started from WB and CLI
  9. ;Tabsize=8
  10.                                                  
  11.                                                  
  12.                                                  
  13.                                                  
  14. ;exec
  15. _LVOOpenLibrary        = -552
  16. _LVOOldOpenLibrary    = -408
  17. _LVOCloseLibrary    = -414
  18. _LVOFindTask        = -294
  19. _LVOWaitPort        = -384
  20. _LVOGetMsg        = -372
  21. _LVOReplyMsg        = -378
  22. _LVOForbid        = -132
  23.  
  24. ;xpkmaster
  25. _LVOXpkExamine        = -36
  26. _LVOXpkUnpack        = -48
  27.  
  28. ;amigaguide
  29. _LVOOpenAmigaGuideA    = -54
  30. _LVOCloseAmigaGuide    = -66
  31.  
  32. ;dos
  33. _LVODeleteFile        = -72
  34. _LVOReadArgs        = -798
  35. _LVOFreeArgs        = -858
  36. _LVOAddPart        = -882
  37.  
  38. ;asl
  39. _LVOAllocAslRequest    = -48
  40. _LVOFreeAslRequest    = -54
  41. _LVOAslRequest        = -60
  42.  
  43.  
  44. ASL_FileRequest        = 0
  45. ASL_TB            = $80000000+$80000
  46. ASLFR_SleepWindow    = ASL_TB+43
  47. ASLFR_RejectIcons    = ASL_TB+60
  48. fr_File            = 4
  49. fr_Drawer        = 8
  50.  
  51.  
  52. XPK_InName    = $80005851    filename
  53. XPK_OutName    = $80005860    filename
  54. XPK_GetError    = $80005875    buffer
  55. XPK_TaskPri    = $8000587f    ubyte
  56.  
  57.         RSRESET
  58. ;NewAmigaGuide-structure
  59. nag_Lock    RS.L    1    Lock on the document directory
  60. nag_Name    RS.L    1    Name of document file
  61. nag_Screen    RS.L    1    Screen to place windows within
  62. nag_PubScreen    RS.L    1    Public screen name to open on
  63. nag_HostPort    RS.L    1    Application's ARexx port name
  64. nag_ClientPort    RS.L    1    Name to assign to the clients ARexx port
  65. nag_BaseName    RS.L    1    Base name of the application
  66. nag_Flags    RS.L    1    Flags
  67. nag_Context    RS.L    1    NULL terminated context table
  68. nag_Node    RS.L    1    Node to align on first (defaults to Main)
  69. nag_Line    RS.L    1    Line to align on
  70. nag_Extens    RS.L    1    Tag array extens
  71. nag_Client    RS.L    1    Private! MUST be NULL
  72. NewAmigaGuide_SIZEOF    RS.W    0
  73.  
  74. TagSize        = 3*2+1        longwords for tags
  75. NameSize    = 12        for new filename
  76. ArraySize    = 32        must be multiple of 16
  77. PathSize    = 120
  78. AllSize        = NewAmigaGuide_SIZEOF+TagSize*4+NameSize+ArraySize+PathSize
  79.  
  80. pr_CLI        = 172
  81. pr_MsgPort    = 92
  82. pr_CurrentDir    = 152
  83. sm_NumArgs    = 28
  84. sm_ArgList    = 36
  85.  
  86.  
  87.  
  88. ;d0-d3:scratch
  89. ;d4=RdArgs-struct
  90. ;d5=Return-code
  91. ;d6=WB-message
  92. ;d7=filename of guide
  93.  
  94. ;a0-a2:scratch
  95. ;a3=temporary filename
  96. ;a4=this task
  97. ;a5=dos-base
  98.  
  99.  
  100. ;init place for needed structures on stack
  101. start    moveq    #20,d5        ;set return-code to FAIL
  102.     lea    DosName(pc),a0
  103.     move.l    a0,d7        ;set an invalid filename
  104.     moveq    #AllSize/4-1,d0
  105. .Wdh    clr.l    -(sp)        ;get some space for nag
  106.     dbra    d0,.Wdh
  107.     move.l    4.w,a6        ;exec-base to a6
  108.     lea    DosName(pc),a1
  109.     moveq    #36,d0        ;check for OS2.0+
  110.     jsr    _LVOOpenLibrary(a6)    ;open dos.library (in ROM)
  111.     move.l    d0,a5        ;a5=dos-base
  112.  
  113. ;create unique temporary filename in T:
  114.     sub.l    a1,a1
  115.     jsr    _LVOFindTask(a6)    ;find this task
  116.     move.l    d0,a4        ;a4=this task
  117.     lea    NewAmigaGuide_SIZEOF+TagSize*4(sp),a1
  118.     move.l    a1,a3
  119.     move.w    #"T:",(a1)+    ;unpack to T: dir
  120.     moveq    #7,d1        ;create unique name using the task adr.
  121. .Nib    move.b    d0,(a1)
  122.     and.b    #$0f,(a1)
  123.     add.b    #"J",(a1)+    ;use "J" to "Y" for each nibble
  124.     ror.l    #4,d0
  125.     dbra    d1,.Nib        ;do it for all 8 nibbles
  126.  
  127. ;check for WB or CLI start
  128.     moveq    #0,d4        ;reset Rdargs-struct
  129.     moveq    #0,d6        ;reset WB-msg
  130.     tst.l    pr_CLI(a4)    ;a4=this task
  131.     bne.s    CLI
  132. WB    lea    pr_MsgPort(a4),a0    ;it was WB-start
  133.     jsr    _LVOWaitPort(a6)
  134.     lea    pr_MsgPort(a4),a0
  135.     jsr    _LVOGetMsg(a6)
  136.     move.l    d0,d6        ;d6=message from WB
  137.     move.l    d0,a0
  138.     move.l    sm_ArgList(a0),a1
  139.     move.l    (a1),pr_CurrentDir(a4)    ;Lock on Current Dir
  140.     moveq    #2,d0
  141.     cmp.l    sm_NumArgs(a0),d0    ;check shift-doubleclick
  142.     bne.s    Request
  143.     addq.l    #8,a1
  144.     move.l    (a1)+,pr_CurrentDir(a4)    ;Lock on Current Dir
  145.     move.l    (a1),d7        ;filename to d7
  146.     bra.s    UnPack1
  147.  
  148. CLI    move.l    a5,a6            ;started from CLI
  149.     lea    Template(pc),a0
  150.     move.l    a0,d1
  151.     lea    NewAmigaGuide_SIZEOF+TagSize*4+NameSize(sp),a2
  152.     move.l    a2,d2            ;a2=arg-array
  153.     moveq    #0,d3
  154.     jsr    _LVOReadArgs(a6)    ;process argumentline
  155.     move.l    d0,d4            ;d4=RdArgs-struct
  156.     beq.s    REnd
  157.     move.l    (a2),d7            ;filename to d7
  158.     beq.s    Request
  159.     move.l    4(a2),nag_Node(sp)
  160.     move.l    8(a2),d0        ;pointer to linenumber ?
  161.     beq.s    .NoLine
  162.     move.l    d0,a0
  163.     move.l    (a0),nag_Line(sp)
  164. .NoLine    move.l    12(a2),nag_PubScreen(sp)
  165.     move.l    16(a2),nag_ClientPort(sp)
  166. UnPack1    bra.s    UnPack
  167.  
  168. Request    lea    AslName(pc),a1        ;open asl.library
  169.     bsr    OpenLibrary
  170.     tst.l    d0
  171. REnd    beq    Ende
  172.     moveq    #ASL_FileRequest,d0
  173.     sub.l    a0,a0
  174.     jsr    _LVOAllocAslRequest(a6)    ;get filerequest-struct
  175.     move.l    d0,d2
  176.     beq.s    Req2
  177.     move.l    d2,a0
  178.     lea    AslTags(pc),a1
  179.     jsr    _LVOAslRequest(a6)    ;open filerequester
  180.     tst.l    d0
  181.     beq.s    Req1
  182.     move.l    d2,a2
  183.     move.l    fr_Drawer(a2),a0
  184.     lea    NewAmigaGuide_SIZEOF+TagSize*4+NameSize+ArraySize(sp),a1
  185.     move.l    a1,d7
  186. .CpDir    move.b    (a0)+,(a1)+        ;copy dirname
  187.     bne.s    .CpDir
  188.     move.l    d2,-(sp)
  189.     move.l    d7,d1
  190.     move.l    fr_File(a2),d2
  191.     moveq    #120,d3
  192.     exg.l    a5,a6            ;dosbase
  193.     jsr    _LVOAddPart(a6)        ;append filename
  194.     exg.l    a5,a6
  195.     move.l    (sp)+,d2
  196. Req1    move.l    d2,a0
  197.     jsr    _LVOFreeAslRequest(a6)    ;free filerequest-struct
  198. Req2    bsr    CloseLibrary
  199.  
  200. ;try to unpack file to temporary file, will fail if not packed
  201. UnPack    lea    XpkName(pc),a1
  202.     bsr    OpenLibrary
  203.     tst.l    d0
  204.     beq.s    Show        ;opened xpkmaster.library ?
  205.     lea    NewAmigaGuide_SIZEOF(sp),a0    ;create tags-field
  206.     move.l    #XPK_InName,(a0)
  207.     move.l    d7,4(a0)    ;filename from argumentline
  208.     move.l    #XPK_OutName,8(a0)
  209.     move.l    a3,12(a0)    ;unique self-done filename
  210.     move.l    #XPK_TaskPri,16(a0)
  211.     moveq    #-1,d0
  212.     move.l    d0,20(a0)    ;unpack in background
  213.     jsr    _LVOXpkUnpack(a6)
  214.     tst.l    d0
  215.     bne.s    .NoPack
  216.     move.l    a3,d7        ;only replace filename if it succeded
  217. .NoPack    bsr.s    CloseLibrary
  218.  
  219. ;show file using amigaguide.library
  220. Show    lea    GuideName(pc),a1
  221.     bsr.s    OpenLibrary
  222.     tst.l    d0
  223.     beq.s    Ende        ;opened amigaguide.library ?
  224.     move.l    d7,nag_Name(sp)    ;filename into nag
  225.     move.l    sp,a0        ;nag to a0
  226.     sub.l    a1,a1        ;must be zero
  227.     jsr    _LVOOpenAmigaGuideA(a6)    ;open guide
  228.     tst.l    d0
  229.     beq.s    .NoGuid        ;failed to open guide ?
  230.     move.l    d0,a0
  231.     jsr    _LVOCloseAmigaGuide(a6)    ;wait till user closes guide
  232.     moveq    #0,d5        ;set return-code to OK
  233. .NoGuid    bsr.s    CloseLibrary
  234.  
  235. ;clean up all things used
  236. Ende    move.l    a5,a6        ;dos-base to a6
  237.     cmp.l    d7,a3        ;unpacked file ?
  238.     bne.s    .NoDel
  239.     move.l    a3,d1
  240.     jsr    _LVODeleteFile(a6)    ;yes, delete it
  241. .NoDel    move.l    d4,d1
  242.     jsr    _LVOFreeArgs(a6)    ;free RdArgs-struct, if needed
  243.     bsr.s    CloseLibrary        ;close dos.library
  244.     lea    AllSize(sp),sp    ;restore stack
  245.  
  246. ;end program
  247.     move.l    d5,d0        ;set return-code
  248.     tst.l    d6        ;wb-msg ? -> started from WB
  249.     bne.s    .Jump
  250.     rts            ;THE END ! from CLI
  251. .Jump    jsr    _LVOForbid(a6)    ;must be in forbid-state
  252.     move.l    d6,a1
  253.     jmp    _LVOReplyMsg(a6)    ;THE END ! from WB
  254.  
  255. *****    subroutines
  256.  
  257. CloseLibrary    ;close library in a6
  258.     move.l    a6,a1
  259.     move.l    4.w,a6
  260.     jmp    _LVOCloseLibrary(a6)
  261.  
  262. OpenLibrary    ;open library in a1 and put result into a6
  263.     move.l    4.w,a6
  264.     jsr    _LVOOldOpenLibrary(a6)
  265.     move.l    d0,a6
  266.     rts
  267.  
  268. AslTags    dc.l    ASLFR_SleepWindow,1
  269.     dc.l    ASLFR_RejectIcons,1
  270.     dc.l    0
  271.  
  272. AslName        dc.b    "asl.library",0
  273. XpkName        dc.b    "xpkmaster.library",0
  274. GuideName    dc.b    "amigaguide.library",0
  275. DosName        dc.b    "dos.library",0
  276. Template    dc.b    "DATABASE,DOCUMENT/K,LINE/N,PUBSCREEN/K,"
  277.         dc.b    "PORTNAME/K",0
  278.  
  279.         end
  280.  
  281.