home *** CD-ROM | disk | FTP | other *** search
/ ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng) / ProfitPress-MegaCDROM2.B6I / PROG / ASSEMBLY / STDLIB.ZIP / STRICMPL.ASM < prev    next >
Encoding:
Assembly Source File  |  1990-05-31  |  2.5 KB  |  128 lines
  1. stdlib        segment    para public 'slcode'
  2.         assume    cs:stdlib
  3. ;
  4.         extrn    $uprtbl:byte
  5. ;
  6. ; strcmpl- Compares the string pointed at by es:si to the string following
  7. ;       the call instruction.
  8. ;
  9. ; inputs:
  10. ;
  11. ;    es:si-    First string (The string to compare)
  12. ;    cs:rtn-    Second string (The string to compare against)
  13. ;
  14. ;    e.g.,
  15. ;        "if (es:si < cs:rtn) then ..."
  16. ;
  17. ; returns: 
  18. ;
  19. ;    ax- index into strings where they differ (points at the zero byte
  20. ;        if the two strings are equal).
  21. ; 
  22. ;    Condition codes set according to the string comparison.  You should
  23. ;    use the unsigned branches (ja, jb, je, etc.) after calling this
  24. ;    routine.
  25. ;
  26.         public    sl_stricmpl
  27. ;
  28. sl_stricmpl    proc    far
  29.         push    bp
  30.         mov    bp, sp
  31.         push    es
  32.         push    ds
  33.         push    bx
  34.         push    cx
  35.         push    si
  36.         push    di
  37.         mov    ax, es
  38.         mov    ds, ax
  39.         les    di, 2[bp]
  40.         lea    bx, $uprtbl
  41. ;
  42. ; In order to preserve the direction flag across this call, we have to
  43. ; test whether or not it is set here and execute two completely separate
  44. ; pieces of code (so we know which state to exit in.  Unfortunately, we
  45. ; cannot use pushf to preserve this flag since we need to return status
  46. ; info in the other flags.
  47. ;
  48.         pushf
  49.         pop    ax
  50.         test    ah, 4        ;Test direction bit.
  51.         jnz    DirIsSet
  52. ;
  53. ; Compute the length of the string following the CALL instruction:
  54. ;
  55.         cld
  56.         mov    al, 0
  57.         mov    cx, 0ffffh
  58.     repne    scasb
  59.         xchg    di, 2[bp]    ;Save as new return address.
  60. ;
  61.         xor    cx, cx        ;Set char index to zero.
  62. sclp:        lodsb
  63.         xlat    cs:$uprtbl
  64.         mov    ah, al
  65.         mov    al, es:[di]
  66.         xlat    cs:$uprtbl
  67.         cmp    ah, al        
  68.         jne    scNE        ;If strings are <>, quit.
  69.         inc    cx            ;Increment index into strs.
  70.         inc    di        ;Incrment str2 ptr.
  71.         cmp    al, 0        ;Check for end of strings.
  72.         jne    sclp
  73.         pushf
  74.         dec    cx
  75.         popf
  76. ;
  77. scNE:        mov    ax, cx
  78.         pop    di
  79.         pop    si
  80.         pop    cx
  81.         pop    bx
  82.         pop    ds
  83.         pop    es
  84.         pop    bp
  85.         ret            ;Return with direction flag clear.
  86. ;
  87. ;
  88. DirIsSet:    cld
  89.         mov    al, 0
  90.         mov    cx, 0ffffh
  91.     repne    scasb
  92.         xchg    di, 2[bp]    ;Save as new return address.
  93. ;
  94.         xor    cx, cx        ;Set char index to zero.
  95. sclp2:        lodsb
  96.         xlat    cs:$uprtbl
  97.         mov    ah, al
  98.         mov    al, es:[di]
  99.         xlat    cs:$uprtbl
  100.         cmp    ah, al        
  101.         jne    scNE2        ;If strings are <>, quit.
  102.         inc    cx            ;Increment index into strs.
  103.         inc    di        ;Incrment str2 ptr.
  104.         cmp    al, 0        ;Check for end of strings.
  105.         jne    sclp2
  106.         pushf
  107.         dec    cx
  108.         popf
  109. ;
  110. scNE2:        mov    ax, cx
  111.         pop    di
  112.         pop    si
  113.         pop    cx
  114.         pop    bx
  115.         pop    ds
  116.         pop    es
  117.         pop    bp
  118.         std
  119.         ret            ;Return with direction flag set.
  120. ;
  121. ;
  122. ;
  123. sl_stricmpl    endp
  124. ;
  125. ;
  126. stdlib        ends
  127.         end
  128.