ProfitPress Mega CDROM2 …eeware (MSDOS)(1992)(Eng)/ProfitPress-MegaCDROM2.B6I/MISC/EDUCATIO/SSPICE10.ZIP/ELEMENTS.DOC

Text File | 1991-02-01 | 17.9 KB | 395 lines

This file contains some of the definitions used by Sspice. A complete
listing is found in the Sspice User Manual. See SSPICE.DOC for ordering
information.

A)     Notation

In the following definitions [..] is optional; [name] is limited to 3
characters; and [value] is the numeric value of an element where Sspice
also accepts SPICE abbreviations F=10**-15, P=10**-12, N=10**-9, U=10**-6,
MIL=25.4*10**-6, M=10**-3, K=10**3, MEG=10**6, G=10**9, T=10**12. If [value]
is not given or is not part of the element definition, then the [value] is
obtained by prompting the user. Input descriptions are case insensitive.
All elements and names are echoed as upper case. Sspice uses a lower case
Laplace variable "s".

The first line of an Sspice input file is the TITLE LINE. This is the title
of all output files. The last line of the input file must be .END. Between
these two lines is the description of the circuit. In this part of the input
file, Sspice ignores all lines that do not begin with one of the element
letters given below. Sspice also ignores all .SUBCKT definitions.

B)     Elements

...Resistor modeled as a conductance G[name]:
R[name] <node> <node> [value of R] {ignore rest of line}

Examples:
R12 4 9 1K              modeled as G12 between nodes 4 and 9 with value 1mMHO.
Rab 5 3                 modeled as GAB between nodes 5 and 3.

*****************************************************************************
...Capacitor modeled as an admittance sC[name]:
C[name] <node> <node> [value of C] {ignore rest of line}

Examples:
cc1 4 2 4.7u            modeled as sCC1 between nodes 4 and 2 with value
                        s(4.7micro).
C 5 3                   modeled as sC between nodes 5 and 3.

*****************************************************************************
...Coupling Capacitor modeled as a short circuit:
C@[name] <node> <node> {ignore rest of line}

Example:
C@1 4 2 4.7u            modeled as short between nodes 4 and 2.

*****************************************************************************
...Inductor modeled as an admittance 1/sL[name]:
L[name] <node> <node> [value of L] {ignore rest of line}

Examples:
Ls 1 2 10m              modeled as 1/sLS between nodes 1 and 2 with value
                        1/s(10m).
L 2 3                   modeled as 1/sL between nodes 2 and 3.

*****************************************************************************
...Voltage-Controlled-Current Source with a transconductance GM[name]:
G[name] <(+)node> <(-)node> <(+control)node> <(-control)node> [value of GM]
      {ignore rest of line}

Examples:
Gxy 7 0 1 0 1m          modeled as a GMXY*V(1) between nodes 7 and 0 with a
                        value of 0.001V1.
G1 5 2 3 6              modeled as a GM1*V(3,6) between nodes 5 and 2.

*****************************************************************************
...Voltage-Controlled-Voltage-Source with gain A[name]:
E[name] <(+)node> <(-)node> <(+control)node> <(-control)node> [value of A]
      {ignore rest of line}

Examples:
e7 3 0 1 2 1k           modeled as a A7*V(1,2) between nodes 3 and 0
                        with a value of 1000V12.
Ex 1 2 0 6              modeled as a -AX*V(6) between nodes 1 and 2.

*****************************************************************************
...Voltage-Controlled-Voltage-Source with gain 1/K[name]:
EK[name] <(+)node> <(-)node> <(+control)node> <(-control)node> [value of K]
      {ignore rest of line}

Examples:
ek7 3 0 1 2 1U          modeled as a V(1,2)/K7 between nodes 3 and 0 with a
                        value of V12 /1micro.
Ek 1 2 0 6              modeled as a -V(6)/K between nodes 1 and 2.

*****************************************************************************
...Current-Controlled-Current-Source with gain B[name]:
F[name] <(+)node> <(-)node> <Unique control device VSC[name]> [value of B]
      {ignore rest of line}

Examples:
F 4 9 vsc1 100          modeled as a B*I(VSC1) between nodes 4 and 9 with
VSC1 3 5                a value of 100IVSC1 .
fx 1 2 VSCa             modeled as a BX*I(VSCA) between nodes 1 and 2.
VSCa 3 4

