home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / UTILITY / BATCH / TSBAT35.ZIP / BOOT.BAT < prev    next >
Encoding:
DOS Batch File  |  1992-02-08  |  1.7 KB  |  72 lines
  1. echo off
  2. echo.
  3. echo ┌───────────────────────────────────────────────────┐
  4. echo │ Choose the boot configuration for the next boot   │
  5. echo │ By Prof. Timo Salmi, ts@chyde.uwasa.fi, 8-Feb-92  │
  6. echo └───────────────────────────────────────────────────┘
  7. echo.
  8.  
  9. rem Put a line with the word "Description:" into your alternative
  10. rem autoexec.bat files to show which boot is now on, E.g.
  11. rem Description: LastByte upper memory manager boot
  12.  
  13. rem If no parameter give help, and show the current boot choice
  14. if "%1"=="" goto _help
  15.  
  16. rem Turn off the read-only attribute
  17. attrib -r c:\autoexec.bat
  18. attrib -r c:\config.sys
  19.  
  20. rem Choose the next boot
  21. for %%f in (1 2 3) do if "%1"=="%%f" goto _%%f
  22. goto :_help
  23.  
  24. :_1
  25. copy c:\confnorm.sys c:\config.sys > nul
  26. copy c:\autonorm.bat c:\autoexec.bat > nul
  27. goto _common
  28.  
  29. :_2
  30. copy c:\conftlb.sys c:\config.sys > nul
  31. copy c:\autotlb.bat c:\autoexec.bat > nul
  32. goto _common
  33.  
  34. :_3
  35. copy c:\conftest.sys c:\config.sys > nul
  36. copy c:\autotest.bat c:\autoexec.bat > nul
  37. goto _common
  38.  
  39. rem Instructions to the user
  40. :_common
  41. set _return=_altcd
  42. goto _subru
  43. :_altcd
  44. echo.
  45. echo ALT-CTRL-DEL to boot
  46.  
  47. rem Turn on the read-only attribute for safety
  48. attrib +r c:\autoexec.bat
  49. attrib +r c:\config.sys
  50. goto :_out
  51.  
  52. rem Help for the user.  Customize as appropriate. If you
  53. rem have more that two, also edit the "for" statement earlier
  54. :_help
  55. echo Usage: BOOT [Choice]
  56. echo.
  57. echo 1 = My normal MsDos 3.3 boot
  58. echo 2 = LastByte upper memory manager boot
  59. echo 3 = Test configuration
  60. echo.
  61. set _return=_out
  62.  
  63. :_subru
  64. rem Batch subroutine to show which boot choice is the currently selected
  65. echo The current boot is
  66. find "Description:" c:\autoexec.bat
  67. goto %_return%
  68.  
  69. :_out
  70. set _return=
  71. echo on
  72.