*****************************************************************************
...Current-Controlled-Voltage-Source with gain RM[name]:
H[name] <(+)node> <(-)node> <Unique control device VSC[name]> [value of RM]
      {ignore rest of line}

Example:
HA 5 2 VSC2             modeled as a RMA*I(VSC2) between nodes 5 and 2.
VSC2 1 4

*****************************************************************************
...AC Voltage Source modeled with a value of 1:
V[name] <(+)node> <(-)node> {ignore} AC {ignore rest of line}

Examples:
Vin 1 2 AC              modeled as an AC voltage of 1 between nodes 1
                        and 2.
V2 2 3 12 AC 4          modeled as an AC voltage of 1 between nodes 2 and 3.

*****************************************************************************
...DC Voltage Source modeled as a short and [name] is not SC[name]:
V[name] <(+)node> <(-)node> {ignore} {ignore rest of line}

Examples:
Vin 1 2                 modeled as short between nodes 1 and 2.
V2 2 3 12               modeled as short between nodes 2 and 3.

*****************************************************************************
...AC Current Source modeled with a value of 1:
I[name] <(+)node> <(-)node> {ignore} AC {ignore rest of line}

Examples:
Iin 8 2 AC              modeled as an AC current of 1 between nodes 8
                        and 2.
I2 2 7 1m AC 2          modeled as an AC current of 1 between nodes 2 and 7.

*****************************************************************************
...DC Current Source modeled as an open circuit:
I[name] <(+)node> <(-)node> {ignore} {ignore rest of line}

Examples:
Iin 8 2                 modeled as an open between nodes 8 and 2.
I2 2 7 1m               modeled as an open between nodes 2 and 7.

*****************************************************************************
...Transformed AC Current Source modeled with a value of G[name]:
I{ignore}/R[name] <(+)node> <(-)node> {ignore} AC {ignore rest of line}

Examples:
I1/R1 8 2 AC            modeled as an AC current of G1 between nodes 8
                        and 2.

*****************************************************************************
...Transformed AC Current Source modeled with a value of sC[name]:
I{ignore}*sC[name] <(+)node> <(-)node> {ignore} AC {ignore rest of line}

Examples:
I1*sC1 8 2 AC           modeled as an AC current of sC1 between nodes 8 and 2.
I*sC 2 7 1 AC 2         modeled as an AC current of sC between nodes 2 and 7.

*****************************************************************************
...Ideal Diode modeled as a short circuit:
D[name] <node> <node> {ignore rest of line}

Examples:
D1 1 2 D1N4001          modeled as short between nodes 1 and 2.
D 2 3                   modeled as short between nodes 2 and 3.

*****************************************************************************
...Low Frequency Diode modeled as a conductance GD[name]:
DL[name] <node> <node> {ignore rest of line}

Examples:
DL1 1 2 D1N4001         modeled as GD1 between nodes 1 and 2.
DL 2 3                  modeled as GD between nodes 2 and 3.

*****************************************************************************
...High Frequency Diode modeled as a conductance GD[name] in parallel with a
      capacitor CD[name]:
DH[name] <node> <node> {ignore rest of line}

Examples:
Dh1 1 2 D1N4001         modeled as GD1 with sCD1 between nodes 1 and 2.
DH 2 3                  modeled as GD with sCD between nodes 2 and 3.

*****************************************************************************
...Simple BJT modeled with a base-emitter conductance GPI[name] and collector-
      emitter VCCS of gain GM[name]:
Q[name] <(collector)node> <(base)node> <(emitter)node> {ignore rest of line}

Examples:
Q 6 2 5 Q2N2222         modeled as GPI between nodes 2 and 5 and as
                        GM*V(2,5) between nodes 6 and 5.
Q18 10 3 7              modeled as GPI18 between nodes 3 and 7 and as
                        GM18*V(3,7) between nodes 10 and 7.

*****************************************************************************
...Simple BJT with Beta modeled with a base-emitter conductance GPI[name] and
      collector-emitter CCCS of gain B[name]:
QB[name] <(collector)node> <(base)node> <(emitter)node> {ignore rest of line}

Example:
QB1 6 2 5 Qmod          modeled as GPI1 between nodes 2 and 5 and as
                        B1*I(GPI1) between nodes 6 and 5.

*****************************************************************************
...Low Frequency BJT modeled with a base-emitter conductance GPI[name],
      collector-emitter conductance GO[name] and collector-emitter VCCS of
      gain GM[name]:
QL[name] <(collector)node> <(base)node> <(emitter)node> {ignore rest of line}

Example:
QL1 6 2 5 QNPN          modeled as GPI1 between nodes 2 and 5, and as GO1
                        with GM1*V(2,5) between nodes 6 and 5.

*****************************************************************************
...High Frequency BJT modeled with a base-emitter conductance GPI[name],
      collector-emitter conductance GO[name], base-emitter capacitance
      CPI[name], base-collector capacitance CMU[name] and collector-emitter
      VCCS of gain GM[name]:
QH[name] <(collector)node> <(base)node> <(emitter)node> {ignore rest of line}

Example:
QH1 6 2 5 QNPN          modeled as GPI1 with sCPI1 between nodes 2 and 5, as
                        sCMU1 between nodes 2 and 6, and as GO1 with
                        GM1*V(2,5) between nodes 6 and 5.

*****************************************************************************
...Simple JFET modeled with a drain-source VCCS of gain GM[name]:
J[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
J2 6 2 5 jmod           modeled as GM2*V(2,5) between nodes 6 and 5.

*****************************************************************************
...Low Frequency JFET modeled with a drain-source conductance GDS[name] and
      drain-source VCCS of gain GM[name]:
JL[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
JL1 6 2 5               modeled as GDS1 with GM1*V(2,5) between
                        nodes 6 and 5.

*****************************************************************************
...High Frequency JFET modeled with a drain-source conductance GDS[name],
      gate-source capacitance CGS[name], gate-drain capacitance CGD[name]
      and drain-source VCCS of gain GM[name]:
JH[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
JH1 6 2 5 mod           modeled as sCGS1 between nodes 2 and 5, as sCGD1
                        between nodes 2 and 6, and as GDS1 with GM1*V(2,5)
                        between nodes 6 and 5.

*****************************************************************************
...Simple MOSFET modeled with a drain-source VCCS of gain GM[name] and bulk-
      source VCCS of gain GMB[name]:
M[name] <(drain)node> <(gate)node> <(source)node> <(bulk)node>
      {ignore rest of line}

Example:
M2 6 2 5 7 mod          modeled as GM2*V(2,5) and GMB2*V(7,5) between
                        nodes 6 and 5.
M1 4 2 3 3 MOS          modeled as GM1*V(2,3) between nodes 4 and 3.
+ W=33U L=10U
+ AD=.3N AS=.3N
+ PD=50U PS=50U

*****************************************************************************
...Low Frequency MOSFET modeled with a drain-source conductance GDS[name],
      drain-source VCCS of gain GM[name] and bulk-source VCCS of gain
      GMB[name]:
ML[name] <(drain)node> <(gate)node> <(source)node> <(bulk)node>
      {ignore rest of line}

Example:
ML2 6 2 5 7 mod         modeled as GDS2, GM2*V(2,5) and GMB2*V(7,5)
                        between nodes 6 and 5.

*****************************************************************************
...High Frequency MOSFETmodeled  with  a  drain - source  conductance
      GDS[name], gate-source capacitance CGS[name], gate-drain capacitance
      CGD[name], gate-bulk capacitance CGB[name], bulk-source capacitance
      CBS[name], bulk-drain capacitance CBD[name], drain-source VCCS of
      gain GM[name] and bulk-source VCCS of gain GMB[name]:
MH[name] <(drain)node> <(gate)node> <(source)node> <(bulk)node>
      {ignore rest of line}

Example:
MH2 6 2 5 7 mod         modeled as sCGS2 between nodes 2 and 5, as sCGD2
                        between nodes 2 and 6, as sCGB2 between nodes 2 and 7,
                        as sCBS2 between nodes 5 and 7, as sCBD2 between
                        nodes 6 and 7, and as GDS2, GM2*V(2,5) and
                        GMB2*V(7,5) between nodes 6 and 5.

*****************************************************************************
...Simple GaAsFET modeled with a drain-source VCCS of gain GM[name]:
B[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
B2 6 2 5 bmod           modeled as GM2*V(2,5) between nodes 6 and 5.

*****************************************************************************
...Low Frequency GaAsFET modeled with a drain-source conductance
      GDS[name] and drain-source VCCS of gain GM[name]:
BL[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
BL1 6 2 5               modeled as GDS1 with GM1*V(2,5) between
                        nodes 6 and 5.

*****************************************************************************
...High Frequency GaAsFET modeled with a drain-source conductance
      GDS[name], gate-source capacitance CGS[name], gate-drain capacitance
      CGD[name] and drain-source VCCS of gain GM[name]:
BH[name] <(drain)node> <(gate)node> <(source)node> {ignore rest of line}

Example:
BH1 6 2 5 mod           modeled as sCGS1 between nodes 2 and 5, as sCGD1
                        between nodes 2 and 6, and as GDS1 with GM1*V(2,5)
                        between nodes 6 and 5.

*****************************************************************************
...Ideal Op-Amp modeled with no voltage across and no current into the input
      terminals:
XOA[name] <(+)input> <(-)input> <output> {ignore rest of line}

Example:
xoa 1 2 3               modeled as 0 voltage and current between nodes 1 and 2
                        and as an arbitrary voltage and current between nodes 3
                        and 0.
xoa 7 0 4 oa            modeled as an ideal op-amp with the subcircuit
.subckt ...             definition ignored. This allows the user to find the
 (elements)             ideal response.
.ends oa

*****************************************************************************
...Active Filter Nonideal Op-Amp modeled with a gain-bandwidth-product
      GBP[name] in Hertz to predict the change in filter parameters due to
      GBP using the Wilson, Bedri, Bowron approximation:
XNOA[name] <(+)input> <(-)input> <output> {ignore rest of line}

Example:
xnoa 1 2 3              modeled as 0 current into nodes 1 and 2 and as voltage
                        gain of 2*PI*GBP/s between nodes 3 and 0.

Comment:
When this element is used in the input file, a new set of menu options appears.
This is because this element invokes an approximation algorithm which is only
valid for second order active filters. If the user wishes to create an
expression for the GBP, it must be done with an equivalent circuit.

*****************************************************************************
...Operational Transconductance Amplifier modeled with a VCCS of gain
      GM[name] delivering current:
XOTA[name] <(+)input> <(-)input> <output> {ignore rest of line}

Example:
XOTA1 6 4 7             modeled as a GM1*V(6,4) between nodes 0 and 7.

*****************************************************************************
...Ideal Transformer modeled with a turns ratio of the secondary to the
      primary of value N[name] where the secondary voltage is N[name] times
      the primary voltage and the secondary current is the primary current
      divided by N[name]:
XFMR[name] <(dot)input> <(non-dot)input> <(dot)output> <(non-dot)output>
      {ignore rest of line}

Example:
XFMR7 1 2 3 4           modeled as V(3,4) = V(1,2)*N7 and IS = IP/N7.

Comment:
In using this element and all 2-ports, there must be a path back to ground
through elements on both ports. Otherwise node voltages are indeterminant
and will result in all matrices have zero determinants. This is fixed by adding
a resistor to ground even though it might not be present. This resistor will
most likely become a common factor in transfer functions and be canceled.

*****************************************************************************
...Pathological Element Pair modeled as a nullator with zero voltage and zero
      current, and a norator with arbitrary voltage and arbitrary current :
XNN <(nullator)node> <(nullator)node> <(norator)node> <(norator)node>
      {ignore rest of line}

Example:
xnn 1 2 3 4             modeled as 0 voltage and current between nodes
                        1 and 2 and as arbitrary voltage and current
                        between nodes 3 and 4.

Comment:
The nullator and norator form a pair of elements with some very unusual
properties. This pair is essentially the ideal floating op-amp. Nullator-
norator circuit theory is not well known and has appeared in very few books.
Nonetheless, the use of these elements provides a link between passive circuit
theory and active circuit theory, in particular, the forming of node equations
by inspection. Any active circuit can be modeled using only resistors,
capacitors, independent current sources and nullators-norators. Sspice uses
this theory to map the user selected components into such a set. It then
formulates the node equations.